LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
subroutine cunbdb4 ( integer  M,
integer  P,
integer  Q,
complex, dimension(ldx11,*)  X11,
integer  LDX11,
complex, dimension(ldx21,*)  X21,
integer  LDX21,
real, dimension(*)  THETA,
real, dimension(*)  PHI,
complex, dimension(*)  TAUP1,
complex, dimension(*)  TAUP2,
complex, dimension(*)  TAUQ1,
complex, dimension(*)  PHANTOM,
complex, dimension(*)  WORK,
integer  LWORK,
integer  INFO 
)

CUNBDB4

Download CUNBDB4 + dependencies [TGZ] [ZIP] [TXT]

Purpose: 

 CUNBDB4 simultaneously bidiagonalizes the blocks of a tall and skinny
 matrix X with orthonomal columns:

                            [ B11 ]
      [ X11 ]   [ P1 |    ] [  0  ]
      [-----] = [---------] [-----] Q1**T .
      [ X21 ]   [    | P2 ] [ B21 ]
                            [  0  ]

 X11 is P-by-Q, and X21 is (M-P)-by-Q. M-Q must be no larger than P,
 M-P, or Q. Routines CUNBDB1, CUNBDB2, and CUNBDB3 handle cases in
 which M-Q is not the minimum dimension.

 The unitary matrices P1, P2, and Q1 are P-by-P, (M-P)-by-(M-P),
 and (M-Q)-by-(M-Q), respectively. They are represented implicitly by
 Householder vectors.

 B11 and B12 are (M-Q)-by-(M-Q) bidiagonal matrices represented
 implicitly by angles THETA, PHI.
Parameters
[in]M
          M is INTEGER
           The number of rows X11 plus the number of rows in X21.
[in]P
          P is INTEGER
           The number of rows in X11. 0 <= P <= M.
[in]Q
          Q is INTEGER
           The number of columns in X11 and X21. 0 <= Q <= M and
           M-Q <= min(P,M-P,Q).
[in,out]X11
          X11 is COMPLEX array, dimension (LDX11,Q)
           On entry, the top block of the matrix X to be reduced. On
           exit, the columns of tril(X11) specify reflectors for P1 and
           the rows of triu(X11,1) specify reflectors for Q1.
[in]LDX11
          LDX11 is INTEGER
           The leading dimension of X11. LDX11 >= P.
[in,out]X21
          X21 is COMPLEX array, dimension (LDX21,Q)
           On entry, the bottom block of the matrix X to be reduced. On
           exit, the columns of tril(X21) specify reflectors for P2.
[in]LDX21
          LDX21 is INTEGER
           The leading dimension of X21. LDX21 >= M-P.
[out]THETA
          THETA is REAL array, dimension (Q)
           The entries of the bidiagonal blocks B11, B21 are defined by
           THETA and PHI. See Further Details.
[out]PHI
          PHI is REAL array, dimension (Q-1)
           The entries of the bidiagonal blocks B11, B21 are defined by
           THETA and PHI. See Further Details.
[out]TAUP1
          TAUP1 is COMPLEX array, dimension (P)
           The scalar factors of the elementary reflectors that define
           P1.
[out]TAUP2
          TAUP2 is COMPLEX array, dimension (M-P)
           The scalar factors of the elementary reflectors that define
           P2.
[out]TAUQ1
          TAUQ1 is COMPLEX array, dimension (Q)
           The scalar factors of the elementary reflectors that define
           Q1.
[out]PHANTOM
          PHANTOM is COMPLEX array, dimension (M)
           The routine computes an M-by-1 column vector Y that is
           orthogonal to the columns of [ X11; X21 ]. PHANTOM(1:P) and
           PHANTOM(P+1:M) contain Householder vectors for Y(1:P) and
           Y(P+1:M), respectively.
[out]WORK
          WORK is COMPLEX array, dimension (LWORK)
[in]LWORK
          LWORK is INTEGER
           The dimension of the array WORK. LWORK >= M-Q.
 
           If LWORK = -1, then a workspace query is assumed; the routine
           only calculates the optimal size of the WORK array, returns
           this value as the first entry of the WORK array, and no error
           message related to LWORK is issued by XERBLA.
[out]INFO
          INFO is INTEGER
           = 0:  successful exit.
           < 0:  if INFO = -i, the i-th argument had an illegal value.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
July 2012
Further Details:

The upper-bidiagonal blocks B11, B21 are represented implicitly by angles THETA(1), ..., THETA(Q) and PHI(1), ..., PHI(Q-1). Every entry in each bidiagonal band is a product of a sine or cosine of a THETA with a sine or cosine of a PHI. See [1] or CUNCSD for details.

P1, P2, and Q1 are represented as products of elementary reflectors. See CUNCSD2BY1 for details on generating P1, P2, and Q1 using CUNGQR and CUNGLQ.

References:
[1] Brian D. Sutton. Computing the complete CS decomposition. Numer. Algorithms, 50(1):33-65, 2009.

Definition at line 215 of file cunbdb4.f.

215 *
216 * -- LAPACK computational routine (version 3.6.1) --
217 * -- LAPACK is a software package provided by Univ. of Tennessee, --
218 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
219 * July 2012
220 *
221 * .. Scalar Arguments ..
222  INTEGER info, lwork, m, p, q, ldx11, ldx21
223 * ..
224 * .. Array Arguments ..
225  REAL phi(*), theta(*)
226  COMPLEX phantom(*), taup1(*), taup2(*), tauq1(*),
227  $ work(*), x11(ldx11,*), x21(ldx21,*)
228 * ..
229 *
230 * ====================================================================
231 *
232 * .. Parameters ..
233  COMPLEX negone, one, zero
234  parameter ( negone = (-1.0e0,0.0e0), one = (1.0e0,0.0e0),
235  $ zero = (0.0e0,0.0e0) )
236 * ..
237 * .. Local Scalars ..
238  REAL c, s
239  INTEGER childinfo, i, ilarf, iorbdb5, j, llarf,
240  $ lorbdb5, lworkmin, lworkopt
241  LOGICAL lquery
242 * ..
243 * .. External Subroutines ..
244  EXTERNAL clarf, clarfgp, cunbdb5, csrot, cscal, xerbla
245 * ..
246 * .. External Functions ..
247  REAL scnrm2
248  EXTERNAL scnrm2
249 * ..
250 * .. Intrinsic Function ..
251  INTRINSIC atan2, cos, max, sin, sqrt
252 * ..
253 * .. Executable Statements ..
254 *
255 * Test input arguments
256 *
257  info = 0
258  lquery = lwork .EQ. -1
259 *
260  IF( m .LT. 0 ) THEN
261  info = -1
262  ELSE IF( p .LT. m-q .OR. m-p .LT. m-q ) THEN
263  info = -2
264  ELSE IF( q .LT. m-q .OR. q .GT. m ) THEN
265  info = -3
266  ELSE IF( ldx11 .LT. max( 1, p ) ) THEN
267  info = -5
268  ELSE IF( ldx21 .LT. max( 1, m-p ) ) THEN
269  info = -7
270  END IF
271 *
272 * Compute workspace
273 *
274  IF( info .EQ. 0 ) THEN
275  ilarf = 2
276  llarf = max( q-1, p-1, m-p-1 )
277  iorbdb5 = 2
278  lorbdb5 = q
279  lworkopt = ilarf + llarf - 1
280  lworkopt = max( lworkopt, iorbdb5 + lorbdb5 - 1 )
281  lworkmin = lworkopt
282  work(1) = lworkopt
283  IF( lwork .LT. lworkmin .AND. .NOT.lquery ) THEN
284  info = -14
285  END IF
286  END IF
287  IF( info .NE. 0 ) THEN
288  CALL xerbla( 'CUNBDB4', -info )
289  RETURN
290  ELSE IF( lquery ) THEN
291  RETURN
292  END IF
293 *
294 * Reduce columns 1, ..., M-Q of X11 and X21
295 *
296  DO i = 1, m-q
297 *
298  IF( i .EQ. 1 ) THEN
299  DO j = 1, m
300  phantom(j) = zero
301  END DO
302  CALL cunbdb5( p, m-p, q, phantom(1), 1, phantom(p+1), 1,
303  $ x11, ldx11, x21, ldx21, work(iorbdb5),
304  $ lorbdb5, childinfo )
305  CALL cscal( p, negone, phantom(1), 1 )
306  CALL clarfgp( p, phantom(1), phantom(2), 1, taup1(1) )
307  CALL clarfgp( m-p, phantom(p+1), phantom(p+2), 1, taup2(1) )
308  theta(i) = atan2( REAL( PHANTOM(1) ), REAL( PHANTOM(P+1) ) )
309  c = cos( theta(i) )
310  s = sin( theta(i) )
311  phantom(1) = one
312  phantom(p+1) = one
313  CALL clarf( 'L', p, q, phantom(1), 1, conjg(taup1(1)), x11,
314  $ ldx11, work(ilarf) )
315  CALL clarf( 'L', m-p, q, phantom(p+1), 1, conjg(taup2(1)),
316  $ x21, ldx21, work(ilarf) )
317  ELSE
318  CALL cunbdb5( p-i+1, m-p-i+1, q-i+1, x11(i,i-1), 1,
319  $ x21(i,i-1), 1, x11(i,i), ldx11, x21(i,i),
320  $ ldx21, work(iorbdb5), lorbdb5, childinfo )
321  CALL cscal( p-i+1, negone, x11(i,i-1), 1 )
322  CALL clarfgp( p-i+1, x11(i,i-1), x11(i+1,i-1), 1, taup1(i) )
323  CALL clarfgp( m-p-i+1, x21(i,i-1), x21(i+1,i-1), 1,
324  $ taup2(i) )
325  theta(i) = atan2( REAL( X11(I,I-1) ), REAL( X21(I,I-1) ) )
326  c = cos( theta(i) )
327  s = sin( theta(i) )
328  x11(i,i-1) = one
329  x21(i,i-1) = one
330  CALL clarf( 'L', p-i+1, q-i+1, x11(i,i-1), 1,
331  $ conjg(taup1(i)), x11(i,i), ldx11, work(ilarf) )
332  CALL clarf( 'L', m-p-i+1, q-i+1, x21(i,i-1), 1,
333  $ conjg(taup2(i)), x21(i,i), ldx21, work(ilarf) )
334  END IF
335 *
336  CALL csrot( q-i+1, x11(i,i), ldx11, x21(i,i), ldx21, s, -c )
337  CALL clacgv( q-i+1, x21(i,i), ldx21 )
338  CALL clarfgp( q-i+1, x21(i,i), x21(i,i+1), ldx21, tauq1(i) )
339  c = REAL( X21(I,I) )
340  x21(i,i) = one
341  CALL clarf( 'R', p-i, q-i+1, x21(i,i), ldx21, tauq1(i),
342  $ x11(i+1,i), ldx11, work(ilarf) )
343  CALL clarf( 'R', m-p-i, q-i+1, x21(i,i), ldx21, tauq1(i),
344  $ x21(i+1,i), ldx21, work(ilarf) )
345  CALL clacgv( q-i+1, x21(i,i), ldx21 )
346  IF( i .LT. m-q ) THEN
347  s = sqrt( scnrm2( p-i, x11(i+1,i), 1 )**2
348  $ + scnrm2( m-p-i, x21(i+1,i), 1 )**2 )
349  phi(i) = atan2( s, c )
350  END IF
351 *
352  END DO
353 *
354 * Reduce the bottom-right portion of X11 to [ I 0 ]
355 *
356  DO i = m - q + 1, p
357  CALL clacgv( q-i+1, x11(i,i), ldx11 )
358  CALL clarfgp( q-i+1, x11(i,i), x11(i,i+1), ldx11, tauq1(i) )
359  x11(i,i) = one
360  CALL clarf( 'R', p-i, q-i+1, x11(i,i), ldx11, tauq1(i),
361  $ x11(i+1,i), ldx11, work(ilarf) )
362  CALL clarf( 'R', q-p, q-i+1, x11(i,i), ldx11, tauq1(i),
363  $ x21(m-q+1,i), ldx21, work(ilarf) )
364  CALL clacgv( q-i+1, x11(i,i), ldx11 )
365  END DO
366 *
367 * Reduce the bottom-right portion of X21 to [ 0 I ]
368 *
369  DO i = p + 1, q
370  CALL clacgv( q-i+1, x21(m-q+i-p,i), ldx21 )
371  CALL clarfgp( q-i+1, x21(m-q+i-p,i), x21(m-q+i-p,i+1), ldx21,
372  $ tauq1(i) )
373  x21(m-q+i-p,i) = one
374  CALL clarf( 'R', q-i, q-i+1, x21(m-q+i-p,i), ldx21, tauq1(i),
375  $ x21(m-q+i-p+1,i), ldx21, work(ilarf) )
376  CALL clacgv( q-i+1, x21(m-q+i-p,i), ldx21 )
377  END DO
378 *
379  RETURN
380 *
381 * End of CUNBDB4
382 *
scnrm2
real function scnrm2(N, X, INCX)
SCNRM2
Definition: scnrm2.f:56
cunbdb5
subroutine cunbdb5(M1, M2, N, X1, INCX1, X2, INCX2, Q1, LDQ1, Q2, LDQ2, WORK, LWORK, INFO)
CUNBDB5
Definition: cunbdb5.f:158
xerbla
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
cscal
subroutine cscal(N, CA, CX, INCX)
CSCAL
Definition: cscal.f:54
clarfgp
subroutine clarfgp(N, ALPHA, X, INCX, TAU)
CLARFGP generates an elementary reflector (Householder matrix) with non-negative beta.
Definition: clarfgp.f:106
clarf
subroutine clarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
CLARF applies an elementary reflector to a general rectangular matrix.
Definition: clarf.f:130
csrot
subroutine csrot(N, CX, INCX, CY, INCY, C, S)
CSROT
Definition: csrot.f:100
clacgv
subroutine clacgv(N, X, INCX)
CLACGV conjugates a complex vector.
Definition: clacgv.f:76

Here is the call graph for this function:

Here is the caller graph for this function: