subroutine zhpt01	(	character	UPLO,
		integer	N,
		complex*16, dimension( * )	A,
		complex*16, dimension( * )	AFAC,
		integer, dimension( * )	IPIV,
		complex*16, dimension( ldc, * )	C,
		integer	LDC,
		double precision, dimension( * )	RWORK,
		double precision	RESID
	)

ZHPT01

Purpose:

 ZHPT01 reconstructs a Hermitian indefinite packed matrix A from its
 block L*D*L' or U*D*U' factorization and computes the residual
    norm( C - A ) / ( N * norm(A) * EPS ),
 where C is the reconstructed matrix, EPS is the machine epsilon,
 L' is the conjugate transpose of L, and U' is the conjugate transpose
 of U.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the Hermitian matrix A is stored: = 'U': Upper triangular = 'L': Lower triangular
[in]	N	N is INTEGER The number of rows and columns of the matrix A. N >= 0.
[in]	A	A is COMPLEX*16 array, dimension (N*(N+1)/2) The original Hermitian matrix A, stored as a packed triangular matrix.
[in]	AFAC	AFAC is COMPLEX*16 array, dimension (N*(N+1)/2) The factored form of the matrix A, stored as a packed triangular matrix. AFAC contains the block diagonal matrix D and the multipliers used to obtain the factor L or U from the block L*D*L' or U*D*U' factorization as computed by ZHPTRF.
[in]	IPIV	IPIV is INTEGER array, dimension (N) The pivot indices from ZHPTRF.
[out]	C	C is COMPLEX*16 array, dimension (LDC,N)
[in]	LDC	LDC is INTEGER The leading dimension of the array C. LDC >= max(1,N).
[out]	RWORK	RWORK is DOUBLE PRECISION array, dimension (N)
[out]	RESID	RESID is DOUBLE PRECISION If UPLO = 'L', norm(L*D*L' - A) / ( N * norm(A) * EPS ) If UPLO = 'U', norm(U*D*U' - A) / ( N * norm(A) * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 115 of file zhpt01.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            ldc, n
      DOUBLE PRECISION   resid
*     ..
*     .. Array Arguments ..
      INTEGER            ipiv( * )
      DOUBLE PRECISION   rwork( * )
      COMPLEX*16         a( * ), afac( * ), c( ldc, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter                ( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         czero, cone
      parameter                ( czero = ( 0.0d+0, 0.0d+0 ),
     $                   cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            i, info, j, jc
      DOUBLE PRECISION   anorm, eps
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      DOUBLE PRECISION   dlamch, zlanhe, zlanhp
      EXTERNAL           lsame, dlamch, zlanhe, zlanhp
*     ..
*     .. External Subroutines ..
      EXTERNAL           zlaset, zlavhp
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dimag
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     Determine EPS and the norm of A.
*
      eps = dlamch( 'Epsilon' )
      anorm = zlanhp( '1', uplo, n, a, rwork )
*
*     Check the imaginary parts of the diagonal elements and return with
*     an error code if any are nonzero.
*
      jc = 1
      IF( lsame( uplo, 'U' ) ) THEN
         DO 10 j = 1, n
            IF( dimag( afac( jc ) ).NE.zero ) THEN
               resid = one / eps
               RETURN
            END IF
            jc = jc + j + 1
   10    CONTINUE
      ELSE
         DO 20 j = 1, n
            IF( dimag( afac( jc ) ).NE.zero ) THEN
               resid = one / eps
               RETURN
            END IF
            jc = jc + n - j + 1
   20    CONTINUE
      END IF
*
*     Initialize C to the identity matrix.
*
      CALL zlaset( 'Full', n, n, czero, cone, c, ldc )
*
*     Call ZLAVHP to form the product D * U' (or D * L' ).
*
      CALL zlavhp( uplo, 'Conjugate', 'Non-unit', n, n, afac, ipiv, c,
     $             ldc, info )
*
*     Call ZLAVHP again to multiply by U ( or L ).
*
      CALL zlavhp( uplo, 'No transpose', 'Unit', n, n, afac, ipiv, c,
     $             ldc, info )
*
*     Compute the difference  C - A .
*
      IF( lsame( uplo, 'U' ) ) THEN
         jc = 0
         DO 40 j = 1, n
            DO 30 i = 1, j - 1
               c( i, j ) = c( i, j ) - a( jc+i )
   30       CONTINUE
            c( j, j ) = c( j, j ) - dble( a( jc+j ) )
            jc = jc + j
   40    CONTINUE
      ELSE
         jc = 1
         DO 60 j = 1, n
            c( j, j ) = c( j, j ) - dble( a( jc ) )
            DO 50 i = j + 1, n
               c( i, j ) = c( i, j ) - a( jc+i-j )
   50       CONTINUE
            jc = jc + n - j + 1
   60    CONTINUE
      END IF
*
*     Compute norm( C - A ) / ( N * norm(A) * EPS )
*
      resid = zlanhe( '1', uplo, n, c, ldc, rwork )
*
      IF( anorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         resid = ( ( resid / dble( n ) ) / anorm ) / eps
      END IF
*
      RETURN
*
*     End of ZHPT01
*

Here is the call graph for this function:

Here is the caller graph for this function: