subroutine zsyt02	(	character	UPLO,
		integer	N,
		integer	NRHS,
		complex*16, dimension( lda, * )	A,
		integer	LDA,
		complex*16, dimension( ldx, * )	X,
		integer	LDX,
		complex*16, dimension( ldb, * )	B,
		integer	LDB,
		double precision, dimension( * )	RWORK,
		double precision	RESID
	)

ZSYT02

Purpose:

 ZSYT02 computes the residual for a solution to a complex symmetric
 system of linear equations  A*x = b:

    RESID = norm(B - A*X) / ( norm(A) * norm(X) * EPS ),

 where EPS is the machine epsilon.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the symmetric matrix A is stored: = 'U': Upper triangular = 'L': Lower triangular
[in]	N	N is INTEGER The number of rows and columns of the matrix A. N >= 0.
[in]	NRHS	NRHS is INTEGER The number of columns of B, the matrix of right hand sides. NRHS >= 0.
[in]	A	A is COMPLEX*16 array, dimension (LDA,N) The original complex symmetric matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N)
[in]	X	X is COMPLEX*16 array, dimension (LDX,NRHS) The computed solution vectors for the system of linear equations.
[in]	LDX	LDX is INTEGER The leading dimension of the array X. LDX >= max(1,N).
[in,out]	B	B is COMPLEX*16 array, dimension (LDB,NRHS) On entry, the right hand side vectors for the system of linear equations. On exit, B is overwritten with the difference B - A*X.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).
[out]	RWORK	RWORK is DOUBLE PRECISION array, dimension (N)
[out]	RESID	RESID is DOUBLE PRECISION The maximum over the number of right hand sides of norm(B - A*X) / ( norm(A) * norm(X) * EPS ).

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 129 of file zsyt02.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            lda, ldb, ldx, n, nrhs
      DOUBLE PRECISION   resid
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   rwork( * )
      COMPLEX*16         a( lda, * ), b( ldb, * ), x( ldx, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter                ( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         cone
      parameter                ( cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            j
      DOUBLE PRECISION   anorm, bnorm, eps, xnorm
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch, dzasum, zlansy
      EXTERNAL           dlamch, dzasum, zlansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           zsymm
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0 or NRHS = 0
*
      IF( n.LE.0 .OR. nrhs.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0.
*
      eps = dlamch( 'Epsilon' )
      anorm = zlansy( '1', uplo, n, a, lda, rwork )
      IF( anorm.LE.zero ) THEN
         resid = one / eps
         RETURN
      END IF
*
*     Compute  B - A*X  (or  B - A'*X ) and store in B .
*
      CALL zsymm( 'Left', uplo, n, nrhs, -cone, a, lda, x, ldx, cone, b,
     $            ldb )
*
*     Compute the maximum over the number of right hand sides of
*        norm( B - A*X ) / ( norm(A) * norm(X) * EPS ) .
*
      resid = zero
      DO 10 j = 1, nrhs
         bnorm = dzasum( n, b( 1, j ), 1 )
         xnorm = dzasum( n, x( 1, j ), 1 )
         IF( xnorm.LE.zero ) THEN
            resid = one / eps
         ELSE
            resid = max( resid, ( ( bnorm / anorm ) / xnorm ) / eps )
         END IF
   10 CONTINUE
*
      RETURN
*
*     End of ZSYT02
*

Here is the call graph for this function:

Here is the caller graph for this function: