subroutine zlqt03	(	integer	M,
		integer	N,
		integer	K,
		complex*16, dimension( lda, * )	AF,
		complex*16, dimension( lda, * )	C,
		complex*16, dimension( lda, * )	CC,
		complex*16, dimension( lda, * )	Q,
		integer	LDA,
		complex*16, dimension( * )	TAU,
		complex*16, dimension( lwork )	WORK,
		integer	LWORK,
		double precision, dimension( * )	RWORK,
		double precision, dimension( * )	RESULT
	)

ZLQT03

Purpose:

 ZLQT03 tests ZUNMLQ, which computes Q*C, Q'*C, C*Q or C*Q'.

 ZLQT03 compares the results of a call to ZUNMLQ with the results of
 forming Q explicitly by a call to ZUNGLQ and then performing matrix
 multiplication by a call to ZGEMM.

Parameters

[in]	M	M is INTEGER The number of rows or columns of the matrix C; C is n-by-m if Q is applied from the left, or m-by-n if Q is applied from the right. M >= 0.
[in]	N	N is INTEGER The order of the orthogonal matrix Q. N >= 0.
[in]	K	K is INTEGER The number of elementary reflectors whose product defines the orthogonal matrix Q. N >= K >= 0.
[in]	AF	AF is COMPLEX*16 array, dimension (LDA,N) Details of the LQ factorization of an m-by-n matrix, as returned by ZGELQF. See CGELQF for further details.
[out]	C	C is COMPLEX*16 array, dimension (LDA,N)
[out]	CC	CC is COMPLEX*16 array, dimension (LDA,N)
[out]	Q	Q is COMPLEX*16 array, dimension (LDA,N)
[in]	LDA	LDA is INTEGER The leading dimension of the arrays AF, C, CC, and Q.
[in]	TAU	TAU is COMPLEX*16 array, dimension (min(M,N)) The scalar factors of the elementary reflectors corresponding to the LQ factorization in AF.
[out]	WORK	WORK is COMPLEX*16 array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The length of WORK. LWORK must be at least M, and should be M*NB, where NB is the blocksize for this environment.
[out]	RWORK	RWORK is DOUBLE PRECISION array, dimension (M)
[out]	RESULT	RESULT is DOUBLE PRECISION array, dimension (4) The test ratios compare two techniques for multiplying a random matrix C by an n-by-n orthogonal matrix Q. RESULT(1) = norm( Q*C - Q*C ) / ( N * norm(C) * EPS ) RESULT(2) = norm( C*Q - C*Q ) / ( N * norm(C) * EPS ) RESULT(3) = norm( Q'*C - Q'*C )/ ( N * norm(C) * EPS ) RESULT(4) = norm( C*Q' - C*Q' )/ ( N * norm(C) * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 138 of file zlqt03.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            k, lda, lwork, m, n
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   result( * ), rwork( * )
      COMPLEX*16         af( lda, * ), c( lda, * ), cc( lda, * ),
     $                   q( lda, * ), tau( * ), work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter                ( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         rogue
      parameter                ( rogue = ( -1.0d+10, -1.0d+10 ) )
*     ..
*     .. Local Scalars ..
      CHARACTER          side, trans
      INTEGER            info, iside, itrans, j, mc, nc
      DOUBLE PRECISION   cnorm, eps, resid
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      DOUBLE PRECISION   dlamch, zlange
      EXTERNAL           lsame, dlamch, zlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           zgemm, zlacpy, zlarnv, zlaset, zunglq, zunmlq
*     ..
*     .. Local Arrays ..
      INTEGER            iseed( 4 )
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dcmplx, max
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       srnamt
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseed / 1988, 1989, 1990, 1991 /
*     ..
*     .. Executable Statements ..
*
      eps = dlamch( 'Epsilon' )
*
*     Copy the first k rows of the factorization to the array Q
*
      CALL zlaset( 'Full', n, n, rogue, rogue, q, lda )
      CALL zlacpy( 'Upper', k, n-1, af( 1, 2 ), lda, q( 1, 2 ), lda )
*
*     Generate the n-by-n matrix Q
*
      srnamt = 'ZUNGLQ'
      CALL zunglq( n, n, k, q, lda, tau, work, lwork, info )
*
      DO 30 iside = 1, 2
         IF( iside.EQ.1 ) THEN
            side = 'L'
            mc = n
            nc = m
         ELSE
            side = 'R'
            mc = m
            nc = n
         END IF
*
*        Generate MC by NC matrix C
*
         DO 10 j = 1, nc
            CALL zlarnv( 2, iseed, mc, c( 1, j ) )
   10    CONTINUE
         cnorm = zlange( '1', mc, nc, c, lda, rwork )
         IF( cnorm.EQ.zero )
     $      cnorm = one
*
         DO 20 itrans = 1, 2
            IF( itrans.EQ.1 ) THEN
               trans = 'N'
            ELSE
               trans = 'C'
            END IF
*
*           Copy C
*
            CALL zlacpy( 'Full', mc, nc, c, lda, cc, lda )
*
*           Apply Q or Q' to C
*
            srnamt = 'ZUNMLQ'
            CALL zunmlq( side, trans, mc, nc, k, af, lda, tau, cc, lda,
     $                   work, lwork, info )
*
*           Form explicit product and subtract
*
            IF( lsame( side, 'L' ) ) THEN
               CALL zgemm( trans, 'No transpose', mc, nc, mc,
     $                     dcmplx( -one ), q, lda, c, lda,
     $                     dcmplx( one ), cc, lda )
            ELSE
               CALL zgemm( 'No transpose', trans, mc, nc, nc,
     $                     dcmplx( -one ), c, lda, q, lda,
     $                     dcmplx( one ), cc, lda )
            END IF
*
*           Compute error in the difference
*
            resid = zlange( '1', mc, nc, cc, lda, rwork )
            result( ( iside-1 )*2+itrans ) = resid /
     $         ( dble( max( 1, n ) )*cnorm*eps )
*
   20    CONTINUE
   30 CONTINUE
*
      RETURN
*
*     End of ZLQT03
*

Here is the call graph for this function:

Here is the caller graph for this function: