LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
zlansb.f
Go to the documentation of this file.
1 *> \brief \b ZLANSB returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a symmetric band matrix.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download ZLANSB + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlansb.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlansb.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlansb.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * DOUBLE PRECISION FUNCTION ZLANSB( NORM, UPLO, N, K, AB, LDAB,
22 * WORK )
23 *
24 * .. Scalar Arguments ..
25 * CHARACTER NORM, UPLO
26 * INTEGER K, LDAB, N
27 * ..
28 * .. Array Arguments ..
29 * DOUBLE PRECISION WORK( * )
30 * COMPLEX*16 AB( LDAB, * )
31 * ..
32 *
33 *
34 *> \par Purpose:
35 * =============
36 *>
37 *> \verbatim
38 *>
39 *> ZLANSB returns the value of the one norm, or the Frobenius norm, or
40 *> the infinity norm, or the element of largest absolute value of an
41 *> n by n symmetric band matrix A, with k super-diagonals.
42 *> \endverbatim
43 *>
44 *> \return ZLANSB
45 *> \verbatim
46 *>
47 *> ZLANSB = ( max(abs(A(i,j))), NORM = 'M' or 'm'
48 *> (
49 *> ( norm1(A), NORM = '1', 'O' or 'o'
50 *> (
51 *> ( normI(A), NORM = 'I' or 'i'
52 *> (
53 *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
54 *>
55 *> where norm1 denotes the one norm of a matrix (maximum column sum),
56 *> normI denotes the infinity norm of a matrix (maximum row sum) and
57 *> normF denotes the Frobenius norm of a matrix (square root of sum of
58 *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
59 *> \endverbatim
60 *
61 * Arguments:
62 * ==========
63 *
64 *> \param[in] NORM
65 *> \verbatim
66 *> NORM is CHARACTER*1
67 *> Specifies the value to be returned in ZLANSB as described
68 *> above.
69 *> \endverbatim
70 *>
71 *> \param[in] UPLO
72 *> \verbatim
73 *> UPLO is CHARACTER*1
74 *> Specifies whether the upper or lower triangular part of the
75 *> band matrix A is supplied.
76 *> = 'U': Upper triangular part is supplied
77 *> = 'L': Lower triangular part is supplied
78 *> \endverbatim
79 *>
80 *> \param[in] N
81 *> \verbatim
82 *> N is INTEGER
83 *> The order of the matrix A. N >= 0. When N = 0, ZLANSB is
84 *> set to zero.
85 *> \endverbatim
86 *>
87 *> \param[in] K
88 *> \verbatim
89 *> K is INTEGER
90 *> The number of super-diagonals or sub-diagonals of the
91 *> band matrix A. K >= 0.
92 *> \endverbatim
93 *>
94 *> \param[in] AB
95 *> \verbatim
96 *> AB is COMPLEX*16 array, dimension (LDAB,N)
97 *> The upper or lower triangle of the symmetric band matrix A,
98 *> stored in the first K+1 rows of AB. The j-th column of A is
99 *> stored in the j-th column of the array AB as follows:
100 *> if UPLO = 'U', AB(k+1+i-j,j) = A(i,j) for max(1,j-k)<=i<=j;
101 *> if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+k).
102 *> \endverbatim
103 *>
104 *> \param[in] LDAB
105 *> \verbatim
106 *> LDAB is INTEGER
107 *> The leading dimension of the array AB. LDAB >= K+1.
108 *> \endverbatim
109 *>
110 *> \param[out] WORK
111 *> \verbatim
112 *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
113 *> where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
114 *> WORK is not referenced.
115 *> \endverbatim
116 *
117 * Authors:
118 * ========
119 *
120 *> \author Univ. of Tennessee
121 *> \author Univ. of California Berkeley
122 *> \author Univ. of Colorado Denver
123 *> \author NAG Ltd.
124 *
125 *> \date September 2012
126 *
127 *> \ingroup complex16OTHERauxiliary
128 *
129 * =====================================================================
130  DOUBLE PRECISION FUNCTION zlansb( NORM, UPLO, N, K, AB, LDAB,
131  $ work )
132 *
133 * -- LAPACK auxiliary routine (version 3.4.2) --
134 * -- LAPACK is a software package provided by Univ. of Tennessee, --
135 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
136 * September 2012
137 *
138 * .. Scalar Arguments ..
139  CHARACTER NORM, UPLO
140  INTEGER K, LDAB, N
141 * ..
142 * .. Array Arguments ..
143  DOUBLE PRECISION WORK( * )
144  COMPLEX*16 AB( ldab, * )
145 * ..
146 *
147 * =====================================================================
148 *
149 * .. Parameters ..
150  DOUBLE PRECISION ONE, ZERO
151  parameter ( one = 1.0d+0, zero = 0.0d+0 )
152 * ..
153 * .. Local Scalars ..
154  INTEGER I, J, L
155  DOUBLE PRECISION ABSA, SCALE, SUM, VALUE
156 * ..
157 * .. External Functions ..
158  LOGICAL LSAME, DISNAN
159  EXTERNAL lsame, disnan
160 * ..
161 * .. External Subroutines ..
162  EXTERNAL zlassq
163 * ..
164 * .. Intrinsic Functions ..
165  INTRINSIC abs, max, min, sqrt
166 * ..
167 * .. Executable Statements ..
168 *
169  IF( n.EQ.0 ) THEN
170  VALUE = zero
171  ELSE IF( lsame( norm, 'M' ) ) THEN
172 *
173 * Find max(abs(A(i,j))).
174 *
175  VALUE = zero
176  IF( lsame( uplo, 'U' ) ) THEN
177  DO 20 j = 1, n
178  DO 10 i = max( k+2-j, 1 ), k + 1
179  sum = abs( ab( i, j ) )
180  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
181  10 CONTINUE
182  20 CONTINUE
183  ELSE
184  DO 40 j = 1, n
185  DO 30 i = 1, min( n+1-j, k+1 )
186  sum = abs( ab( i, j ) )
187  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
188  30 CONTINUE
189  40 CONTINUE
190  END IF
191  ELSE IF( ( lsame( norm, 'I' ) ) .OR. ( lsame( norm, 'O' ) ) .OR.
192  $ ( norm.EQ.'1' ) ) THEN
193 *
194 * Find normI(A) ( = norm1(A), since A is symmetric).
195 *
196  VALUE = zero
197  IF( lsame( uplo, 'U' ) ) THEN
198  DO 60 j = 1, n
199  sum = zero
200  l = k + 1 - j
201  DO 50 i = max( 1, j-k ), j - 1
202  absa = abs( ab( l+i, j ) )
203  sum = sum + absa
204  work( i ) = work( i ) + absa
205  50 CONTINUE
206  work( j ) = sum + abs( ab( k+1, j ) )
207  60 CONTINUE
208  DO 70 i = 1, n
209  sum = work( i )
210  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
211  70 CONTINUE
212  ELSE
213  DO 80 i = 1, n
214  work( i ) = zero
215  80 CONTINUE
216  DO 100 j = 1, n
217  sum = work( j ) + abs( ab( 1, j ) )
218  l = 1 - j
219  DO 90 i = j + 1, min( n, j+k )
220  absa = abs( ab( l+i, j ) )
221  sum = sum + absa
222  work( i ) = work( i ) + absa
223  90 CONTINUE
224  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
225  100 CONTINUE
226  END IF
227  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
228 *
229 * Find normF(A).
230 *
231  scale = zero
232  sum = one
233  IF( k.GT.0 ) THEN
234  IF( lsame( uplo, 'U' ) ) THEN
235  DO 110 j = 2, n
236  CALL zlassq( min( j-1, k ), ab( max( k+2-j, 1 ), j ),
237  $ 1, scale, sum )
238  110 CONTINUE
239  l = k + 1
240  ELSE
241  DO 120 j = 1, n - 1
242  CALL zlassq( min( n-j, k ), ab( 2, j ), 1, scale,
243  $ sum )
244  120 CONTINUE
245  l = 1
246  END IF
247  sum = 2*sum
248  ELSE
249  l = 1
250  END IF
251  CALL zlassq( n, ab( l, 1 ), ldab, scale, sum )
252  VALUE = scale*sqrt( sum )
253  END IF
254 *
255  zlansb = VALUE
256  RETURN
257 *
258 * End of ZLANSB
259 *
260  END
subroutine zlassq(N, X, INCX, SCALE, SUMSQ)
ZLASSQ updates a sum of squares represented in scaled form.
Definition: zlassq.f:108
double precision function zlansb(NORM, UPLO, N, K, AB, LDAB, WORK)
ZLANSB returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a symmetric band matrix.
Definition: zlansb.f:132