dchkpt.f

Go to the documentation of this file.

*> \brief \b DCHKPT
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE DCHKPT( DOTYPE, NN, NVAL, NNS, NSVAL, THRESH, TSTERR,
*                          A, D, E, B, X, XACT, WORK, RWORK, NOUT )
* 
*       .. Scalar Arguments ..
*       LOGICAL            TSTERR
*       INTEGER            NN, NNS, NOUT
*       DOUBLE PRECISION   THRESH
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * )
*       INTEGER            NSVAL( * ), NVAL( * )
*       DOUBLE PRECISION   A( * ), B( * ), D( * ), E( * ), RWORK( * ),
*      $                   WORK( * ), X( * ), XACT( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DCHKPT tests DPTTRF, -TRS, -RFS, and -CON
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          The matrix types to be used for testing.  Matrices of type j
*>          (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) =
*>          .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER
*>          The number of values of N contained in the vector NVAL.
*> \endverbatim
*>
*> \param[in] NVAL
*> \verbatim
*>          NVAL is INTEGER array, dimension (NN)
*>          The values of the matrix dimension N.
*> \endverbatim
*>
*> \param[in] NNS
*> \verbatim
*>          NNS is INTEGER
*>          The number of values of NRHS contained in the vector NSVAL.
*> \endverbatim
*>
*> \param[in] NSVAL
*> \verbatim
*>          NSVAL is INTEGER array, dimension (NNS)
*>          The values of the number of right hand sides NRHS.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is DOUBLE PRECISION
*>          The threshold value for the test ratios.  A result is
*>          included in the output file if RESULT >= THRESH.  To have
*>          every test ratio printed, use THRESH = 0.
*> \endverbatim
*>
*> \param[in] TSTERR
*> \verbatim
*>          TSTERR is LOGICAL
*>          Flag that indicates whether error exits are to be tested.
*> \endverbatim
*>
*> \param[out] A
*> \verbatim
*>          A is DOUBLE PRECISION array, dimension (NMAX*2)
*> \endverbatim
*>
*> \param[out] D
*> \verbatim
*>          D is DOUBLE PRECISION array, dimension (NMAX*2)
*> \endverbatim
*>
*> \param[out] E
*> \verbatim
*>          E is DOUBLE PRECISION array, dimension (NMAX*2)
*> \endverbatim
*>
*> \param[out] B
*> \verbatim
*>          B is DOUBLE PRECISION array, dimension (NMAX*NSMAX)
*>          where NSMAX is the largest entry in NSVAL.
*> \endverbatim
*>
*> \param[out] X
*> \verbatim
*>          X is DOUBLE PRECISION array, dimension (NMAX*NSMAX)
*> \endverbatim
*>
*> \param[out] XACT
*> \verbatim
*>          XACT is DOUBLE PRECISION array, dimension (NMAX*NSMAX)
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is DOUBLE PRECISION array, dimension
*>                      (NMAX*max(3,NSMAX))
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is DOUBLE PRECISION array, dimension
*>                      (max(NMAX,2*NSMAX))
*> \endverbatim
*>
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>          The unit number for output.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup double_lin
*
*  =====================================================================
      SUBROUTINE dchkpt( DOTYPE, NN, NVAL, NNS, NSVAL, THRESH, TSTERR,
     $                   a, d, e, b, x, xact, work, rwork, nout )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NN, NNS, NOUT
      DOUBLE PRECISION   THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            NSVAL( * ), NVAL( * )
      DOUBLE PRECISION   A( * ), B( * ), D( * ), E( * ), RWORK( * ),
     $                   work( * ), x( * ), xact( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter                ( one = 1.0d+0, zero = 0.0d+0 )
      INTEGER            NTYPES
      parameter                ( ntypes = 12 )
      INTEGER            NTESTS
      parameter                ( ntests = 7 )
*     ..
*     .. Local Scalars ..
      LOGICAL            ZEROT
      CHARACTER          DIST, TYPE
      CHARACTER*3        PATH
      INTEGER            I, IA, IMAT, IN, INFO, IRHS, IX, IZERO, J, K,
     $                   kl, ku, lda, mode, n, nerrs, nfail, nimat,
     $                   nrhs, nrun
      DOUBLE PRECISION   AINVNM, ANORM, COND, DMAX, RCOND, RCONDC
*     ..
*     .. Local Arrays ..
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      DOUBLE PRECISION   RESULT( ntests ), Z( 3 )
*     ..
*     .. External Functions ..
      INTEGER            IDAMAX
      DOUBLE PRECISION   DASUM, DGET06, DLANST
      EXTERNAL           idamax, dasum, dget06, dlanst
*     ..
*     .. External Subroutines ..
      EXTERNAL           alaerh, alahd, alasum, dcopy, derrgt, dget04,
     $                   dlacpy, dlaptm, dlarnv, dlatb4, dlatms, dptcon,
     $                   dptrfs, dptt01, dptt02, dptt05, dpttrf, dpttrs,
     $                   dscal
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseedy / 0, 0, 0, 1 /
*     ..
*     .. Executable Statements ..
*
      path( 1: 1 ) = 'Double precision'
      path( 2: 3 ) = 'PT'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL derrgt( path, nout )
      infot = 0
*
      DO 110 in = 1, nn
*
*        Do for each value of N in NVAL.
*
         n = nval( in )
         lda = max( 1, n )
         nimat = ntypes
         IF( n.LE.0 )
     $      nimat = 1
*
         DO 100 imat = 1, nimat
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( n.GT.0 .AND. .NOT.dotype( imat ) )
     $         GO TO 100
*
*           Set up parameters with DLATB4.
*
            CALL dlatb4( path, imat, n, n, TYPE, KL, KU, ANORM, MODE,
     $                   cond, dist )
*
            zerot = imat.GE.8 .AND. imat.LE.10
            IF( imat.LE.6 ) THEN
*
*              Type 1-6:  generate a symmetric tridiagonal matrix of
*              known condition number in lower triangular band storage.
*
               srnamt = 'DLATMS'
               CALL dlatms( n, n, dist, iseed, TYPE, RWORK, MODE, COND,
     $                      anorm, kl, ku, 'B', a, 2, work, info )
*
*              Check the error code from DLATMS.
*
               IF( info.NE.0 ) THEN
                  CALL alaerh( path, 'DLATMS', info, 0, ' ', n, n, kl,
     $                         ku, -1, imat, nfail, nerrs, nout )
                  GO TO 100
               END IF
               izero = 0
*
*              Copy the matrix to D and E.
*
               ia = 1
               DO 20 i = 1, n - 1
                  d( i ) = a( ia )
                  e( i ) = a( ia+1 )
                  ia = ia + 2
   20          CONTINUE
               IF( n.GT.0 )
     $            d( n ) = a( ia )
            ELSE
*
*              Type 7-12:  generate a diagonally dominant matrix with
*              unknown condition number in the vectors D and E.
*
               IF( .NOT.zerot .OR. .NOT.dotype( 7 ) ) THEN
*
*                 Let D and E have values from [-1,1].
*
                  CALL dlarnv( 2, iseed, n, d )
                  CALL dlarnv( 2, iseed, n-1, e )
*
*                 Make the tridiagonal matrix diagonally dominant.
*
                  IF( n.EQ.1 ) THEN
                     d( 1 ) = abs( d( 1 ) )
                  ELSE
                     d( 1 ) = abs( d( 1 ) ) + abs( e( 1 ) )
                     d( n ) = abs( d( n ) ) + abs( e( n-1 ) )
                     DO 30 i = 2, n - 1
                        d( i ) = abs( d( i ) ) + abs( e( i ) ) +
     $                           abs( e( i-1 ) )
   30                CONTINUE
                  END IF
*
*                 Scale D and E so the maximum element is ANORM.
*
                  ix = idamax( n, d, 1 )
                  dmax = d( ix )
                  CALL dscal( n, anorm / dmax, d, 1 )
                  CALL dscal( n-1, anorm / dmax, e, 1 )
*
               ELSE IF( izero.GT.0 ) THEN
*
*                 Reuse the last matrix by copying back the zeroed out
*                 elements.
*
                  IF( izero.EQ.1 ) THEN
                     d( 1 ) = z( 2 )
                     IF( n.GT.1 )
     $                  e( 1 ) = z( 3 )
                  ELSE IF( izero.EQ.n ) THEN
                     e( n-1 ) = z( 1 )
                     d( n ) = z( 2 )
                  ELSE
                     e( izero-1 ) = z( 1 )
                     d( izero ) = z( 2 )
                     e( izero ) = z( 3 )
                  END IF
               END IF
*
*              For types 8-10, set one row and column of the matrix to
*              zero.
*
               izero = 0
               IF( imat.EQ.8 ) THEN
                  izero = 1
                  z( 2 ) = d( 1 )
                  d( 1 ) = zero
                  IF( n.GT.1 ) THEN
                     z( 3 ) = e( 1 )
                     e( 1 ) = zero
                  END IF
               ELSE IF( imat.EQ.9 ) THEN
                  izero = n
                  IF( n.GT.1 ) THEN
                     z( 1 ) = e( n-1 )
                     e( n-1 ) = zero
                  END IF
                  z( 2 ) = d( n )
                  d( n ) = zero
               ELSE IF( imat.EQ.10 ) THEN
                  izero = ( n+1 ) / 2
                  IF( izero.GT.1 ) THEN
                     z( 1 ) = e( izero-1 )
                     e( izero-1 ) = zero
                     z( 3 ) = e( izero )
                     e( izero ) = zero
                  END IF
                  z( 2 ) = d( izero )
                  d( izero ) = zero
               END IF
            END IF
*
            CALL dcopy( n, d, 1, d( n+1 ), 1 )
            IF( n.GT.1 )
     $         CALL dcopy( n-1, e, 1, e( n+1 ), 1 )
*
*+    TEST 1
*           Factor A as L*D*L' and compute the ratio
*              norm(L*D*L' - A) / (n * norm(A) * EPS )
*
            CALL dpttrf( n, d( n+1 ), e( n+1 ), info )
*
*           Check error code from DPTTRF.
*
            IF( info.NE.izero ) THEN
               CALL alaerh( path, 'DPTTRF', info, izero, ' ', n, n, -1,
     $                      -1, -1, imat, nfail, nerrs, nout )
               GO TO 100
            END IF
*
            IF( info.GT.0 ) THEN
               rcondc = zero
               GO TO 90
            END IF
*
            CALL dptt01( n, d, e, d( n+1 ), e( n+1 ), work,
     $                   result( 1 ) )
*
*           Print the test ratio if greater than or equal to THRESH.
*
            IF( result( 1 ).GE.thresh ) THEN
               IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $            CALL alahd( nout, path )
               WRITE( nout, fmt = 9999 )n, imat, 1, result( 1 )
               nfail = nfail + 1
            END IF
            nrun = nrun + 1
*
*           Compute RCONDC = 1 / (norm(A) * norm(inv(A))
*
*           Compute norm(A).
*
            anorm = dlanst( '1', n, d, e )
*
*           Use DPTTRS to solve for one column at a time of inv(A),
*           computing the maximum column sum as we go.
*
            ainvnm = zero
            DO 50 i = 1, n
               DO 40 j = 1, n
                  x( j ) = zero
   40          CONTINUE
               x( i ) = one
               CALL dpttrs( n, 1, d( n+1 ), e( n+1 ), x, lda, info )
               ainvnm = max( ainvnm, dasum( n, x, 1 ) )
   50       CONTINUE
            rcondc = one / max( one, anorm*ainvnm )
*
            DO 80 irhs = 1, nns
               nrhs = nsval( irhs )
*
*           Generate NRHS random solution vectors.
*
               ix = 1
               DO 60 j = 1, nrhs
                  CALL dlarnv( 2, iseed, n, xact( ix ) )
                  ix = ix + lda
   60          CONTINUE
*
*           Set the right hand side.
*
               CALL dlaptm( n, nrhs, one, d, e, xact, lda, zero, b,
     $                      lda )
*
*+    TEST 2
*           Solve A*x = b and compute the residual.
*
               CALL dlacpy( 'Full', n, nrhs, b, lda, x, lda )
               CALL dpttrs( n, nrhs, d( n+1 ), e( n+1 ), x, lda, info )
*
*           Check error code from DPTTRS.
*
               IF( info.NE.0 )
     $            CALL alaerh( path, 'DPTTRS', info, 0, ' ', n, n, -1,
     $                         -1, nrhs, imat, nfail, nerrs, nout )
*
               CALL dlacpy( 'Full', n, nrhs, b, lda, work, lda )
               CALL dptt02( n, nrhs, d, e, x, lda, work, lda,
     $                      result( 2 ) )
*
*+    TEST 3
*           Check solution from generated exact solution.
*
               CALL dget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                      result( 3 ) )
*
*+    TESTS 4, 5, and 6
*           Use iterative refinement to improve the solution.
*
               srnamt = 'DPTRFS'
               CALL dptrfs( n, nrhs, d, e, d( n+1 ), e( n+1 ), b, lda,
     $                      x, lda, rwork, rwork( nrhs+1 ), work, info )
*
*           Check error code from DPTRFS.
*
               IF( info.NE.0 )
     $            CALL alaerh( path, 'DPTRFS', info, 0, ' ', n, n, -1,
     $                         -1, nrhs, imat, nfail, nerrs, nout )
*
               CALL dget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                      result( 4 ) )
               CALL dptt05( n, nrhs, d, e, b, lda, x, lda, xact, lda,
     $                      rwork, rwork( nrhs+1 ), result( 5 ) )
*
*           Print information about the tests that did not pass the
*           threshold.
*
               DO 70 k = 2, 6
                  IF( result( k ).GE.thresh ) THEN
                     IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                  CALL alahd( nout, path )
                     WRITE( nout, fmt = 9998 )n, nrhs, imat, k,
     $                  result( k )
                     nfail = nfail + 1
                  END IF
   70          CONTINUE
               nrun = nrun + 5
   80       CONTINUE
*
*+    TEST 7
*           Estimate the reciprocal of the condition number of the
*           matrix.
*
   90       CONTINUE
            srnamt = 'DPTCON'
            CALL dptcon( n, d( n+1 ), e( n+1 ), anorm, rcond, rwork,
     $                   info )
*
*           Check error code from DPTCON.
*
            IF( info.NE.0 )
     $         CALL alaerh( path, 'DPTCON', info, 0, ' ', n, n, -1, -1,
     $                      -1, imat, nfail, nerrs, nout )
*
            result( 7 ) = dget06( rcond, rcondc )
*
*           Print the test ratio if greater than or equal to THRESH.
*
            IF( result( 7 ).GE.thresh ) THEN
               IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $            CALL alahd( nout, path )
               WRITE( nout, fmt = 9999 )n, imat, 7, result( 7 )
               nfail = nfail + 1
            END IF
            nrun = nrun + 1
  100    CONTINUE
  110 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( ' N =', i5, ', type ', i2, ', test ', i2, ', ratio = ',
     $      g12.5 )
 9998 FORMAT( ' N =', i5, ', NRHS=', i3, ', type ', i2, ', test(', i2,
     $      ') = ', g12.5 )
      RETURN
*
*     End of DCHKPT
*
      END