LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
cungqr.f
Go to the documentation of this file.
1 *> \brief \b CUNGQR
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download CUNGQR + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cungqr.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cungqr.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cungqr.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE CUNGQR( M, N, K, A, LDA, TAU, WORK, LWORK, INFO )
22 *
23 * .. Scalar Arguments ..
24 * INTEGER INFO, K, LDA, LWORK, M, N
25 * ..
26 * .. Array Arguments ..
27 * COMPLEX A( LDA, * ), TAU( * ), WORK( * )
28 * ..
29 *
30 *
31 *> \par Purpose:
32 * =============
33 *>
34 *> \verbatim
35 *>
36 *> CUNGQR generates an M-by-N complex matrix Q with orthonormal columns,
37 *> which is defined as the first N columns of a product of K elementary
38 *> reflectors of order M
39 *>
40 *> Q = H(1) H(2) . . . H(k)
41 *>
42 *> as returned by CGEQRF.
43 *> \endverbatim
44 *
45 * Arguments:
46 * ==========
47 *
48 *> \param[in] M
49 *> \verbatim
50 *> M is INTEGER
51 *> The number of rows of the matrix Q. M >= 0.
52 *> \endverbatim
53 *>
54 *> \param[in] N
55 *> \verbatim
56 *> N is INTEGER
57 *> The number of columns of the matrix Q. M >= N >= 0.
58 *> \endverbatim
59 *>
60 *> \param[in] K
61 *> \verbatim
62 *> K is INTEGER
63 *> The number of elementary reflectors whose product defines the
64 *> matrix Q. N >= K >= 0.
65 *> \endverbatim
66 *>
67 *> \param[in,out] A
68 *> \verbatim
69 *> A is COMPLEX array, dimension (LDA,N)
70 *> On entry, the i-th column must contain the vector which
71 *> defines the elementary reflector H(i), for i = 1,2,...,k, as
72 *> returned by CGEQRF in the first k columns of its array
73 *> argument A.
74 *> On exit, the M-by-N matrix Q.
75 *> \endverbatim
76 *>
77 *> \param[in] LDA
78 *> \verbatim
79 *> LDA is INTEGER
80 *> The first dimension of the array A. LDA >= max(1,M).
81 *> \endverbatim
82 *>
83 *> \param[in] TAU
84 *> \verbatim
85 *> TAU is COMPLEX array, dimension (K)
86 *> TAU(i) must contain the scalar factor of the elementary
87 *> reflector H(i), as returned by CGEQRF.
88 *> \endverbatim
89 *>
90 *> \param[out] WORK
91 *> \verbatim
92 *> WORK is COMPLEX array, dimension (MAX(1,LWORK))
93 *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
94 *> \endverbatim
95 *>
96 *> \param[in] LWORK
97 *> \verbatim
98 *> LWORK is INTEGER
99 *> The dimension of the array WORK. LWORK >= max(1,N).
100 *> For optimum performance LWORK >= N*NB, where NB is the
101 *> optimal blocksize.
102 *>
103 *> If LWORK = -1, then a workspace query is assumed; the routine
104 *> only calculates the optimal size of the WORK array, returns
105 *> this value as the first entry of the WORK array, and no error
106 *> message related to LWORK is issued by XERBLA.
107 *> \endverbatim
108 *>
109 *> \param[out] INFO
110 *> \verbatim
111 *> INFO is INTEGER
112 *> = 0: successful exit
113 *> < 0: if INFO = -i, the i-th argument has an illegal value
114 *> \endverbatim
115 *
116 * Authors:
117 * ========
118 *
119 *> \author Univ. of Tennessee
120 *> \author Univ. of California Berkeley
121 *> \author Univ. of Colorado Denver
122 *> \author NAG Ltd.
123 *
124 *> \date November 2011
125 *
126 *> \ingroup complexOTHERcomputational
127 *
128 * =====================================================================
129  SUBROUTINE cungqr( M, N, K, A, LDA, TAU, WORK, LWORK, INFO )
130 *
131 * -- LAPACK computational routine (version 3.4.0) --
132 * -- LAPACK is a software package provided by Univ. of Tennessee, --
133 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
134 * November 2011
135 *
136 * .. Scalar Arguments ..
137  INTEGER INFO, K, LDA, LWORK, M, N
138 * ..
139 * .. Array Arguments ..
140  COMPLEX A( lda, * ), TAU( * ), WORK( * )
141 * ..
142 *
143 * =====================================================================
144 *
145 * .. Parameters ..
146  COMPLEX ZERO
147  parameter ( zero = ( 0.0e+0, 0.0e+0 ) )
148 * ..
149 * .. Local Scalars ..
150  LOGICAL LQUERY
151  INTEGER I, IB, IINFO, IWS, J, KI, KK, L, LDWORK,
152  $ lwkopt, nb, nbmin, nx
153 * ..
154 * .. External Subroutines ..
155  EXTERNAL clarfb, clarft, cung2r, xerbla
156 * ..
157 * .. Intrinsic Functions ..
158  INTRINSIC max, min
159 * ..
160 * .. External Functions ..
161  INTEGER ILAENV
162  EXTERNAL ilaenv
163 * ..
164 * .. Executable Statements ..
165 *
166 * Test the input arguments
167 *
168  info = 0
169  nb = ilaenv( 1, 'CUNGQR', ' ', m, n, k, -1 )
170  lwkopt = max( 1, n )*nb
171  work( 1 ) = lwkopt
172  lquery = ( lwork.EQ.-1 )
173  IF( m.LT.0 ) THEN
174  info = -1
175  ELSE IF( n.LT.0 .OR. n.GT.m ) THEN
176  info = -2
177  ELSE IF( k.LT.0 .OR. k.GT.n ) THEN
178  info = -3
179  ELSE IF( lda.LT.max( 1, m ) ) THEN
180  info = -5
181  ELSE IF( lwork.LT.max( 1, n ) .AND. .NOT.lquery ) THEN
182  info = -8
183  END IF
184  IF( info.NE.0 ) THEN
185  CALL xerbla( 'CUNGQR', -info )
186  RETURN
187  ELSE IF( lquery ) THEN
188  RETURN
189  END IF
190 *
191 * Quick return if possible
192 *
193  IF( n.LE.0 ) THEN
194  work( 1 ) = 1
195  RETURN
196  END IF
197 *
198  nbmin = 2
199  nx = 0
200  iws = n
201  IF( nb.GT.1 .AND. nb.LT.k ) THEN
202 *
203 * Determine when to cross over from blocked to unblocked code.
204 *
205  nx = max( 0, ilaenv( 3, 'CUNGQR', ' ', m, n, k, -1 ) )
206  IF( nx.LT.k ) THEN
207 *
208 * Determine if workspace is large enough for blocked code.
209 *
210  ldwork = n
211  iws = ldwork*nb
212  IF( lwork.LT.iws ) THEN
213 *
214 * Not enough workspace to use optimal NB: reduce NB and
215 * determine the minimum value of NB.
216 *
217  nb = lwork / ldwork
218  nbmin = max( 2, ilaenv( 2, 'CUNGQR', ' ', m, n, k, -1 ) )
219  END IF
220  END IF
221  END IF
222 *
223  IF( nb.GE.nbmin .AND. nb.LT.k .AND. nx.LT.k ) THEN
224 *
225 * Use blocked code after the last block.
226 * The first kk columns are handled by the block method.
227 *
228  ki = ( ( k-nx-1 ) / nb )*nb
229  kk = min( k, ki+nb )
230 *
231 * Set A(1:kk,kk+1:n) to zero.
232 *
233  DO 20 j = kk + 1, n
234  DO 10 i = 1, kk
235  a( i, j ) = zero
236  10 CONTINUE
237  20 CONTINUE
238  ELSE
239  kk = 0
240  END IF
241 *
242 * Use unblocked code for the last or only block.
243 *
244  IF( kk.LT.n )
245  $ CALL cung2r( m-kk, n-kk, k-kk, a( kk+1, kk+1 ), lda,
246  $ tau( kk+1 ), work, iinfo )
247 *
248  IF( kk.GT.0 ) THEN
249 *
250 * Use blocked code
251 *
252  DO 50 i = ki + 1, 1, -nb
253  ib = min( nb, k-i+1 )
254  IF( i+ib.LE.n ) THEN
255 *
256 * Form the triangular factor of the block reflector
257 * H = H(i) H(i+1) . . . H(i+ib-1)
258 *
259  CALL clarft( 'Forward', 'Columnwise', m-i+1, ib,
260  $ a( i, i ), lda, tau( i ), work, ldwork )
261 *
262 * Apply H to A(i:m,i+ib:n) from the left
263 *
264  CALL clarfb( 'Left', 'No transpose', 'Forward',
265  $ 'Columnwise', m-i+1, n-i-ib+1, ib,
266  $ a( i, i ), lda, work, ldwork, a( i, i+ib ),
267  $ lda, work( ib+1 ), ldwork )
268  END IF
269 *
270 * Apply H to rows i:m of current block
271 *
272  CALL cung2r( m-i+1, ib, ib, a( i, i ), lda, tau( i ), work,
273  $ iinfo )
274 *
275 * Set rows 1:i-1 of current block to zero
276 *
277  DO 40 j = i, i + ib - 1
278  DO 30 l = 1, i - 1
279  a( l, j ) = zero
280  30 CONTINUE
281  40 CONTINUE
282  50 CONTINUE
283  END IF
284 *
285  work( 1 ) = iws
286  RETURN
287 *
288 * End of CUNGQR
289 *
290  END
subroutine clarft(DIRECT, STOREV, N, K, V, LDV, TAU, T, LDT)
CLARFT forms the triangular factor T of a block reflector H = I - vtvH
Definition: clarft.f:165
subroutine cung2r(M, N, K, A, LDA, TAU, WORK, INFO)
CUNG2R
Definition: cung2r.f:116
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine cungqr(M, N, K, A, LDA, TAU, WORK, LWORK, INFO)
CUNGQR
Definition: cungqr.f:130
subroutine clarfb(SIDE, TRANS, DIRECT, STOREV, M, N, K, V, LDV, T, LDT, C, LDC, WORK, LDWORK)
CLARFB applies a block reflector or its conjugate-transpose to a general rectangular matrix...
Definition: clarfb.f:197