double precision function dqpt01	(	integer	M,
		integer	N,
		integer	K,
		double precision, dimension( lda, * )	A,
		double precision, dimension( lda, * )	AF,
		integer	LDA,
		double precision, dimension( * )	TAU,
		integer, dimension( * )	JPVT,
		double precision, dimension( lwork )	WORK,
		integer	LWORK
	)

DQPT01

Purpose:

 DQPT01 tests the QR-factorization with pivoting of a matrix A.  The
 array AF contains the (possibly partial) QR-factorization of A, where
 the upper triangle of AF(1:k,1:k) is a partial triangular factor,
 the entries below the diagonal in the first k columns are the
 Householder vectors, and the rest of AF contains a partially updated
 matrix.

 This function returns ||A*P - Q*R||/(||norm(A)||*eps*M)

Parameters

[in]	M	M is INTEGER The number of rows of the matrices A and AF.
[in]	N	N is INTEGER The number of columns of the matrices A and AF.
[in]	K	K is INTEGER The number of columns of AF that have been reduced to upper triangular form.
[in]	A	A is DOUBLE PRECISION array, dimension (LDA, N) The original matrix A.
[in]	AF	AF is DOUBLE PRECISION array, dimension (LDA,N) The (possibly partial) output of DGEQPF. The upper triangle of AF(1:k,1:k) is a partial triangular factor, the entries below the diagonal in the first k columns are the Householder vectors, and the rest of AF contains a partially updated matrix.
[in]	LDA	LDA is INTEGER The leading dimension of the arrays A and AF.
[in]	TAU	TAU is DOUBLE PRECISION array, dimension (K) Details of the Householder transformations as returned by DGEQPF.
[in]	JPVT	JPVT is INTEGER array, dimension (N) Pivot information as returned by DGEQPF.
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The length of the array WORK. LWORK >= M*N+N.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 122 of file dqpt01.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            k, lda, lwork, m, n
*     ..
*     .. Array Arguments ..
      INTEGER            jpvt( * )
      DOUBLE PRECISION   a( lda, * ), af( lda, * ), tau( * ),
     $                   work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter                ( zero = 0.0d0, one = 1.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, info, j
      DOUBLE PRECISION   norma
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   rwork( 1 )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch, dlange
      EXTERNAL           dlamch, dlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           daxpy, dcopy, dormqr, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max, min
*     ..
*     .. Executable Statements ..
*
      dqpt01 = zero
*
*     Test if there is enough workspace
*
      IF( lwork.LT.m*n+n ) THEN
         CALL xerbla( 'DQPT01', 10 )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.LE.0 .OR. n.LE.0 )
     $   RETURN
*
      norma = dlange( 'One-norm', m, n, a, lda, rwork )
*
      DO 30 j = 1, k
         DO 10 i = 1, min( j, m )
            work( ( j-1 )*m+i ) = af( i, j )
   10    CONTINUE
         DO 20 i = j + 1, m
            work( ( j-1 )*m+i ) = zero
   20    CONTINUE
   30 CONTINUE
      DO 40 j = k + 1, n
         CALL dcopy( m, af( 1, j ), 1, work( ( j-1 )*m+1 ), 1 )
   40 CONTINUE
*
      CALL dormqr( 'Left', 'No transpose', m, n, k, af, lda, tau, work,
     $             m, work( m*n+1 ), lwork-m*n, info )
*
      DO 50 j = 1, n
*
*        Compare i-th column of QR and jpvt(i)-th column of A
*
         CALL daxpy( m, -one, a( 1, jpvt( j ) ), 1, work( ( j-1 )*m+1 ),
     $               1 )
   50 CONTINUE
*
      dqpt01 = dlange( 'One-norm', m, n, work, m, rwork ) /
     $         ( dble( max( m, n ) )*dlamch( 'Epsilon' ) )
      IF( norma.NE.zero )
     $   dqpt01 = dqpt01 / norma
*
      RETURN
*
*     End of DQPT01
*

Here is the call graph for this function: