double precision function zlangt	(	character	NORM,
		integer	N,
		complex*16, dimension( * )	DL,
		complex*16, dimension( * )	D,
		complex*16, dimension( * )	DU
	)

ZLANGT returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of a general tridiagonal matrix.

Download ZLANGT + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZLANGT  returns the value of the one norm,  or the Frobenius norm, or
 the  infinity norm,  or the  element of  largest absolute value  of a
 complex tridiagonal matrix A.

Returns

ZLANGT

    ZLANGT = ( max(abs(A(i,j))), NORM = 'M' or 'm'
             (
             ( norm1(A),         NORM = '1', 'O' or 'o'
             (
             ( normI(A),         NORM = 'I' or 'i'
             (
             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'

 where  norm1  denotes the  one norm of a matrix (maximum column sum),
 normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
 normF  denotes the  Frobenius norm of a matrix (square root of sum of
 squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.

Parameters

[in]	NORM	NORM is CHARACTER*1 Specifies the value to be returned in ZLANGT as described above.
[in]	N	N is INTEGER The order of the matrix A. N >= 0. When N = 0, ZLANGT is set to zero.
[in]	DL	DL is COMPLEX*16 array, dimension (N-1) The (n-1) sub-diagonal elements of A.
[in]	D	D is COMPLEX*16 array, dimension (N) The diagonal elements of A.
[in]	DU	DU is COMPLEX*16 array, dimension (N-1) The (n-1) super-diagonal elements of A.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

September 2012

Definition at line 108 of file zlangt.f.

*
*  -- LAPACK auxiliary routine (version 3.4.2) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     September 2012
*
*     .. Scalar Arguments ..
      CHARACTER          norm
      INTEGER            n
*     ..
*     .. Array Arguments ..
      COMPLEX*16         d( * ), dl( * ), du( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   one, zero
      parameter                ( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i
      DOUBLE PRECISION   anorm, scale, sum, temp
*     ..
*     .. External Functions ..
      LOGICAL            lsame, disnan
      EXTERNAL           lsame, disnan
*     ..
*     .. External Subroutines ..
      EXTERNAL           zlassq
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, sqrt
*     ..
*     .. Executable Statements ..
*
      IF( n.LE.0 ) THEN
         anorm = zero
      ELSE IF( lsame( norm, 'M' ) ) THEN
*
*        Find max(abs(A(i,j))).
*
         anorm = abs( d( n ) )
         DO 10 i = 1, n - 1
            IF( anorm.LT.abs( dl( i ) ) .OR. disnan( abs( dl( i ) ) ) ) 
     $           anorm = abs(dl(i))
            IF( anorm.LT.abs( d( i ) ) .OR. disnan( abs( d( i ) ) ) ) 
     $           anorm = abs(d(i))
            IF( anorm.LT.abs( du( i ) ) .OR. disnan(abs( du( i ) ) ) ) 
     $           anorm = abs(du(i))
   10    CONTINUE
      ELSE IF( lsame( norm, 'O' ) .OR. norm.EQ.'1' ) THEN
*
*        Find norm1(A).
*
         IF( n.EQ.1 ) THEN
            anorm = abs( d( 1 ) )
         ELSE
            anorm = abs( d( 1 ) )+abs( dl( 1 ) )
            temp = abs( d( n ) )+abs( du( n-1 ) ) 
            IF( anorm .LT. temp .OR. disnan( temp ) ) anorm = temp
            DO 20 i = 2, n - 1
               temp = abs( d( i ) )+abs( dl( i ) )+abs( du( i-1 ) )
               IF( anorm .LT. temp .OR. disnan( temp ) ) anorm = temp
   20       CONTINUE
         END IF
      ELSE IF( lsame( norm, 'I' ) ) THEN
*
*        Find normI(A).
*
         IF( n.EQ.1 ) THEN
            anorm = abs( d( 1 ) )
         ELSE
            anorm = abs( d( 1 ) )+abs( du( 1 ) )
            temp = abs( d( n ) )+abs( dl( n-1 ) )
            IF( anorm .LT. temp .OR. disnan( temp ) ) anorm = temp
            DO 30 i = 2, n - 1
               temp = abs( d( i ) )+abs( du( i ) )+abs( dl( i-1 ) )
               IF( anorm .LT. temp .OR. disnan( temp ) ) anorm = temp
   30       CONTINUE
         END IF
      ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
*
*        Find normF(A).
*
         scale = zero
         sum = one
         CALL zlassq( n, d, 1, scale, sum )
         IF( n.GT.1 ) THEN
            CALL zlassq( n-1, dl, 1, scale, sum )
            CALL zlassq( n-1, du, 1, scale, sum )
         END IF
         anorm = scale*sqrt( sum )
      END IF
*
      zlangt = anorm
      RETURN
*
*     End of ZLANGT
*

Here is the call graph for this function: