subroutine clatrz	(	integer	M,
		integer	N,
		integer	L,
		complex, dimension( lda, * )	A,
		integer	LDA,
		complex, dimension( * )	TAU,
		complex, dimension( * )	WORK
	)

CLATRZ factors an upper trapezoidal matrix by means of unitary transformations.

Download CLATRZ + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CLATRZ factors the M-by-(M+L) complex upper trapezoidal matrix
 [ A1 A2 ] = [ A(1:M,1:M) A(1:M,N-L+1:N) ] as ( R  0 ) * Z by means
 of unitary transformations, where  Z is an (M+L)-by-(M+L) unitary
 matrix and, R and A1 are M-by-M upper triangular matrices.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix A. N >= 0.
[in]	L	L is INTEGER The number of columns of the matrix A containing the meaningful part of the Householder vectors. N-M >= L >= 0.
[in,out]	A	A is COMPLEX array, dimension (LDA,N) On entry, the leading M-by-N upper trapezoidal part of the array A must contain the matrix to be factorized. On exit, the leading M-by-M upper triangular part of A contains the upper triangular matrix R, and elements N-L+1 to N of the first M rows of A, with the array TAU, represent the unitary matrix Z as a product of M elementary reflectors.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).
[out]	TAU	TAU is COMPLEX array, dimension (M) The scalar factors of the elementary reflectors.
[out]	WORK	WORK is COMPLEX array, dimension (M)

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

September 2012

Contributors:

A. Petitet, Computer Science Dept., Univ. of Tenn., Knoxville, USA

Further Details:

  The factorization is obtained by Householder's method.  The kth
  transformation matrix, Z( k ), which is used to introduce zeros into
  the ( m - k + 1 )th row of A, is given in the form

     Z( k ) = ( I     0   ),
              ( 0  T( k ) )

  where

     T( k ) = I - tau*u( k )*u( k )**H,   u( k ) = (   1    ),
                                                 (   0    )
                                                 ( z( k ) )

  tau is a scalar and z( k ) is an l element vector. tau and z( k )
  are chosen to annihilate the elements of the kth row of A2.

  The scalar tau is returned in the kth element of TAU and the vector
  u( k ) in the kth row of A2, such that the elements of z( k ) are
  in  a( k, l + 1 ), ..., a( k, n ). The elements of R are returned in
  the upper triangular part of A1.

  Z is given by

     Z =  Z( 1 ) * Z( 2 ) * ... * Z( m ).

Definition at line 142 of file clatrz.f.

*
*  -- LAPACK computational routine (version 3.4.2) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     September 2012
*
*     .. Scalar Arguments ..
      INTEGER            l, lda, m, n
*     ..
*     .. Array Arguments ..
      COMPLEX            a( lda, * ), tau( * ), work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            zero
      parameter                ( zero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            i
      COMPLEX            alpha
*     ..
*     .. External Subroutines ..
      EXTERNAL           clacgv, clarfg, clarz
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          conjg
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( m.EQ.0 ) THEN
         RETURN
      ELSE IF( m.EQ.n ) THEN
         DO 10 i = 1, n
            tau( i ) = zero
   10    CONTINUE
         RETURN
      END IF
*
      DO 20 i = m, 1, -1
*
*        Generate elementary reflector H(i) to annihilate
*        [ A(i,i) A(i,n-l+1:n) ]
*
         CALL clacgv( l, a( i, n-l+1 ), lda )
         alpha = conjg( a( i, i ) )
         CALL clarfg( l+1, alpha, a( i, n-l+1 ), lda, tau( i ) )
         tau( i ) = conjg( tau( i ) )
*
*        Apply H(i) to A(1:i-1,i:n) from the right
*
         CALL clarz( 'Right', i-1, n-i+1, l, a( i, n-l+1 ), lda,
     $               conjg( tau( i ) ), a( 1, i ), lda, work )
         a( i, i ) = conjg( alpha )
*
   20 CONTINUE
*
      RETURN
*
*     End of CLATRZ
*

Here is the call graph for this function:

Here is the caller graph for this function: