cspr.f

Go to the documentation of this file.

*> \brief \b CSPR performs the symmetrical rank-1 update of a complex symmetric packed matrix.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*> \htmlonly
*> Download CSPR + dependencies 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cspr.f"> 
*> [TGZ]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cspr.f"> 
*> [ZIP]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cspr.f"> 
*> [TXT]</a>
*> \endhtmlonly 
*
*  Definition:
*  ===========
*
*       SUBROUTINE CSPR( UPLO, N, ALPHA, X, INCX, AP )
* 
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            INCX, N
*       COMPLEX            ALPHA
*       ..
*       .. Array Arguments ..
*       COMPLEX            AP( * ), X( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CSPR    performs the symmetric rank 1 operation
*>
*>    A := alpha*x*x**H + A,
*>
*> where alpha is a complex scalar, x is an n element vector and A is an
*> n by n symmetric matrix, supplied in packed form.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>           On entry, UPLO specifies whether the upper or lower
*>           triangular part of the matrix A is supplied in the packed
*>           array AP as follows:
*>
*>              UPLO = 'U' or 'u'   The upper triangular part of A is
*>                                  supplied in AP.
*>
*>              UPLO = 'L' or 'l'   The lower triangular part of A is
*>                                  supplied in AP.
*>
*>           Unchanged on exit.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>           On entry, N specifies the order of the matrix A.
*>           N must be at least zero.
*>           Unchanged on exit.
*> \endverbatim
*>
*> \param[in] ALPHA
*> \verbatim
*>          ALPHA is COMPLEX
*>           On entry, ALPHA specifies the scalar alpha.
*>           Unchanged on exit.
*> \endverbatim
*>
*> \param[in] X
*> \verbatim
*>          X is COMPLEX array, dimension at least
*>           ( 1 + ( N - 1 )*abs( INCX ) ).
*>           Before entry, the incremented array X must contain the N-
*>           element vector x.
*>           Unchanged on exit.
*> \endverbatim
*>
*> \param[in] INCX
*> \verbatim
*>          INCX is INTEGER
*>           On entry, INCX specifies the increment for the elements of
*>           X. INCX must not be zero.
*>           Unchanged on exit.
*> \endverbatim
*>
*> \param[in,out] AP
*> \verbatim
*>          AP is COMPLEX array, dimension at least
*>           ( ( N*( N + 1 ) )/2 ).
*>           Before entry, with  UPLO = 'U' or 'u', the array AP must
*>           contain the upper triangular part of the symmetric matrix
*>           packed sequentially, column by column, so that AP( 1 )
*>           contains a( 1, 1 ), AP( 2 ) and AP( 3 ) contain a( 1, 2 )
*>           and a( 2, 2 ) respectively, and so on. On exit, the array
*>           AP is overwritten by the upper triangular part of the
*>           updated matrix.
*>           Before entry, with UPLO = 'L' or 'l', the array AP must
*>           contain the lower triangular part of the symmetric matrix
*>           packed sequentially, column by column, so that AP( 1 )
*>           contains a( 1, 1 ), AP( 2 ) and AP( 3 ) contain a( 2, 1 )
*>           and a( 3, 1 ) respectively, and so on. On exit, the array
*>           AP is overwritten by the lower triangular part of the
*>           updated matrix.
*>           Note that the imaginary parts of the diagonal elements need
*>           not be set, they are assumed to be zero, and on exit they
*>           are set to zero.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date September 2012
*
*> \ingroup complexOTHERauxiliary
*
*  =====================================================================
      SUBROUTINE cspr( UPLO, N, ALPHA, X, INCX, AP )
*
*  -- LAPACK auxiliary routine (version 3.4.2) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     September 2012
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INCX, N
      COMPLEX            ALPHA
*     ..
*     .. Array Arguments ..
      COMPLEX            AP( * ), X( * )
*     ..
*
* =====================================================================
*
*     .. Parameters ..
      COMPLEX            ZERO
      parameter                ( zero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, INFO, IX, J, JX, K, KK, KX
      COMPLEX            TEMP
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF( .NOT.lsame( uplo, 'U' ) .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = 1
      ELSE IF( n.LT.0 ) THEN
         info = 2
      ELSE IF( incx.EQ.0 ) THEN
         info = 5
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CSPR  ', info )
         RETURN
      END IF
*
*     Quick return if possible.
*
      IF( ( n.EQ.0 ) .OR. ( alpha.EQ.zero ) )
     $   RETURN
*
*     Set the start point in X if the increment is not unity.
*
      IF( incx.LE.0 ) THEN
         kx = 1 - ( n-1 )*incx
      ELSE IF( incx.NE.1 ) THEN
         kx = 1
      END IF
*
*     Start the operations. In this version the elements of the array AP
*     are accessed sequentially with one pass through AP.
*
      kk = 1
      IF( lsame( uplo, 'U' ) ) THEN
*
*        Form  A  when upper triangle is stored in AP.
*
         IF( incx.EQ.1 ) THEN
            DO 20 j = 1, n
               IF( x( j ).NE.zero ) THEN
                  temp = alpha*x( j )
                  k = kk
                  DO 10 i = 1, j - 1
                     ap( k ) = ap( k ) + x( i )*temp
                     k = k + 1
   10             CONTINUE
                  ap( kk+j-1 ) = ap( kk+j-1 ) + x( j )*temp
               ELSE
                  ap( kk+j-1 ) = ap( kk+j-1 )
               END IF
               kk = kk + j
   20       CONTINUE
         ELSE
            jx = kx
            DO 40 j = 1, n
               IF( x( jx ).NE.zero ) THEN
                  temp = alpha*x( jx )
                  ix = kx
                  DO 30 k = kk, kk + j - 2
                     ap( k ) = ap( k ) + x( ix )*temp
                     ix = ix + incx
   30             CONTINUE
                  ap( kk+j-1 ) = ap( kk+j-1 ) + x( jx )*temp
               ELSE
                  ap( kk+j-1 ) = ap( kk+j-1 )
               END IF
               jx = jx + incx
               kk = kk + j
   40       CONTINUE
         END IF
      ELSE
*
*        Form  A  when lower triangle is stored in AP.
*
         IF( incx.EQ.1 ) THEN
            DO 60 j = 1, n
               IF( x( j ).NE.zero ) THEN
                  temp = alpha*x( j )
                  ap( kk ) = ap( kk ) + temp*x( j )
                  k = kk + 1
                  DO 50 i = j + 1, n
                     ap( k ) = ap( k ) + x( i )*temp
                     k = k + 1
   50             CONTINUE
               ELSE
                  ap( kk ) = ap( kk )
               END IF
               kk = kk + n - j + 1
   60       CONTINUE
         ELSE
            jx = kx
            DO 80 j = 1, n
               IF( x( jx ).NE.zero ) THEN
                  temp = alpha*x( jx )
                  ap( kk ) = ap( kk ) + temp*x( jx )
                  ix = jx
                  DO 70 k = kk + 1, kk + n - j
                     ix = ix + incx
                     ap( k ) = ap( k ) + x( ix )*temp
   70             CONTINUE
               ELSE
                  ap( kk ) = ap( kk )
               END IF
               jx = jx + incx
               kk = kk + n - j + 1
   80       CONTINUE
         END IF
      END IF
*
      RETURN
*
*     End of CSPR
*
      END