LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
sla_porpvgrw.f
Go to the documentation of this file.
1 *> \brief \b SLA_PORPVGRW computes the reciprocal pivot growth factor norm(A)/norm(U) for a symmetric or Hermitian positive-definite matrix.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download SLA_PORPVGRW + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sla_porpvgrw.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sla_porpvgrw.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sla_porpvgrw.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * REAL FUNCTION SLA_PORPVGRW( UPLO, NCOLS, A, LDA, AF, LDAF, WORK )
22 *
23 * .. Scalar Arguments ..
24 * CHARACTER*1 UPLO
25 * INTEGER NCOLS, LDA, LDAF
26 * ..
27 * .. Array Arguments ..
28 * REAL A( LDA, * ), AF( LDAF, * ), WORK( * )
29 * ..
30 *
31 *
32 *> \par Purpose:
33 * =============
34 *>
35 *> \verbatim
36 *>
37 *>
38 *> SLA_PORPVGRW computes the reciprocal pivot growth factor
39 *> norm(A)/norm(U). The "max absolute element" norm is used. If this is
40 *> much less than 1, the stability of the LU factorization of the
41 *> (equilibrated) matrix A could be poor. This also means that the
42 *> solution X, estimated condition numbers, and error bounds could be
43 *> unreliable.
44 *> \endverbatim
45 *
46 * Arguments:
47 * ==========
48 *
49 *> \param[in] UPLO
50 *> \verbatim
51 *> UPLO is CHARACTER*1
52 *> = 'U': Upper triangle of A is stored;
53 *> = 'L': Lower triangle of A is stored.
54 *> \endverbatim
55 *>
56 *> \param[in] NCOLS
57 *> \verbatim
58 *> NCOLS is INTEGER
59 *> The number of columns of the matrix A. NCOLS >= 0.
60 *> \endverbatim
61 *>
62 *> \param[in] A
63 *> \verbatim
64 *> A is REAL array, dimension (LDA,N)
65 *> On entry, the N-by-N matrix A.
66 *> \endverbatim
67 *>
68 *> \param[in] LDA
69 *> \verbatim
70 *> LDA is INTEGER
71 *> The leading dimension of the array A. LDA >= max(1,N).
72 *> \endverbatim
73 *>
74 *> \param[in] AF
75 *> \verbatim
76 *> AF is REAL array, dimension (LDAF,N)
77 *> The triangular factor U or L from the Cholesky factorization
78 *> A = U**T*U or A = L*L**T, as computed by SPOTRF.
79 *> \endverbatim
80 *>
81 *> \param[in] LDAF
82 *> \verbatim
83 *> LDAF is INTEGER
84 *> The leading dimension of the array AF. LDAF >= max(1,N).
85 *> \endverbatim
86 *>
87 *> \param[in] WORK
88 *> \verbatim
89 *> WORK is REAL array, dimension (2*N)
90 *> \endverbatim
91 *
92 * Authors:
93 * ========
94 *
95 *> \author Univ. of Tennessee
96 *> \author Univ. of California Berkeley
97 *> \author Univ. of Colorado Denver
98 *> \author NAG Ltd.
99 *
100 *> \date September 2012
101 *
102 *> \ingroup realPOcomputational
103 *
104 * =====================================================================
105  REAL FUNCTION sla_porpvgrw( UPLO, NCOLS, A, LDA, AF, LDAF, WORK )
106 *
107 * -- LAPACK computational routine (version 3.4.2) --
108 * -- LAPACK is a software package provided by Univ. of Tennessee, --
109 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
110 * September 2012
111 *
112 * .. Scalar Arguments ..
113  CHARACTER*1 UPLO
114  INTEGER NCOLS, LDA, LDAF
115 * ..
116 * .. Array Arguments ..
117  REAL A( lda, * ), AF( ldaf, * ), WORK( * )
118 * ..
119 *
120 * =====================================================================
121 *
122 * .. Local Scalars ..
123  INTEGER I, J
124  REAL AMAX, UMAX, RPVGRW
125  LOGICAL UPPER
126 * ..
127 * .. Intrinsic Functions ..
128  INTRINSIC abs, max, min
129 * ..
130 * .. External Functions ..
131  EXTERNAL lsame, slaset
132  LOGICAL LSAME
133 * ..
134 * .. Executable Statements ..
135 *
136  upper = lsame( 'Upper', uplo )
137 *
138 * SPOTRF will have factored only the NCOLSxNCOLS leading minor, so
139 * we restrict the growth search to that minor and use only the first
140 * 2*NCOLS workspace entries.
141 *
142  rpvgrw = 1.0
143  DO i = 1, 2*ncols
144  work( i ) = 0.0
145  END DO
146 *
147 * Find the max magnitude entry of each column.
148 *
149  IF ( upper ) THEN
150  DO j = 1, ncols
151  DO i = 1, j
152  work( ncols+j ) =
153  $ max( abs( a( i, j ) ), work( ncols+j ) )
154  END DO
155  END DO
156  ELSE
157  DO j = 1, ncols
158  DO i = j, ncols
159  work( ncols+j ) =
160  $ max( abs( a( i, j ) ), work( ncols+j ) )
161  END DO
162  END DO
163  END IF
164 *
165 * Now find the max magnitude entry of each column of the factor in
166 * AF. No pivoting, so no permutations.
167 *
168  IF ( lsame( 'Upper', uplo ) ) THEN
169  DO j = 1, ncols
170  DO i = 1, j
171  work( j ) = max( abs( af( i, j ) ), work( j ) )
172  END DO
173  END DO
174  ELSE
175  DO j = 1, ncols
176  DO i = j, ncols
177  work( j ) = max( abs( af( i, j ) ), work( j ) )
178  END DO
179  END DO
180  END IF
181 *
182 * Compute the *inverse* of the max element growth factor. Dividing
183 * by zero would imply the largest entry of the factor's column is
184 * zero. Than can happen when either the column of A is zero or
185 * massive pivots made the factor underflow to zero. Neither counts
186 * as growth in itself, so simply ignore terms with zero
187 * denominators.
188 *
189  IF ( lsame( 'Upper', uplo ) ) THEN
190  DO i = 1, ncols
191  umax = work( i )
192  amax = work( ncols+i )
193  IF ( umax /= 0.0 ) THEN
194  rpvgrw = min( amax / umax, rpvgrw )
195  END IF
196  END DO
197  ELSE
198  DO i = 1, ncols
199  umax = work( i )
200  amax = work( ncols+i )
201  IF ( umax /= 0.0 ) THEN
202  rpvgrw = min( amax / umax, rpvgrw )
203  END IF
204  END DO
205  END IF
206 
207  sla_porpvgrw = rpvgrw
208  END
subroutine slaset(UPLO, M, N, ALPHA, BETA, A, LDA)
SLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values...
Definition: slaset.f:112
real function sla_porpvgrw(UPLO, NCOLS, A, LDA, AF, LDAF, WORK)
SLA_PORPVGRW computes the reciprocal pivot growth factor norm(A)/norm(U) for a symmetric or Hermitian...
Definition: sla_porpvgrw.f:106
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55