sstt22.f

Go to the documentation of this file.

*> \brief \b SSTT22
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE SSTT22( N, M, KBAND, AD, AE, SD, SE, U, LDU, WORK,
*                          LDWORK, RESULT )
* 
*       .. Scalar Arguments ..
*       INTEGER            KBAND, LDU, LDWORK, M, N
*       ..
*       .. Array Arguments ..
*       REAL               AD( * ), AE( * ), RESULT( 2 ), SD( * ),
*      $                   SE( * ), U( LDU, * ), WORK( LDWORK, * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SSTT22  checks a set of M eigenvalues and eigenvectors,
*>
*>     A U = U S
*>
*> where A is symmetric tridiagonal, the columns of U are orthogonal,
*> and S is diagonal (if KBAND=0) or symmetric tridiagonal (if KBAND=1).
*> Two tests are performed:
*>
*>    RESULT(1) = | U' A U - S | / ( |A| m ulp )
*>
*>    RESULT(2) = | I - U'U | / ( m ulp )
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The size of the matrix.  If it is zero, SSTT22 does nothing.
*>          It must be at least zero.
*> \endverbatim
*>
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of eigenpairs to check.  If it is zero, SSTT22
*>          does nothing.  It must be at least zero.
*> \endverbatim
*>
*> \param[in] KBAND
*> \verbatim
*>          KBAND is INTEGER
*>          The bandwidth of the matrix S.  It may only be zero or one.
*>          If zero, then S is diagonal, and SE is not referenced.  If
*>          one, then S is symmetric tri-diagonal.
*> \endverbatim
*>
*> \param[in] AD
*> \verbatim
*>          AD is REAL array, dimension (N)
*>          The diagonal of the original (unfactored) matrix A.  A is
*>          assumed to be symmetric tridiagonal.
*> \endverbatim
*>
*> \param[in] AE
*> \verbatim
*>          AE is REAL array, dimension (N)
*>          The off-diagonal of the original (unfactored) matrix A.  A
*>          is assumed to be symmetric tridiagonal.  AE(1) is ignored,
*>          AE(2) is the (1,2) and (2,1) element, etc.
*> \endverbatim
*>
*> \param[in] SD
*> \verbatim
*>          SD is REAL array, dimension (N)
*>          The diagonal of the (symmetric tri-) diagonal matrix S.
*> \endverbatim
*>
*> \param[in] SE
*> \verbatim
*>          SE is REAL array, dimension (N)
*>          The off-diagonal of the (symmetric tri-) diagonal matrix S.
*>          Not referenced if KBSND=0.  If KBAND=1, then AE(1) is
*>          ignored, SE(2) is the (1,2) and (2,1) element, etc.
*> \endverbatim
*>
*> \param[in] U
*> \verbatim
*>          U is REAL array, dimension (LDU, N)
*>          The orthogonal matrix in the decomposition.
*> \endverbatim
*>
*> \param[in] LDU
*> \verbatim
*>          LDU is INTEGER
*>          The leading dimension of U.  LDU must be at least N.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (LDWORK, M+1)
*> \endverbatim
*>
*> \param[in] LDWORK
*> \verbatim
*>          LDWORK is INTEGER
*>          The leading dimension of WORK.  LDWORK must be at least
*>          max(1,M).
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is REAL array, dimension (2)
*>          The values computed by the two tests described above.  The
*>          values are currently limited to 1/ulp, to avoid overflow.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup single_eig
*
*  =====================================================================
      SUBROUTINE sstt22( N, M, KBAND, AD, AE, SD, SE, U, LDU, WORK,
     $                   ldwork, result )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            KBAND, LDU, LDWORK, M, N
*     ..
*     .. Array Arguments ..
      REAL               AD( * ), AE( * ), RESULT( 2 ), SD( * ),
     $                   se( * ), u( ldu, * ), work( ldwork, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter                ( zero = 0.0e0, one = 1.0e0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J, K
      REAL               ANORM, AUKJ, ULP, UNFL, WNORM
*     ..
*     .. External Functions ..
      REAL               SLAMCH, SLANGE, SLANSY
      EXTERNAL           slamch, slange, slansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min, real
*     ..
*     .. Executable Statements ..
*
      result( 1 ) = zero
      result( 2 ) = zero
      IF( n.LE.0 .OR. m.LE.0 )
     $   RETURN
*
      unfl = slamch( 'Safe minimum' )
      ulp = slamch( 'Epsilon' )
*
*     Do Test 1
*
*     Compute the 1-norm of A.
*
      IF( n.GT.1 ) THEN
         anorm = abs( ad( 1 ) ) + abs( ae( 1 ) )
         DO 10 j = 2, n - 1
            anorm = max( anorm, abs( ad( j ) )+abs( ae( j ) )+
     $              abs( ae( j-1 ) ) )
   10    CONTINUE
         anorm = max( anorm, abs( ad( n ) )+abs( ae( n-1 ) ) )
      ELSE
         anorm = abs( ad( 1 ) )
      END IF
      anorm = max( anorm, unfl )
*
*     Norm of U'AU - S
*
      DO 40 i = 1, m
         DO 30 j = 1, m
            work( i, j ) = zero
            DO 20 k = 1, n
               aukj = ad( k )*u( k, j )
               IF( k.NE.n )
     $            aukj = aukj + ae( k )*u( k+1, j )
               IF( k.NE.1 )
     $            aukj = aukj + ae( k-1 )*u( k-1, j )
               work( i, j ) = work( i, j ) + u( k, i )*aukj
   20       CONTINUE
   30    CONTINUE
         work( i, i ) = work( i, i ) - sd( i )
         IF( kband.EQ.1 ) THEN
            IF( i.NE.1 )
     $         work( i, i-1 ) = work( i, i-1 ) - se( i-1 )
            IF( i.NE.n )
     $         work( i, i+1 ) = work( i, i+1 ) - se( i )
         END IF
   40 CONTINUE
*
      wnorm = slansy( '1', 'L', m, work, m, work( 1, m+1 ) )
*
      IF( anorm.GT.wnorm ) THEN
         result( 1 ) = ( wnorm / anorm ) / ( m*ulp )
      ELSE
         IF( anorm.LT.one ) THEN
            result( 1 ) = ( min( wnorm, m*anorm ) / anorm ) / ( m*ulp )
         ELSE
            result( 1 ) = min( wnorm / anorm, REAL( M ) ) / ( M*ULP )
         END IF
      END IF
*
*     Do Test 2
*
*     Compute  U'U - I
*
      CALL sgemm( 'T', 'N', m, m, n, one, u, ldu, u, ldu, zero, work,
     $            m )
*
      DO 50 j = 1, m
         work( j, j ) = work( j, j ) - one
   50 CONTINUE
*
      result( 2 ) = min( REAL( M ), SLANGE( '1', m, m, work, m, work( 1,
     $              m+1 ) ) ) / ( m*ulp )
*
      RETURN
*
*     End of SSTT22
*
      END