drqt01.f

Go to the documentation of this file.

*> \brief \b DRQT01
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE DRQT01( M, N, A, AF, Q, R, LDA, TAU, WORK, LWORK,
*                          RWORK, RESULT )
* 
*       .. Scalar Arguments ..
*       INTEGER            LDA, LWORK, M, N
*       ..
*       .. Array Arguments ..
*       DOUBLE PRECISION   A( LDA, * ), AF( LDA, * ), Q( LDA, * ),
*      $                   R( LDA, * ), RESULT( * ), RWORK( * ), TAU( * ),
*      $                   WORK( LWORK )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DRQT01 tests DGERQF, which computes the RQ factorization of an m-by-n
*> matrix A, and partially tests DORGRQ which forms the n-by-n
*> orthogonal matrix Q.
*>
*> DRQT01 compares R with A*Q', and checks that Q is orthogonal.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix A.  M >= 0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is DOUBLE PRECISION array, dimension (LDA,N)
*>          The m-by-n matrix A.
*> \endverbatim
*>
*> \param[out] AF
*> \verbatim
*>          AF is DOUBLE PRECISION array, dimension (LDA,N)
*>          Details of the RQ factorization of A, as returned by DGERQF.
*>          See DGERQF for further details.
*> \endverbatim
*>
*> \param[out] Q
*> \verbatim
*>          Q is DOUBLE PRECISION array, dimension (LDA,N)
*>          The n-by-n orthogonal matrix Q.
*> \endverbatim
*>
*> \param[out] R
*> \verbatim
*>          R is DOUBLE PRECISION array, dimension (LDA,max(M,N))
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the arrays A, AF, Q and L.
*>          LDA >= max(M,N).
*> \endverbatim
*>
*> \param[out] TAU
*> \verbatim
*>          TAU is DOUBLE PRECISION array, dimension (min(M,N))
*>          The scalar factors of the elementary reflectors, as returned
*>          by DGERQF.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is DOUBLE PRECISION array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The dimension of the array WORK.
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is DOUBLE PRECISION array, dimension (max(M,N))
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is DOUBLE PRECISION array, dimension (2)
*>          The test ratios:
*>          RESULT(1) = norm( R - A*Q' ) / ( N * norm(A) * EPS )
*>          RESULT(2) = norm( I - Q*Q' ) / ( N * EPS )
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup double_lin
*
*  =====================================================================
      SUBROUTINE drqt01( M, N, A, AF, Q, R, LDA, TAU, WORK, LWORK,
     $                   rwork, result )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( lda, * ), AF( lda, * ), Q( lda, * ),
     $                   r( lda, * ), result( * ), rwork( * ), tau( * ),
     $                   work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter                ( zero = 0.0d+0, one = 1.0d+0 )
      DOUBLE PRECISION   ROGUE
      parameter                ( rogue = -1.0d+10 )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO, MINMN
      DOUBLE PRECISION   ANORM, EPS, RESID
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, DLANGE, DLANSY
      EXTERNAL           dlamch, dlange, dlansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemm, dgerqf, dlacpy, dlaset, dorgrq, dsyrk
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max, min
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       SRNAMT
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
      minmn = min( m, n )
      eps = dlamch( 'Epsilon' )
*
*     Copy the matrix A to the array AF.
*
      CALL dlacpy( 'Full', m, n, a, lda, af, lda )
*
*     Factorize the matrix A in the array AF.
*
      srnamt = 'DGERQF'
      CALL dgerqf( m, n, af, lda, tau, work, lwork, info )
*
*     Copy details of Q
*
      CALL dlaset( 'Full', n, n, rogue, rogue, q, lda )
      IF( m.LE.n ) THEN
         IF( m.GT.0 .AND. m.LT.n )
     $      CALL dlacpy( 'Full', m, n-m, af, lda, q( n-m+1, 1 ), lda )
         IF( m.GT.1 )
     $      CALL dlacpy( 'Lower', m-1, m-1, af( 2, n-m+1 ), lda,
     $                   q( n-m+2, n-m+1 ), lda )
      ELSE
         IF( n.GT.1 )
     $      CALL dlacpy( 'Lower', n-1, n-1, af( m-n+2, 1 ), lda,
     $                   q( 2, 1 ), lda )
      END IF
*
*     Generate the n-by-n matrix Q
*
      srnamt = 'DORGRQ'
      CALL dorgrq( n, n, minmn, q, lda, tau, work, lwork, info )
*
*     Copy R
*
      CALL dlaset( 'Full', m, n, zero, zero, r, lda )
      IF( m.LE.n ) THEN
         IF( m.GT.0 )
     $      CALL dlacpy( 'Upper', m, m, af( 1, n-m+1 ), lda,
     $                   r( 1, n-m+1 ), lda )
      ELSE
         IF( m.GT.n .AND. n.GT.0 )
     $      CALL dlacpy( 'Full', m-n, n, af, lda, r, lda )
         IF( n.GT.0 )
     $      CALL dlacpy( 'Upper', n, n, af( m-n+1, 1 ), lda,
     $                   r( m-n+1, 1 ), lda )
      END IF
*
*     Compute R - A*Q'
*
      CALL dgemm( 'No transpose', 'Transpose', m, n, n, -one, a, lda, q,
     $            lda, one, r, lda )
*
*     Compute norm( R - Q'*A ) / ( N * norm(A) * EPS ) .
*
      anorm = dlange( '1', m, n, a, lda, rwork )
      resid = dlange( '1', m, n, r, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / dble( max( 1, n ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q*Q'
*
      CALL dlaset( 'Full', n, n, zero, one, r, lda )
      CALL dsyrk( 'Upper', 'No transpose', n, n, -one, q, lda, one, r,
     $            lda )
*
*     Compute norm( I - Q*Q' ) / ( N * EPS ) .
*
      resid = dlansy( '1', 'Upper', n, r, lda, rwork )
*
      result( 2 ) = ( resid / dble( max( 1, n ) ) ) / eps
*
      RETURN
*
*     End of DRQT01
*
      END