subroutine zlaqhb	(	character	UPLO,
		integer	N,
		integer	KD,
		complex*16, dimension( ldab, * )	AB,
		integer	LDAB,
		double precision, dimension( * )	S,
		double precision	SCOND,
		double precision	AMAX,
		character	EQUED
	)

ZLAQHB scales a Hermitian band matrix, using scaling factors computed by cpbequ.

Download ZLAQHB + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZLAQHB equilibrates a Hermitian band matrix A 
 using the scaling factors in the vector S.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the symmetric matrix A is stored. = 'U': Upper triangular = 'L': Lower triangular
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	KD	KD is INTEGER The number of super-diagonals of the matrix A if UPLO = 'U', or the number of sub-diagonals if UPLO = 'L'. KD >= 0.
[in,out]	AB	AB is COMPLEX*16 array, dimension (LDAB,N) On entry, the upper or lower triangle of the symmetric band matrix A, stored in the first KD+1 rows of the array. The j-th column of A is stored in the j-th column of the array AB as follows: if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j; if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+kd). On exit, if INFO = 0, the triangular factor U or L from the Cholesky factorization A = U**H *U or A = L*L**H of the band matrix A, in the same storage format as A.
[in]	LDAB	LDAB is INTEGER The leading dimension of the array AB. LDAB >= KD+1.
[out]	S	S is DOUBLE PRECISION array, dimension (N) The scale factors for A.
[in]	SCOND	SCOND is DOUBLE PRECISION Ratio of the smallest S(i) to the largest S(i).
[in]	AMAX	AMAX is DOUBLE PRECISION Absolute value of largest matrix entry.
[out]	EQUED	EQUED is CHARACTER*1 Specifies whether or not equilibration was done. = 'N': No equilibration. = 'Y': Equilibration was done, i.e., A has been replaced by diag(S) * A * diag(S).

Internal Parameters:

  THRESH is a threshold value used to decide if scaling should be done
  based on the ratio of the scaling factors.  If SCOND < THRESH,
  scaling is done.

  LARGE and SMALL are threshold values used to decide if scaling should
  be done based on the absolute size of the largest matrix element.
  If AMAX > LARGE or AMAX < SMALL, scaling is done.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

September 2012

Definition at line 143 of file zlaqhb.f.

*
*  -- LAPACK auxiliary routine (version 3.4.2) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     September 2012
*
*     .. Scalar Arguments ..
      CHARACTER          equed, uplo
      INTEGER            kd, ldab, n
      DOUBLE PRECISION   amax, scond
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   s( * )
      COMPLEX*16         ab( ldab, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   one, thresh
      parameter                ( one = 1.0d+0, thresh = 0.1d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, j
      DOUBLE PRECISION   cj, large, small
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      DOUBLE PRECISION   dlamch
      EXTERNAL           lsame, dlamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max, min
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( n.LE.0 ) THEN
         equed = 'N'
         RETURN
      END IF
*
*     Initialize LARGE and SMALL.
*
      small = dlamch( 'Safe minimum' ) / dlamch( 'Precision' )
      large = one / small
*
      IF( scond.GE.thresh .AND. amax.GE.small .AND. amax.LE.large ) THEN
*
*        No equilibration
*
         equed = 'N'
      ELSE
*
*        Replace A by diag(S) * A * diag(S).
*
         IF( lsame( uplo, 'U' ) ) THEN
*
*           Upper triangle of A is stored in band format.
*
            DO 20 j = 1, n
               cj = s( j )
               DO 10 i = max( 1, j-kd ), j - 1
                  ab( kd+1+i-j, j ) = cj*s( i )*ab( kd+1+i-j, j )
   10          CONTINUE
               ab( kd+1, j ) = cj*cj*dble( ab( kd+1, j ) )
   20       CONTINUE
         ELSE
*
*           Lower triangle of A is stored.
*
            DO 40 j = 1, n
               cj = s( j )
               ab( 1, j ) = cj*cj*dble( ab( 1, j ) )
               DO 30 i = j + 1, min( n, j+kd )
                  ab( 1+i-j, j ) = cj*s( i )*ab( 1+i-j, j )
   30          CONTINUE
   40       CONTINUE
         END IF
         equed = 'Y'
      END IF
*
      RETURN
*
*     End of ZLAQHB
*

Here is the caller graph for this function: