dtbsv.f

Go to the documentation of this file.

*> \brief \b DTBSV
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE DTBSV(UPLO,TRANS,DIAG,N,K,A,LDA,X,INCX)
* 
*       .. Scalar Arguments ..
*       INTEGER INCX,K,LDA,N
*       CHARACTER DIAG,TRANS,UPLO
*       ..
*       .. Array Arguments ..
*       DOUBLE PRECISION A(LDA,*),X(*)
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DTBSV  solves one of the systems of equations
*>
*>    A*x = b,   or   A**T*x = b,
*>
*> where b and x are n element vectors and A is an n by n unit, or
*> non-unit, upper or lower triangular band matrix, with ( k + 1 )
*> diagonals.
*>
*> No test for singularity or near-singularity is included in this
*> routine. Such tests must be performed before calling this routine.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>           On entry, UPLO specifies whether the matrix is an upper or
*>           lower triangular matrix as follows:
*>
*>              UPLO = 'U' or 'u'   A is an upper triangular matrix.
*>
*>              UPLO = 'L' or 'l'   A is a lower triangular matrix.
*> \endverbatim
*>
*> \param[in] TRANS
*> \verbatim
*>          TRANS is CHARACTER*1
*>           On entry, TRANS specifies the equations to be solved as
*>           follows:
*>
*>              TRANS = 'N' or 'n'   A*x = b.
*>
*>              TRANS = 'T' or 't'   A**T*x = b.
*>
*>              TRANS = 'C' or 'c'   A**T*x = b.
*> \endverbatim
*>
*> \param[in] DIAG
*> \verbatim
*>          DIAG is CHARACTER*1
*>           On entry, DIAG specifies whether or not A is unit
*>           triangular as follows:
*>
*>              DIAG = 'U' or 'u'   A is assumed to be unit triangular.
*>
*>              DIAG = 'N' or 'n'   A is not assumed to be unit
*>                                  triangular.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>           On entry, N specifies the order of the matrix A.
*>           N must be at least zero.
*> \endverbatim
*>
*> \param[in] K
*> \verbatim
*>          K is INTEGER
*>           On entry with UPLO = 'U' or 'u', K specifies the number of
*>           super-diagonals of the matrix A.
*>           On entry with UPLO = 'L' or 'l', K specifies the number of
*>           sub-diagonals of the matrix A.
*>           K must satisfy  0 .le. K.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is DOUBLE PRECISION array of DIMENSION ( LDA, n ).
*>           Before entry with UPLO = 'U' or 'u', the leading ( k + 1 )
*>           by n part of the array A must contain the upper triangular
*>           band part of the matrix of coefficients, supplied column by
*>           column, with the leading diagonal of the matrix in row
*>           ( k + 1 ) of the array, the first super-diagonal starting at
*>           position 2 in row k, and so on. The top left k by k triangle
*>           of the array A is not referenced.
*>           The following program segment will transfer an upper
*>           triangular band matrix from conventional full matrix storage
*>           to band storage:
*>
*>                 DO 20, J = 1, N
*>                    M = K + 1 - J
*>                    DO 10, I = MAX( 1, J - K ), J
*>                       A( M + I, J ) = matrix( I, J )
*>              10    CONTINUE
*>              20 CONTINUE
*>
*>           Before entry with UPLO = 'L' or 'l', the leading ( k + 1 )
*>           by n part of the array A must contain the lower triangular
*>           band part of the matrix of coefficients, supplied column by
*>           column, with the leading diagonal of the matrix in row 1 of
*>           the array, the first sub-diagonal starting at position 1 in
*>           row 2, and so on. The bottom right k by k triangle of the
*>           array A is not referenced.
*>           The following program segment will transfer a lower
*>           triangular band matrix from conventional full matrix storage
*>           to band storage:
*>
*>                 DO 20, J = 1, N
*>                    M = 1 - J
*>                    DO 10, I = J, MIN( N, J + K )
*>                       A( M + I, J ) = matrix( I, J )
*>              10    CONTINUE
*>              20 CONTINUE
*>
*>           Note that when DIAG = 'U' or 'u' the elements of the array A
*>           corresponding to the diagonal elements of the matrix are not
*>           referenced, but are assumed to be unity.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>           On entry, LDA specifies the first dimension of A as declared
*>           in the calling (sub) program. LDA must be at least
*>           ( k + 1 ).
*> \endverbatim
*>
*> \param[in,out] X
*> \verbatim
*>          X is DOUBLE PRECISION array of dimension at least
*>           ( 1 + ( n - 1 )*abs( INCX ) ).
*>           Before entry, the incremented array X must contain the n
*>           element right-hand side vector b. On exit, X is overwritten
*>           with the solution vector x.
*> \endverbatim
*>
*> \param[in] INCX
*> \verbatim
*>          INCX is INTEGER
*>           On entry, INCX specifies the increment for the elements of
*>           X. INCX must not be zero.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup double_blas_level2
*
*> \par Further Details:
*  =====================
*>
*> \verbatim
*>
*>  Level 2 Blas routine.
*>
*>  -- Written on 22-October-1986.
*>     Jack Dongarra, Argonne National Lab.
*>     Jeremy Du Croz, Nag Central Office.
*>     Sven Hammarling, Nag Central Office.
*>     Richard Hanson, Sandia National Labs.
*> \endverbatim
*>
*  =====================================================================
      SUBROUTINE dtbsv(UPLO,TRANS,DIAG,N,K,A,LDA,X,INCX)
*
*  -- Reference BLAS level2 routine (version 3.4.0) --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER INCX,K,LDA,N
      CHARACTER DIAG,TRANS,UPLO
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION A(lda,*),X(*)
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION ZERO
      parameter(zero=0.0d+0)
*     ..
*     .. Local Scalars ..
      DOUBLE PRECISION TEMP
      INTEGER I,INFO,IX,J,JX,KPLUS1,KX,L
      LOGICAL NOUNIT
*     ..
*     .. External Functions ..
      LOGICAL LSAME
      EXTERNAL lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC max,min
*     ..
*
*     Test the input parameters.
*
      info = 0
      IF (.NOT.lsame(uplo,'U') .AND. .NOT.lsame(uplo,'L')) THEN
          info = 1
      ELSE IF (.NOT.lsame(trans,'N') .AND. .NOT.lsame(trans,'T') .AND.
     +         .NOT.lsame(trans,'C')) THEN
          info = 2
      ELSE IF (.NOT.lsame(diag,'U') .AND. .NOT.lsame(diag,'N')) THEN
          info = 3
      ELSE IF (n.LT.0) THEN
          info = 4
      ELSE IF (k.LT.0) THEN
          info = 5
      ELSE IF (lda.LT. (k+1)) THEN
          info = 7
      ELSE IF (incx.EQ.0) THEN
          info = 9
      END IF
      IF (info.NE.0) THEN
          CALL xerbla('DTBSV ',info)
          RETURN
      END IF
*
*     Quick return if possible.
*
      IF (n.EQ.0) RETURN
*
      nounit = lsame(diag,'N')
*
*     Set up the start point in X if the increment is not unity. This
*     will be  ( N - 1 )*INCX  too small for descending loops.
*
      IF (incx.LE.0) THEN
          kx = 1 - (n-1)*incx
      ELSE IF (incx.NE.1) THEN
          kx = 1
      END IF
*
*     Start the operations. In this version the elements of A are
*     accessed by sequentially with one pass through A.
*
      IF (lsame(trans,'N')) THEN
*
*        Form  x := inv( A )*x.
*
          IF (lsame(uplo,'U')) THEN
              kplus1 = k + 1
              IF (incx.EQ.1) THEN
                  DO 20 j = n,1,-1
                      IF (x(j).NE.zero) THEN
                          l = kplus1 - j
                          IF (nounit) x(j) = x(j)/a(kplus1,j)
                          temp = x(j)
                          DO 10 i = j - 1,max(1,j-k),-1
                              x(i) = x(i) - temp*a(l+i,j)
   10                     CONTINUE
                      END IF
   20             CONTINUE
              ELSE
                  kx = kx + (n-1)*incx
                  jx = kx
                  DO 40 j = n,1,-1
                      kx = kx - incx
                      IF (x(jx).NE.zero) THEN
                          ix = kx
                          l = kplus1 - j
                          IF (nounit) x(jx) = x(jx)/a(kplus1,j)
                          temp = x(jx)
                          DO 30 i = j - 1,max(1,j-k),-1
                              x(ix) = x(ix) - temp*a(l+i,j)
                              ix = ix - incx
   30                     CONTINUE
                      END IF
                      jx = jx - incx
   40             CONTINUE
              END IF
          ELSE
              IF (incx.EQ.1) THEN
                  DO 60 j = 1,n
                      IF (x(j).NE.zero) THEN
                          l = 1 - j
                          IF (nounit) x(j) = x(j)/a(1,j)
                          temp = x(j)
                          DO 50 i = j + 1,min(n,j+k)
                              x(i) = x(i) - temp*a(l+i,j)
   50                     CONTINUE
                      END IF
   60             CONTINUE
              ELSE
                  jx = kx
                  DO 80 j = 1,n
                      kx = kx + incx
                      IF (x(jx).NE.zero) THEN
                          ix = kx
                          l = 1 - j
                          IF (nounit) x(jx) = x(jx)/a(1,j)
                          temp = x(jx)
                          DO 70 i = j + 1,min(n,j+k)
                              x(ix) = x(ix) - temp*a(l+i,j)
                              ix = ix + incx
   70                     CONTINUE
                      END IF
                      jx = jx + incx
   80             CONTINUE
              END IF
          END IF
      ELSE
*
*        Form  x := inv( A**T)*x.
*
          IF (lsame(uplo,'U')) THEN
              kplus1 = k + 1
              IF (incx.EQ.1) THEN
                  DO 100 j = 1,n
                      temp = x(j)
                      l = kplus1 - j
                      DO 90 i = max(1,j-k),j - 1
                          temp = temp - a(l+i,j)*x(i)
   90                 CONTINUE
                      IF (nounit) temp = temp/a(kplus1,j)
                      x(j) = temp
  100             CONTINUE
              ELSE
                  jx = kx
                  DO 120 j = 1,n
                      temp = x(jx)
                      ix = kx
                      l = kplus1 - j
                      DO 110 i = max(1,j-k),j - 1
                          temp = temp - a(l+i,j)*x(ix)
                          ix = ix + incx
  110                 CONTINUE
                      IF (nounit) temp = temp/a(kplus1,j)
                      x(jx) = temp
                      jx = jx + incx
                      IF (j.GT.k) kx = kx + incx
  120             CONTINUE
              END IF
          ELSE
              IF (incx.EQ.1) THEN
                  DO 140 j = n,1,-1
                      temp = x(j)
                      l = 1 - j
                      DO 130 i = min(n,j+k),j + 1,-1
                          temp = temp - a(l+i,j)*x(i)
  130                 CONTINUE
                      IF (nounit) temp = temp/a(1,j)
                      x(j) = temp
  140             CONTINUE
              ELSE
                  kx = kx + (n-1)*incx
                  jx = kx
                  DO 160 j = n,1,-1
                      temp = x(jx)
                      ix = kx
                      l = 1 - j
                      DO 150 i = min(n,j+k),j + 1,-1
                          temp = temp - a(l+i,j)*x(ix)
                          ix = ix - incx
  150                 CONTINUE
                      IF (nounit) temp = temp/a(1,j)
                      x(jx) = temp
                      jx = jx - incx
                      IF ((n-j).GE.k) kx = kx - incx
  160             CONTINUE
              END IF
          END IF
      END IF
*
      RETURN
*
*     End of DTBSV .
*
      END