dqlt03.f

Go to the documentation of this file.

*> \brief \b DQLT03
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE DQLT03( M, N, K, AF, C, CC, Q, LDA, TAU, WORK, LWORK,
*                          RWORK, RESULT )
* 
*       .. Scalar Arguments ..
*       INTEGER            K, LDA, LWORK, M, N
*       ..
*       .. Array Arguments ..
*       DOUBLE PRECISION   AF( LDA, * ), C( LDA, * ), CC( LDA, * ),
*      $                   Q( LDA, * ), RESULT( * ), RWORK( * ), TAU( * ),
*      $                   WORK( LWORK )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DQLT03 tests DORMQL, which computes Q*C, Q'*C, C*Q or C*Q'.
*>
*> DQLT03 compares the results of a call to DORMQL with the results of
*> forming Q explicitly by a call to DORGQL and then performing matrix
*> multiplication by a call to DGEMM.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The order of the orthogonal matrix Q.  M >= 0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of rows or columns of the matrix C; C is m-by-n if
*>          Q is applied from the left, or n-by-m if Q is applied from
*>          the right.  N >= 0.
*> \endverbatim
*>
*> \param[in] K
*> \verbatim
*>          K is INTEGER
*>          The number of elementary reflectors whose product defines the
*>          orthogonal matrix Q.  M >= K >= 0.
*> \endverbatim
*>
*> \param[in] AF
*> \verbatim
*>          AF is DOUBLE PRECISION array, dimension (LDA,N)
*>          Details of the QL factorization of an m-by-n matrix, as
*>          returned by DGEQLF. See SGEQLF for further details.
*> \endverbatim
*>
*> \param[out] C
*> \verbatim
*>          C is DOUBLE PRECISION array, dimension (LDA,N)
*> \endverbatim
*>
*> \param[out] CC
*> \verbatim
*>          CC is DOUBLE PRECISION array, dimension (LDA,N)
*> \endverbatim
*>
*> \param[out] Q
*> \verbatim
*>          Q is DOUBLE PRECISION array, dimension (LDA,M)
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the arrays AF, C, CC, and Q.
*> \endverbatim
*>
*> \param[in] TAU
*> \verbatim
*>          TAU is DOUBLE PRECISION array, dimension (min(M,N))
*>          The scalar factors of the elementary reflectors corresponding
*>          to the QL factorization in AF.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is DOUBLE PRECISION array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The length of WORK.  LWORK must be at least M, and should be
*>          M*NB, where NB is the blocksize for this environment.
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is DOUBLE PRECISION array, dimension (M)
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is DOUBLE PRECISION array, dimension (4)
*>          The test ratios compare two techniques for multiplying a
*>          random matrix C by an m-by-m orthogonal matrix Q.
*>          RESULT(1) = norm( Q*C - Q*C )  / ( M * norm(C) * EPS )
*>          RESULT(2) = norm( C*Q - C*Q )  / ( M * norm(C) * EPS )
*>          RESULT(3) = norm( Q'*C - Q'*C )/ ( M * norm(C) * EPS )
*>          RESULT(4) = norm( C*Q' - C*Q' )/ ( M * norm(C) * EPS )
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup double_lin
*
*  =====================================================================
      SUBROUTINE dqlt03( M, N, K, AF, C, CC, Q, LDA, TAU, WORK, LWORK,
     $                   rwork, result )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            K, LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   AF( lda, * ), C( lda, * ), CC( lda, * ),
     $                   q( lda, * ), result( * ), rwork( * ), tau( * ),
     $                   work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter                ( zero = 0.0d0, one = 1.0d0 )
      DOUBLE PRECISION   ROGUE
      parameter                ( rogue = -1.0d+10 )
*     ..
*     .. Local Scalars ..
      CHARACTER          SIDE, TRANS
      INTEGER            INFO, ISIDE, ITRANS, J, MC, MINMN, NC
      DOUBLE PRECISION   CNORM, EPS, RESID
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   DLAMCH, DLANGE
      EXTERNAL           lsame, dlamch, dlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemm, dlacpy, dlarnv, dlaset, dorgql, dormql
*     ..
*     .. Local Arrays ..
      INTEGER            ISEED( 4 )
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max, min
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       SRNAMT
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseed / 1988, 1989, 1990, 1991 /
*     ..
*     .. Executable Statements ..
*
      eps = dlamch( 'Epsilon' )
      minmn = min( m, n )
*
*     Quick return if possible
*
      IF( minmn.EQ.0 ) THEN
         result( 1 ) = zero
         result( 2 ) = zero
         result( 3 ) = zero
         result( 4 ) = zero
         RETURN
      END IF
*
*     Copy the last k columns of the factorization to the array Q
*
      CALL dlaset( 'Full', m, m, rogue, rogue, q, lda )
      IF( k.GT.0 .AND. m.GT.k )
     $   CALL dlacpy( 'Full', m-k, k, af( 1, n-k+1 ), lda,
     $                q( 1, m-k+1 ), lda )
      IF( k.GT.1 )
     $   CALL dlacpy( 'Upper', k-1, k-1, af( m-k+1, n-k+2 ), lda,
     $                q( m-k+1, m-k+2 ), lda )
*
*     Generate the m-by-m matrix Q
*
      srnamt = 'DORGQL'
      CALL dorgql( m, m, k, q, lda, tau( minmn-k+1 ), work, lwork,
     $             info )
*
      DO 30 iside = 1, 2
         IF( iside.EQ.1 ) THEN
            side = 'L'
            mc = m
            nc = n
         ELSE
            side = 'R'
            mc = n
            nc = m
         END IF
*
*        Generate MC by NC matrix C
*
         DO 10 j = 1, nc
            CALL dlarnv( 2, iseed, mc, c( 1, j ) )
   10    CONTINUE
         cnorm = dlange( '1', mc, nc, c, lda, rwork )
         IF( cnorm.EQ.0.0d0 )
     $      cnorm = one
*
         DO 20 itrans = 1, 2
            IF( itrans.EQ.1 ) THEN
               trans = 'N'
            ELSE
               trans = 'T'
            END IF
*
*           Copy C
*
            CALL dlacpy( 'Full', mc, nc, c, lda, cc, lda )
*
*           Apply Q or Q' to C
*
            srnamt = 'DORMQL'
            IF( k.GT.0 )
     $         CALL dormql( side, trans, mc, nc, k, af( 1, n-k+1 ), lda,
     $                      tau( minmn-k+1 ), cc, lda, work, lwork,
     $                      info )
*
*           Form explicit product and subtract
*
            IF( lsame( side, 'L' ) ) THEN
               CALL dgemm( trans, 'No transpose', mc, nc, mc, -one, q,
     $                     lda, c, lda, one, cc, lda )
            ELSE
               CALL dgemm( 'No transpose', trans, mc, nc, nc, -one, c,
     $                     lda, q, lda, one, cc, lda )
            END IF
*
*           Compute error in the difference
*
            resid = dlange( '1', mc, nc, cc, lda, rwork )
            result( ( iside-1 )*2+itrans ) = resid /
     $         ( dble( max( 1, m ) )*cnorm*eps )
*
   20    CONTINUE
   30 CONTINUE
*
      RETURN
*
*     End of DQLT03
*
      END