subroutine chpt01	(	character	UPLO,
		integer	N,
		complex, dimension( * )	A,
		complex, dimension( * )	AFAC,
		integer, dimension( * )	IPIV,
		complex, dimension( ldc, * )	C,
		integer	LDC,
		real, dimension( * )	RWORK,
		real	RESID
	)

CHPT01

Purpose:

 CHPT01 reconstructs a Hermitian indefinite packed matrix A from its
 block L*D*L' or U*D*U' factorization and computes the residual
    norm( C - A ) / ( N * norm(A) * EPS ),
 where C is the reconstructed matrix, EPS is the machine epsilon,
 L' is the conjugate transpose of L, and U' is the conjugate transpose
 of U.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the Hermitian matrix A is stored: = 'U': Upper triangular = 'L': Lower triangular
[in]	N	N is INTEGER The number of rows and columns of the matrix A. N >= 0.
[in]	A	A is COMPLEX array, dimension (N*(N+1)/2) The original Hermitian matrix A, stored as a packed triangular matrix.
[in]	AFAC	AFAC is COMPLEX array, dimension (N*(N+1)/2) The factored form of the matrix A, stored as a packed triangular matrix. AFAC contains the block diagonal matrix D and the multipliers used to obtain the factor L or U from the block L*D*L' or U*D*U' factorization as computed by CHPTRF.
[in]	IPIV	IPIV is INTEGER array, dimension (N) The pivot indices from CHPTRF.
[out]	C	C is COMPLEX array, dimension (LDC,N)
[in]	LDC	LDC is INTEGER The leading dimension of the array C. LDC >= max(1,N).
[out]	RWORK	RWORK is REAL array, dimension (N)
[out]	RESID	RESID is REAL If UPLO = 'L', norm(L*D*L' - A) / ( N * norm(A) * EPS ) If UPLO = 'U', norm(U*D*U' - A) / ( N * norm(A) * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 115 of file chpt01.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            ldc, n
      REAL               resid
*     ..
*     .. Array Arguments ..
      INTEGER            ipiv( * )
      REAL               rwork( * )
      COMPLEX            a( * ), afac( * ), c( ldc, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter                ( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            czero, cone
      parameter                ( czero = ( 0.0e+0, 0.0e+0 ),
     $                   cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            i, info, j, jc
      REAL               anorm, eps
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      REAL               clanhe, clanhp, slamch
      EXTERNAL           lsame, clanhe, clanhp, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           clavhp, claset
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          aimag, real
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     Determine EPS and the norm of A.
*
      eps = slamch( 'Epsilon' )
      anorm = clanhp( '1', uplo, n, a, rwork )
*
*     Check the imaginary parts of the diagonal elements and return with
*     an error code if any are nonzero.
*
      jc = 1
      IF( lsame( uplo, 'U' ) ) THEN
         DO 10 j = 1, n
            IF( aimag( afac( jc ) ).NE.zero ) THEN
               resid = one / eps
               RETURN
            END IF
            jc = jc + j + 1
   10    CONTINUE
      ELSE
         DO 20 j = 1, n
            IF( aimag( afac( jc ) ).NE.zero ) THEN
               resid = one / eps
               RETURN
            END IF
            jc = jc + n - j + 1
   20    CONTINUE
      END IF
*
*     Initialize C to the identity matrix.
*
      CALL claset( 'Full', n, n, czero, cone, c, ldc )
*
*     Call CLAVHP to form the product D * U' (or D * L' ).
*
      CALL clavhp( uplo, 'Conjugate', 'Non-unit', n, n, afac, ipiv, c,
     $             ldc, info )
*
*     Call CLAVHP again to multiply by U ( or L ).
*
      CALL clavhp( uplo, 'No transpose', 'Unit', n, n, afac, ipiv, c,
     $             ldc, info )
*
*     Compute the difference  C - A .
*
      IF( lsame( uplo, 'U' ) ) THEN
         jc = 0
         DO 40 j = 1, n
            DO 30 i = 1, j - 1
               c( i, j ) = c( i, j ) - a( jc+i )
   30       CONTINUE
            c( j, j ) = c( j, j ) - REAL( A( JC+J ) )
            jc = jc + j
   40    CONTINUE
      ELSE
         jc = 1
         DO 60 j = 1, n
            c( j, j ) = c( j, j ) - REAL( A( JC ) )
            DO 50 i = j + 1, n
               c( i, j ) = c( i, j ) - a( jc+i-j )
   50       CONTINUE
            jc = jc + n - j + 1
   60    CONTINUE
      END IF
*
*     Compute norm( C - A ) / ( N * norm(A) * EPS )
*
      resid = clanhe( '1', uplo, n, c, ldc, rwork )
*
      IF( anorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         resid = ( ( resid / REAL( N ) ) / anorm ) / eps
      END IF
*
      RETURN
*
*     End of CHPT01
*

Here is the call graph for this function:

Here is the caller graph for this function: