LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
real function clanhp ( character  NORM,
character  UPLO,
integer  N,
complex, dimension( * )  AP,
real, dimension( * )  WORK 
)

CLANHP returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex Hermitian matrix supplied in packed form.

Download CLANHP + dependencies [TGZ] [ZIP] [TXT]

Purpose: 
 CLANHP  returns the value of the one norm,  or the Frobenius norm, or
 the  infinity norm,  or the  element of  largest absolute value  of a
 complex hermitian matrix A,  supplied in packed form.
Returns
CLANHP 
    CLANHP = ( max(abs(A(i,j))), NORM = 'M' or 'm'
             (
             ( norm1(A),         NORM = '1', 'O' or 'o'
             (
             ( normI(A),         NORM = 'I' or 'i'
             (
             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'

 where  norm1  denotes the  one norm of a matrix (maximum column sum),
 normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
 normF  denotes the  Frobenius norm of a matrix (square root of sum of
 squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
Parameters
[in]NORM
          NORM is CHARACTER*1
          Specifies the value to be returned in CLANHP as described
          above.
[in]UPLO
          UPLO is CHARACTER*1
          Specifies whether the upper or lower triangular part of the
          hermitian matrix A is supplied.
          = 'U':  Upper triangular part of A is supplied
          = 'L':  Lower triangular part of A is supplied
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.  When N = 0, CLANHP is
          set to zero.
[in]AP
          AP is COMPLEX array, dimension (N*(N+1)/2)
          The upper or lower triangle of the hermitian matrix A, packed
          columnwise in a linear array.  The j-th column of A is stored
          in the array AP as follows:
          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
          if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
          Note that the  imaginary parts of the diagonal elements need
          not be set and are assumed to be zero.
[out]WORK
          WORK is REAL array, dimension (MAX(1,LWORK)),
          where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
          WORK is not referenced.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
September 2012

Definition at line 119 of file clanhp.f.

119 *
120 * -- LAPACK auxiliary routine (version 3.4.2) --
121 * -- LAPACK is a software package provided by Univ. of Tennessee, --
122 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
123 * September 2012
124 *
125 * .. Scalar Arguments ..
126  CHARACTER norm, uplo
127  INTEGER n
128 * ..
129 * .. Array Arguments ..
130  REAL work( * )
131  COMPLEX ap( * )
132 * ..
133 *
134 * =====================================================================
135 *
136 * .. Parameters ..
137  REAL one, zero
138  parameter ( one = 1.0e+0, zero = 0.0e+0 )
139 * ..
140 * .. Local Scalars ..
141  INTEGER i, j, k
142  REAL absa, scale, sum, value
143 * ..
144 * .. External Functions ..
145  LOGICAL lsame, sisnan
146  EXTERNAL lsame, sisnan
147 * ..
148 * .. External Subroutines ..
149  EXTERNAL classq
150 * ..
151 * .. Intrinsic Functions ..
152  INTRINSIC abs, REAL, sqrt
153 * ..
154 * .. Executable Statements ..
155 *
156  IF( n.EQ.0 ) THEN
157  VALUE = zero
158  ELSE IF( lsame( norm, 'M' ) ) THEN
159 *
160 * Find max(abs(A(i,j))).
161 *
162  VALUE = zero
163  IF( lsame( uplo, 'U' ) ) THEN
164  k = 0
165  DO 20 j = 1, n
166  DO 10 i = k + 1, k + j - 1
167  sum = abs( ap( i ) )
168  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
169  10 CONTINUE
170  k = k + j
171  sum = abs( REAL( AP( K ) ) )
172  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
173  20 CONTINUE
174  ELSE
175  k = 1
176  DO 40 j = 1, n
177  sum = abs( REAL( AP( K ) ) )
178  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
179  DO 30 i = k + 1, k + n - j
180  sum = abs( ap( i ) )
181  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
182  30 CONTINUE
183  k = k + n - j + 1
184  40 CONTINUE
185  END IF
186  ELSE IF( ( lsame( norm, 'I' ) ) .OR. ( lsame( norm, 'O' ) ) .OR.
187  $ ( norm.EQ.'1' ) ) THEN
188 *
189 * Find normI(A) ( = norm1(A), since A is hermitian).
190 *
191  VALUE = zero
192  k = 1
193  IF( lsame( uplo, 'U' ) ) THEN
194  DO 60 j = 1, n
195  sum = zero
196  DO 50 i = 1, j - 1
197  absa = abs( ap( k ) )
198  sum = sum + absa
199  work( i ) = work( i ) + absa
200  k = k + 1
201  50 CONTINUE
202  work( j ) = sum + abs( REAL( AP( K ) ) )
203  k = k + 1
204  60 CONTINUE
205  DO 70 i = 1, n
206  sum = work( i )
207  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
208  70 CONTINUE
209  ELSE
210  DO 80 i = 1, n
211  work( i ) = zero
212  80 CONTINUE
213  DO 100 j = 1, n
214  sum = work( j ) + abs( REAL( AP( K ) ) )
215  k = k + 1
216  DO 90 i = j + 1, n
217  absa = abs( ap( k ) )
218  sum = sum + absa
219  work( i ) = work( i ) + absa
220  k = k + 1
221  90 CONTINUE
222  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
223  100 CONTINUE
224  END IF
225  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
226 *
227 * Find normF(A).
228 *
229  scale = zero
230  sum = one
231  k = 2
232  IF( lsame( uplo, 'U' ) ) THEN
233  DO 110 j = 2, n
234  CALL classq( j-1, ap( k ), 1, scale, sum )
235  k = k + j
236  110 CONTINUE
237  ELSE
238  DO 120 j = 1, n - 1
239  CALL classq( n-j, ap( k ), 1, scale, sum )
240  k = k + n - j + 1
241  120 CONTINUE
242  END IF
243  sum = 2*sum
244  k = 1
245  DO 130 i = 1, n
246  IF( REAL( AP( K ) ).NE.zero ) then
247  absa = abs( REAL( AP( K ) ) )
248  IF( scale.LT.absa ) THEN
249  sum = one + sum*( scale / absa )**2
250  scale = absa
251  ELSE
252  sum = sum + ( absa / scale )**2
253  END IF
254  END IF
255  IF( lsame( uplo, 'U' ) ) THEN
256  k = k + i + 1
257  ELSE
258  k = k + n - i + 1
259  END IF
260  130 CONTINUE
261  VALUE = scale*sqrt( sum )
262  END IF
263 *
264  clanhp = VALUE
265  RETURN
266 *
267 * End of CLANHP
268 *
sisnan
logical function sisnan(SIN)
SISNAN tests input for NaN.
Definition: sisnan.f:61
classq
subroutine classq(N, X, INCX, SCALE, SUMSQ)
CLASSQ updates a sum of squares represented in scaled form.
Definition: classq.f:108
clanhp
real function clanhp(NORM, UPLO, N, AP, WORK)
CLANHP returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex Hermitian matrix supplied in packed form.
Definition: clanhp.f:119
lsame
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55

Here is the call graph for this function: