subroutine cgtt02	(	character	TRANS,
		integer	N,
		integer	NRHS,
		complex, dimension( * )	DL,
		complex, dimension( * )	D,
		complex, dimension( * )	DU,
		complex, dimension( ldx, * )	X,
		integer	LDX,
		complex, dimension( ldb, * )	B,
		integer	LDB,
		real	RESID
	)

CGTT02

Purpose:

 CGTT02 computes the residual for the solution to a tridiagonal
 system of equations:
    RESID = norm(B - op(A)*X) / (norm(A) * norm(X) * EPS),
 where EPS is the machine epsilon.

Parameters

[in]	TRANS	TRANS is CHARACTER Specifies the form of the residual. = 'N': B - A * X (No transpose) = 'T': B - A**T * X (Transpose) = 'C': B - A**H * X (Conjugate transpose)
[in]	N	N is INTEGTER The order of the matrix A. N >= 0.
[in]	NRHS	NRHS is INTEGER The number of right hand sides, i.e., the number of columns of the matrices B and X. NRHS >= 0.
[in]	DL	DL is COMPLEX array, dimension (N-1) The (n-1) sub-diagonal elements of A.
[in]	D	D is COMPLEX array, dimension (N) The diagonal elements of A.
[in]	DU	DU is COMPLEX array, dimension (N-1) The (n-1) super-diagonal elements of A.
[in]	X	X is COMPLEX array, dimension (LDX,NRHS) The computed solution vectors X.
[in]	LDX	LDX is INTEGER The leading dimension of the array X. LDX >= max(1,N).
[in,out]	B	B is COMPLEX array, dimension (LDB,NRHS) On entry, the right hand side vectors for the system of linear equations. On exit, B is overwritten with the difference B - op(A)*X.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).
[out]	RESID	RESID is REAL norm(B - op(A)*X) / (norm(A) * norm(X) * EPS)

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 126 of file cgtt02.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          trans
      INTEGER            ldb, ldx, n, nrhs
      REAL               resid
*     ..
*     .. Array Arguments ..
      COMPLEX            b( ldb, * ), d( * ), dl( * ), du( * ),
     $                   x( ldx, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               one, zero
      parameter                ( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            j
      REAL               anorm, bnorm, eps, xnorm
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      REAL               clangt, scasum, slamch
      EXTERNAL           lsame, clangt, scasum, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           clagtm
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0 or NRHS = 0
*
      resid = zero
      IF( n.LE.0 .OR. nrhs.EQ.0 )
     $   RETURN
*
*     Compute the maximum over the number of right hand sides of
*        norm(B - op(A)*X) / ( norm(A) * norm(X) * EPS ).
*
      IF( lsame( trans, 'N' ) ) THEN
         anorm = clangt( '1', n, dl, d, du )
      ELSE
         anorm = clangt( 'I', n, dl, d, du )
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0.
*
      eps = slamch( 'Epsilon' )
      IF( anorm.LE.zero ) THEN
         resid = one / eps
         RETURN
      END IF
*
*     Compute B - op(A)*X.
*
      CALL clagtm( trans, n, nrhs, -one, dl, d, du, x, ldx, one, b,
     $             ldb )
*
      DO 10 j = 1, nrhs
         bnorm = scasum( n, b( 1, j ), 1 )
         xnorm = scasum( n, x( 1, j ), 1 )
         IF( xnorm.LE.zero ) THEN
            resid = one / eps
         ELSE
            resid = max( resid, ( ( bnorm / anorm ) / xnorm ) / eps )
         END IF
   10 CONTINUE
*
      RETURN
*
*     End of CGTT02
*

Here is the call graph for this function:

Here is the caller graph for this function: