real function crzt01	(	integer	M,
		integer	N,
		complex, dimension( lda, * )	A,
		complex, dimension( lda, * )	AF,
		integer	LDA,
		complex, dimension( * )	TAU,
		complex, dimension( lwork )	WORK,
		integer	LWORK
	)

CRZT01

Purpose:

 CRZT01 returns
      || A - R*Q || / ( M * eps * ||A|| )
 for an upper trapezoidal A that was factored with CTZRZF.

Parameters

[in]	M	M is INTEGER The number of rows of the matrices A and AF.
[in]	N	N is INTEGER The number of columns of the matrices A and AF.
[in]	A	A is COMPLEX array, dimension (LDA,N) The original upper trapezoidal M by N matrix A.
[in]	AF	AF is COMPLEX array, dimension (LDA,N) The output of CTZRZF for input matrix A. The lower triangle is not referenced.
[in]	LDA	LDA is INTEGER The leading dimension of the arrays A and AF.
[in]	TAU	TAU is COMPLEX array, dimension (M) Details of the Householder transformations as returned by CTZRZF.
[out]	WORK	WORK is COMPLEX array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The length of the array WORK. LWORK >= m*n + m.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 100 of file crzt01.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            lda, lwork, m, n
*     ..
*     .. Array Arguments ..
      COMPLEX            a( lda, * ), af( lda, * ), tau( * ),
     $                   work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter                ( zero = 0.0e0, one = 1.0e0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, info, j
      REAL               norma
*     ..
*     .. Local Arrays ..
      REAL               rwork( 1 )
*     ..
*     .. External Functions ..
      REAL               clange, slamch
      EXTERNAL           clange, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           caxpy, claset, cunmrz, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, real
*     ..
*     .. Executable Statements ..
*
      crzt01 = zero
*
      IF( lwork.LT.m*n+m ) THEN
         CALL xerbla( 'CRZT01', 8 )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.LE.0 .OR. n.LE.0 )
     $   RETURN
*
      norma = clange( 'One-norm', m, n, a, lda, rwork )
*
*     Copy upper triangle R
*
      CALL claset( 'Full', m, n, cmplx( zero ), cmplx( zero ), work, m )
      DO 20 j = 1, m
         DO 10 i = 1, j
            work( ( j-1 )*m+i ) = af( i, j )
   10    CONTINUE
   20 CONTINUE
*
*     R = R * P(1) * ... *P(m)
*
      CALL cunmrz( 'Right', 'No tranpose', m, n, m, n-m, af, lda, tau,
     $             work, m, work( m*n+1 ), lwork-m*n, info )
*
*     R = R - A
*
      DO 30 i = 1, n
         CALL caxpy( m, cmplx( -one ), a( 1, i ), 1,
     $               work( ( i-1 )*m+1 ), 1 )
   30 CONTINUE
*
      crzt01 = clange( 'One-norm', m, n, work, m, rwork )
*
      crzt01 = crzt01 / ( slamch( 'Epsilon' )*REAL( MAX( M, N ) ) )
      IF( norma.NE.zero )
     $   crzt01 = crzt01 / norma
*
      RETURN
*
*     End of CRZT01
*

Here is the call graph for this function: