recursive subroutine zgeqrt3	(	integer	M,
		integer	N,
		complex*16, dimension( lda, * )	A,
		integer	LDA,
		complex*16, dimension( ldt, * )	T,
		integer	LDT,
		integer	INFO
	)

ZGEQRT3 recursively computes a QR factorization of a general real or complex matrix using the compact WY representation of Q.

Download ZGEQRT3 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZGEQRT3 recursively computes a QR factorization of a complex M-by-N 
 matrix A, using the compact WY representation of Q. 

 Based on the algorithm of Elmroth and Gustavson, 
 IBM J. Res. Develop. Vol 44 No. 4 July 2000.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A. M >= N.
[in]	N	N is INTEGER The number of columns of the matrix A. N >= 0.
[in,out]	A	A is COMPLEX*16 array, dimension (LDA,N) On entry, the complex M-by-N matrix A. On exit, the elements on and above the diagonal contain the N-by-N upper triangular matrix R; the elements below the diagonal are the columns of V. See below for further details.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).
[out]	T	T is COMPLEX*16 array, dimension (LDT,N) The N-by-N upper triangular factor of the block reflector. The elements on and above the diagonal contain the block reflector T; the elements below the diagonal are not used. See below for further details.
[in]	LDT	LDT is INTEGER The leading dimension of the array T. LDT >= max(1,N).
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

June 2016

Further Details:

  The matrix V stores the elementary reflectors H(i) in the i-th column
  below the diagonal. For example, if M=5 and N=3, the matrix V is

               V = (  1       )
                   ( v1  1    )
                   ( v1 v2  1 )
                   ( v1 v2 v3 )
                   ( v1 v2 v3 )

  where the vi's represent the vectors which define H(i), which are returned
  in the matrix A.  The 1's along the diagonal of V are not stored in A.  The
  block reflector H is then given by

               H = I - V * T * V**H

  where V**H is the conjugate transpose of V.

  For details of the algorithm, see Elmroth and Gustavson (cited above).

Definition at line 134 of file zgeqrt3.f.

*
*  -- LAPACK computational routine (version 3.6.1) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     June 2016
*
*     .. Scalar Arguments ..
      INTEGER   info, lda, m, n, ldt
*     ..
*     .. Array Arguments ..
      COMPLEX*16   a( lda, * ), t( ldt, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX*16   one
      parameter( one = (1.0d+00,0.0d+00) )
*     ..
*     .. Local Scalars ..
      INTEGER   i, i1, j, j1, n1, n2, iinfo
*     ..
*     .. External Subroutines ..
      EXTERNAL  zlarfg, ztrmm, zgemm, xerbla
*     ..
*     .. Executable Statements ..
*
      info = 0
      IF( n .LT. 0 ) THEN
         info = -2
      ELSE IF( m .LT. n ) THEN
         info = -1
      ELSE IF( lda .LT. max( 1, m ) ) THEN
         info = -4
      ELSE IF( ldt .LT. max( 1, n ) ) THEN
         info = -6
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZGEQRT3', -info )
         RETURN
      END IF
*
      IF( n.EQ.1 ) THEN
*
*        Compute Householder transform when N=1
*
         CALL zlarfg( m, a(1,1), a( min( 2, m ), 1 ), 1, t(1,1) )
*         
      ELSE
*
*        Otherwise, split A into blocks...
*
         n1 = n/2
         n2 = n-n1
         j1 = min( n1+1, n )
         i1 = min( n+1, m )
*
*        Compute A(1:M,1:N1) <- (Y1,R1,T1), where Q1 = I - Y1 T1 Y1^H
*
         CALL zgeqrt3( m, n1, a, lda, t, ldt, iinfo )
*
*        Compute A(1:M,J1:N) = Q1^H A(1:M,J1:N) [workspace: T(1:N1,J1:N)]
*
         DO j=1,n2
            DO i=1,n1
               t( i, j+n1 ) = a( i, j+n1 )
            END DO
         END DO
         CALL ztrmm( 'L', 'L', 'C', 'U', n1, n2, one, 
     &               a, lda, t( 1, j1 ), ldt )
*
         CALL zgemm( 'C', 'N', n1, n2, m-n1, one, a( j1, 1 ), lda,
     &               a( j1, j1 ), lda, one, t( 1, j1 ), ldt)
*
         CALL ztrmm( 'L', 'U', 'C', 'N', n1, n2, one,
     &               t, ldt, t( 1, j1 ), ldt )
*
         CALL zgemm( 'N', 'N', m-n1, n2, n1, -one, a( j1, 1 ), lda, 
     &               t( 1, j1 ), ldt, one, a( j1, j1 ), lda )
*
         CALL ztrmm( 'L', 'L', 'N', 'U', n1, n2, one,
     &               a, lda, t( 1, j1 ), ldt )
*
         DO j=1,n2
            DO i=1,n1
               a( i, j+n1 ) = a( i, j+n1 ) - t( i, j+n1 )
            END DO
         END DO
*
*        Compute A(J1:M,J1:N) <- (Y2,R2,T2) where Q2 = I - Y2 T2 Y2^H
*
         CALL zgeqrt3( m-n1, n2, a( j1, j1 ), lda, 
     &                t( j1, j1 ), ldt, iinfo )
*
*        Compute T3 = T(1:N1,J1:N) = -T1 Y1^H Y2 T2
*
         DO i=1,n1
            DO j=1,n2
               t( i, j+n1 ) = conjg(a( j+n1, i ))
            END DO
         END DO
*
         CALL ztrmm( 'R', 'L', 'N', 'U', n1, n2, one,
     &               a( j1, j1 ), lda, t( 1, j1 ), ldt )
*
         CALL zgemm( 'C', 'N', n1, n2, m-n, one, a( i1, 1 ), lda, 
     &               a( i1, j1 ), lda, one, t( 1, j1 ), ldt )
*
         CALL ztrmm( 'L', 'U', 'N', 'N', n1, n2, -one, t, ldt, 
     &               t( 1, j1 ), ldt )
*
         CALL ztrmm( 'R', 'U', 'N', 'N', n1, n2, one, 
     &               t( j1, j1 ), ldt, t( 1, j1 ), ldt )
*
*        Y = (Y1,Y2); R = [ R1  A(1:N1,J1:N) ];  T = [T1 T3]
*                         [  0        R2     ]       [ 0 T2]
*
      END IF
*
      RETURN
*
*     End of ZGEQRT3
*

Here is the call graph for this function:

Here is the caller graph for this function: