zqrt17.f

Go to the documentation of this file.

*> \brief \b ZQRT17
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       DOUBLE PRECISION FUNCTION ZQRT17( TRANS, IRESID, M, N, NRHS, A,
*                        LDA, X, LDX, B, LDB, C, WORK, LWORK )
* 
*       .. Scalar Arguments ..
*       CHARACTER          TRANS
*       INTEGER            IRESID, LDA, LDB, LDX, LWORK, M, N, NRHS
*       ..
*       .. Array Arguments ..
*       COMPLEX*16         A( LDA, * ), B( LDB, * ), C( LDB, * ),
*      $                   WORK( LWORK ), X( LDX, * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZQRT17 computes the ratio
*>
*>    || R'*op(A) ||/(||A||*alpha*max(M,N,NRHS)*eps)
*>
*> where R = op(A)*X - B, op(A) is A or A', and
*>
*>    alpha = ||B|| if IRESID = 1 (zero-residual problem)
*>    alpha = ||R|| if IRESID = 2 (otherwise).
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] TRANS
*> \verbatim
*>          TRANS is CHARACTER*1
*>          Specifies whether or not the transpose of A is used.
*>          = 'N':  No transpose, op(A) = A.
*>          = 'C':  Conjugate transpose, op(A) = A'.
*> \endverbatim
*>
*> \param[in] IRESID
*> \verbatim
*>          IRESID is INTEGER
*>          IRESID = 1 indicates zero-residual problem.
*>          IRESID = 2 indicates non-zero residual.
*> \endverbatim
*>
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix A.
*>          If TRANS = 'N', the number of rows of the matrix B.
*>          If TRANS = 'C', the number of rows of the matrix X.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix  A.
*>          If TRANS = 'N', the number of rows of the matrix X.
*>          If TRANS = 'C', the number of rows of the matrix B.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>          The number of columns of the matrices X and B.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (LDA,N)
*>          The m-by-n matrix A.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A. LDA >= M.
*> \endverbatim
*>
*> \param[in] X
*> \verbatim
*>          X is COMPLEX*16 array, dimension (LDX,NRHS)
*>          If TRANS = 'N', the n-by-nrhs matrix X.
*>          If TRANS = 'C', the m-by-nrhs matrix X.
*> \endverbatim
*>
*> \param[in] LDX
*> \verbatim
*>          LDX is INTEGER
*>          The leading dimension of the array X.
*>          If TRANS = 'N', LDX >= N.
*>          If TRANS = 'C', LDX >= M.
*> \endverbatim
*>
*> \param[in] B
*> \verbatim
*>          B is COMPLEX*16 array, dimension (LDB,NRHS)
*>          If TRANS = 'N', the m-by-nrhs matrix B.
*>          If TRANS = 'C', the n-by-nrhs matrix B.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B.
*>          If TRANS = 'N', LDB >= M.
*>          If TRANS = 'C', LDB >= N.
*> \endverbatim
*>
*> \param[out] C
*> \verbatim
*>          C is COMPLEX*16 array, dimension (LDB,NRHS)
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX*16 array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The length of the array WORK.  LWORK >= NRHS*(M+N).
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2015
*
*> \ingroup complex16_lin
*
*  =====================================================================
      DOUBLE PRECISION FUNCTION zqrt17( TRANS, IRESID, M, N, NRHS, A,
     $                 lda, x, ldx, b, ldb, c, work, lwork )
*
*  -- LAPACK test routine (version 3.6.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2015
*
*     .. Scalar Arguments ..
      CHARACTER          TRANS
      INTEGER            IRESID, LDA, LDB, LDX, LWORK, M, N, NRHS
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( lda, * ), B( ldb, * ), C( ldb, * ),
     $                   work( lwork ), x( ldx, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter                ( zero = 0.0d0, one = 1.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO, ISCL, NCOLS, NROWS
      DOUBLE PRECISION   BIGNUM, ERR, NORMA, NORMB, NORMRS, NORMX,
     $                   smlnum
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   RWORK( 1 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   DLAMCH, ZLANGE
      EXTERNAL           lsame, dlamch, zlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zgemm, zlacpy, zlascl
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dcmplx, max
*     ..
*     .. Executable Statements ..
*
      zqrt17 = zero
*
      IF( lsame( trans, 'N' ) ) THEN
         nrows = m
         ncols = n
      ELSE IF( lsame( trans, 'C' ) ) THEN
         nrows = n
         ncols = m
      ELSE
         CALL xerbla( 'ZQRT17', 1 )
         RETURN
      END IF
*
      IF( lwork.LT.ncols*nrhs ) THEN
         CALL xerbla( 'ZQRT17', 13 )
         RETURN
      END IF
*
      IF( m.LE.0 .OR. n.LE.0 .OR. nrhs.LE.0 )
     $   RETURN
*
      norma = zlange( 'One-norm', m, n, a, lda, rwork )
      smlnum = dlamch( 'Safe minimum' ) / dlamch( 'Precision' )
      bignum = one / smlnum
      iscl = 0
*
*     compute residual and scale it
*
      CALL zlacpy( 'All', nrows, nrhs, b, ldb, c, ldb )
      CALL zgemm( trans, 'No transpose', nrows, nrhs, ncols,
     $            dcmplx( -one ), a, lda, x, ldx, dcmplx( one ), c,
     $            ldb )
      normrs = zlange( 'Max', nrows, nrhs, c, ldb, rwork )
      IF( normrs.GT.smlnum ) THEN
         iscl = 1
         CALL zlascl( 'General', 0, 0, normrs, one, nrows, nrhs, c, ldb,
     $                info )
      END IF
*
*     compute R'*A
*
      CALL zgemm( 'Conjugate transpose', trans, nrhs, ncols, nrows,
     $            dcmplx( one ), c, ldb, a, lda, dcmplx( zero ), work,
     $            nrhs )
*
*     compute and properly scale error
*
      err = zlange( 'One-norm', nrhs, ncols, work, nrhs, rwork )
      IF( norma.NE.zero )
     $   err = err / norma
*
      IF( iscl.EQ.1 )
     $   err = err*normrs
*
      IF( iresid.EQ.1 ) THEN
         normb = zlange( 'One-norm', nrows, nrhs, b, ldb, rwork )
         IF( normb.NE.zero )
     $      err = err / normb
      ELSE
         IF( normrs.NE.zero )
     $      err = err / normrs
      END IF
*
      zqrt17 = err / ( dlamch( 'Epsilon' )*dble( max( m, n, nrhs ) ) )
      RETURN
*
*     End of ZQRT17
*
      END