slatb9.f

Go to the documentation of this file.

*> \brief \b SLATB9
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE SLATB9( PATH, IMAT, M, P, N, TYPE, KLA, KUA,
*                          KLB, KUB, ANORM, BNORM, MODEA, MODEB,
*                          CNDNMA, CNDNMB, DISTA, DISTB )
* 
*       .. Scalar Arguments ..
*       CHARACTER          DISTA, DISTB, TYPE
*       CHARACTER*3        PATH
*       INTEGER            IMAT, KLA, KUA, KLB, KUB, M, P, MODEA, MODEB, N
*       REAL               ANORM, BNORM, CNDNMA, CNDNMB
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SLATB9 sets parameters for the matrix generator based on the type of
*> matrix to be generated.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] PATH
*> \verbatim
*>          PATH is CHARACTER*3
*>          The LAPACK path name.
*> \endverbatim
*>
*> \param[in] IMAT
*> \verbatim
*>          IMAT is INTEGER
*>          An integer key describing which matrix to generate for this
*>          path.
*>          = 1:   A: diagonal, B: upper triangular
*>          = 2:   A: upper triangular, B: upper triangular
*>          = 3:   A: lower triangular, B: upper triangular
*>          Else:  A: general dense, B: general dense
*> \endverbatim
*>
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows in the matrix to be generated.
*> \endverbatim
*>
*> \param[in] P
*> \verbatim
*>          P is INTEGER
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns in the matrix to be generated.
*> \endverbatim
*>
*> \param[out] TYPE
*> \verbatim
*>          TYPE is CHARACTER*1
*>          The type of the matrix to be generated:
*>          = 'S':  symmetric matrix;
*>          = 'P':  symmetric positive (semi)definite matrix;
*>          = 'N':  nonsymmetric matrix.
*> \endverbatim
*>
*> \param[out] KLA
*> \verbatim
*>          KLA is INTEGER
*>          The lower band width of the matrix to be generated.
*> \endverbatim
*>
*> \param[out] KUA
*> \verbatim
*>          KUA is INTEGER
*>          The upper band width of the matrix to be generated.
*> \endverbatim
*>
*> \param[out] KLB
*> \verbatim
*>          KLB is INTEGER
*>          The lower band width of the matrix to be generated.
*> \endverbatim
*>
*> \param[out] KUB
*> \verbatim
*>          KUA is INTEGER
*>          The upper band width of the matrix to be generated.
*> \endverbatim
*>
*> \param[out] ANORM
*> \verbatim
*>          ANORM is REAL
*>          The desired norm of the matrix to be generated.  The diagonal
*>          matrix of singular values or eigenvalues is scaled by this
*>          value.
*> \endverbatim
*>
*> \param[out] BNORM
*> \verbatim
*>          BNORM is REAL
*>          The desired norm of the matrix to be generated.  The diagonal
*>          matrix of singular values or eigenvalues is scaled by this
*>          value.
*> \endverbatim
*>
*> \param[out] MODEA
*> \verbatim
*>          MODEA is INTEGER
*>          A key indicating how to choose the vector of eigenvalues.
*> \endverbatim
*>
*> \param[out] MODEB
*> \verbatim
*>          MODEB is INTEGER
*>          A key indicating how to choose the vector of eigenvalues.
*> \endverbatim
*>
*> \param[out] CNDNMA
*> \verbatim
*>          CNDNMA is REAL
*>          The desired condition number.
*> \endverbatim
*>
*> \param[out] CNDNMB
*> \verbatim
*>          CNDNMB is REAL
*>          The desired condition number.
*> \endverbatim
*>
*> \param[out] DISTA
*> \verbatim
*>          DISTA is CHARACTER*1
*>          The type of distribution to be used by the random number
*>          generator.
*> \endverbatim
*>
*> \param[out] DISTB
*> \verbatim
*>          DISTB is CHARACTER*1
*>          The type of distribution to be used by the random number
*>          generator.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup single_eig
*
*  =====================================================================
      SUBROUTINE slatb9( PATH, IMAT, M, P, N, TYPE, KLA, KUA,
     $                   klb, kub, anorm, bnorm, modea, modeb,
     $                   cndnma, cndnmb, dista, distb )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          DISTA, DISTB, TYPE
      CHARACTER*3        PATH
      INTEGER            IMAT, KLA, KUA, KLB, KUB, M, P, MODEA, MODEB, N
      REAL               ANORM, BNORM, CNDNMA, CNDNMB
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               SHRINK, TENTH
      parameter                ( shrink = 0.25e0, tenth = 0.1e+0 )
      REAL               ONE, TEN
      parameter                ( one = 1.0e+0, ten = 1.0e+1 )
*     ..
*     .. Local Scalars ..
      LOGICAL            FIRST
      REAL               BADC1, BADC2, EPS, LARGE, SMALL
*     ..
*     .. External Functions ..
      LOGICAL            LSAMEN
      REAL               SLAMCH
      EXTERNAL           lsamen, slamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, sqrt
*     ..
*     .. External Subroutines ..
      EXTERNAL           slabad
*     ..
*     .. Save statement ..
      SAVE               eps, small, large, badc1, badc2, first
*     ..
*     .. Data statements ..
      DATA               first / .true. /
*     ..
*     .. Executable Statements ..
*
*     Set some constants for use in the subroutine.
*
      IF( first ) THEN
         first = .false.
         eps = slamch( 'Precision' )
         badc2 = tenth / eps
         badc1 = sqrt( badc2 )
         small = slamch( 'Safe minimum' )
         large = one / small
*
*        If it looks like we're on a Cray, take the square root of
*        SMALL and LARGE to avoid overflow and underflow problems.
*
         CALL slabad( small, large )
         small = shrink*( small / eps )
         large = one / small
      END IF
*
*     Set some parameters we don't plan to change.
*
      TYPE = 'N'
      dista = 'S'
      distb = 'S'
      modea = 3
      modeb = 4
*
*     Set the lower and upper bandwidths.
*
      IF( lsamen( 3, path, 'GRQ') .OR. lsamen( 3, path, 'LSE') .OR.
     $    lsamen( 3, path, 'GSV') )THEN
*
*        A: M by N, B: P by N
*
         IF( imat.EQ.1 ) THEN
*
*           A: diagonal, B: upper triangular
*
            kla = 0
            kua = 0
            klb = 0
            kub = max( n-1,0 )
*
         ELSE IF( imat.EQ.2 ) THEN
*
*           A: upper triangular, B: upper triangular
*
            kla = 0
            kua = max( n-1, 0 )
            klb = 0
            kub = max( n-1, 0 )
*
         ELSE IF( imat.EQ.3 ) THEN
*
*           A: lower triangular, B: upper triangular
*
            kla = max( m-1, 0 )
            kua = 0
            klb = 0
            kub = max( n-1, 0 )
*
         ELSE
*
*           A: general dense, B: general dense
*       
            kla = max( m-1, 0 )
            kua = max( n-1, 0 )
            klb = max( p-1, 0 )
            kub = max( n-1, 0 )
*
         END IF
*
      ELSE IF( lsamen( 3, path, 'GQR' ) .OR.
     $         lsamen( 3, path, 'GLM') )THEN
*
*        A: N by M, B: N by P
*
         IF( imat.EQ.1 ) THEN
*
*           A: diagonal, B: lower triangular
*
            kla = 0
            kua = 0
            klb = max( n-1,0 )
            kub = 0
         ELSE IF( imat.EQ.2 ) THEN
*
*           A: lower triangular, B: diagonal
*
            kla = max( n-1, 0 )
            kua = 0
            klb = 0
            kub = 0
*
         ELSE IF( imat.EQ.3 ) THEN
*
*           A: lower triangular, B: upper triangular
*
            kla = max( n-1, 0 )
            kua = 0
            klb = 0
            kub = max( p-1, 0 )
*
         ELSE
*
*           A: general dense, B: general dense
*
            kla = max( n-1, 0 )
            kua = max( m-1, 0 )
            klb = max( n-1, 0 )
            kub = max( p-1, 0 )
         END IF
*
      END IF
*
*     Set the condition number and norm.
*
      cndnma = ten*ten
      cndnmb = ten
      IF( lsamen( 3, path, 'GQR') .OR. lsamen( 3, path, 'GRQ') .OR.
     $    lsamen( 3, path, 'GSV') )THEN
         IF( imat.EQ.5 ) THEN
            cndnma = badc1
            cndnmb = badc1
         ELSE IF( imat.EQ.6 ) THEN
            cndnma = badc2
            cndnmb = badc2
         ELSE IF( imat.EQ.7 ) THEN
            cndnma = badc1
            cndnmb = badc2
         ELSE IF( imat.EQ.8 ) THEN
            cndnma = badc2
            cndnmb = badc1
         END IF
      END IF
*
      anorm = ten
      bnorm = ten*ten*ten
      IF( lsamen( 3, path, 'GQR') .OR. lsamen( 3, path, 'GRQ') )THEN
         IF( imat.EQ.7 ) THEN
            anorm = small
            bnorm = large
         ELSE IF( imat.EQ.8 ) THEN
            anorm = large
            bnorm = small
         END IF
      END IF
*
      IF( n.LE.1 )THEN
         cndnma = one
         cndnmb = one
      END IF
*
      RETURN
*
*     End of SLATB9
*
      END