subroutine ctbcon	(	character	NORM,
		character	UPLO,
		character	DIAG,
		integer	N,
		integer	KD,
		complex, dimension( ldab, * )	AB,
		integer	LDAB,
		real	RCOND,
		complex, dimension( * )	WORK,
		real, dimension( * )	RWORK,
		integer	INFO
	)

CTBCON

Download CTBCON + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CTBCON estimates the reciprocal of the condition number of a
 triangular band matrix A, in either the 1-norm or the infinity-norm.

 The norm of A is computed and an estimate is obtained for
 norm(inv(A)), then the reciprocal of the condition number is
 computed as
    RCOND = 1 / ( norm(A) * norm(inv(A)) ).

Parameters

[in]	NORM	NORM is CHARACTER*1 Specifies whether the 1-norm condition number or the infinity-norm condition number is required: = '1' or 'O': 1-norm; = 'I': Infinity-norm.
[in]	UPLO	UPLO is CHARACTER*1 = 'U': A is upper triangular; = 'L': A is lower triangular.
[in]	DIAG	DIAG is CHARACTER*1 = 'N': A is non-unit triangular; = 'U': A is unit triangular.
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	KD	KD is INTEGER The number of superdiagonals or subdiagonals of the triangular band matrix A. KD >= 0.
[in]	AB	AB is COMPLEX array, dimension (LDAB,N) The upper or lower triangular band matrix A, stored in the first kd+1 rows of the array. The j-th column of A is stored in the j-th column of the array AB as follows: if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j; if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+kd). If DIAG = 'U', the diagonal elements of A are not referenced and are assumed to be 1.
[in]	LDAB	LDAB is INTEGER The leading dimension of the array AB. LDAB >= KD+1.
[out]	RCOND	RCOND is REAL The reciprocal of the condition number of the matrix A, computed as RCOND = 1/(norm(A) * norm(inv(A))).
[out]	WORK	WORK is COMPLEX array, dimension (2*N)
[out]	RWORK	RWORK is REAL array, dimension (N)
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 145 of file ctbcon.f.

*
*  -- LAPACK computational routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          diag, norm, uplo
      INTEGER            info, kd, ldab, n
      REAL               rcond
*     ..
*     .. Array Arguments ..
      REAL               rwork( * )
      COMPLEX            ab( ldab, * ), work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               one, zero
      parameter                ( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            nounit, onenrm, upper
      CHARACTER          normin
      INTEGER            ix, kase, kase1
      REAL               ainvnm, anorm, scale, smlnum, xnorm
      COMPLEX            zdum
*     ..
*     .. Local Arrays ..
      INTEGER            isave( 3 )
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      INTEGER            icamax
      REAL               clantb, slamch
      EXTERNAL           lsame, icamax, clantb, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           clacn2, clatbs, csrscl, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, max, real
*     ..
*     .. Statement Functions ..
      REAL               cabs1
*     ..
*     .. Statement Function definitions ..
      cabs1( zdum ) = abs( REAL( ZDUM ) ) + abs( aimag( zdum ) )
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      onenrm = norm.EQ.'1' .OR. lsame( norm, 'O' )
      nounit = lsame( diag, 'N' )
*
      IF( .NOT.onenrm .AND. .NOT.lsame( norm, 'I' ) ) THEN
         info = -1
      ELSE IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -2
      ELSE IF( .NOT.nounit .AND. .NOT.lsame( diag, 'U' ) ) THEN
         info = -3
      ELSE IF( n.LT.0 ) THEN
         info = -4
      ELSE IF( kd.LT.0 ) THEN
         info = -5
      ELSE IF( ldab.LT.kd+1 ) THEN
         info = -7
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CTBCON', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 ) THEN
         rcond = one
         RETURN
      END IF
*
      rcond = zero
      smlnum = slamch( 'Safe minimum' )*REAL( MAX( N, 1 ) )
*
*     Compute the 1-norm of the triangular matrix A or A**H.
*
      anorm = clantb( norm, uplo, diag, n, kd, ab, ldab, rwork )
*
*     Continue only if ANORM > 0.
*
      IF( anorm.GT.zero ) THEN
*
*        Estimate the 1-norm of the inverse of A.
*
         ainvnm = zero
         normin = 'N'
         IF( onenrm ) THEN
            kase1 = 1
         ELSE
            kase1 = 2
         END IF
         kase = 0
   10    CONTINUE
         CALL clacn2( n, work( n+1 ), work, ainvnm, kase, isave )
         IF( kase.NE.0 ) THEN
            IF( kase.EQ.kase1 ) THEN
*
*              Multiply by inv(A).
*
               CALL clatbs( uplo, 'No transpose', diag, normin, n, kd,
     $                      ab, ldab, work, scale, rwork, info )
            ELSE
*
*              Multiply by inv(A**H).
*
               CALL clatbs( uplo, 'Conjugate transpose', diag, normin,
     $                      n, kd, ab, ldab, work, scale, rwork, info )
            END IF
            normin = 'Y'
*
*           Multiply by 1/SCALE if doing so will not cause overflow.
*
            IF( scale.NE.one ) THEN
               ix = icamax( n, work, 1 )
               xnorm = cabs1( work( ix ) )
               IF( scale.LT.xnorm*smlnum .OR. scale.EQ.zero )
     $            GO TO 20
               CALL csrscl( n, scale, work, 1 )
            END IF
            GO TO 10
         END IF
*
*        Compute the estimate of the reciprocal condition number.
*
         IF( ainvnm.NE.zero )
     $      rcond = ( one / anorm ) / ainvnm
      END IF
*
   20 CONTINUE
      RETURN
*
*     End of CTBCON
*

Here is the call graph for this function:

Here is the caller graph for this function: