subroutine csrscl	(	integer	N,
		real	SA,
		complex, dimension( * )	SX,
		integer	INCX
	)

CSRSCL multiplies a vector by the reciprocal of a real scalar.

Download CSRSCL + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CSRSCL multiplies an n-element complex vector x by the real scalar
 1/a.  This is done without overflow or underflow as long as
 the final result x/a does not overflow or underflow.

Parameters

[in]	N	N is INTEGER The number of components of the vector x.
[in]	SA	SA is REAL The scalar a which is used to divide each component of x. SA must be >= 0, or the subroutine will divide by zero.
[in,out]	SX	SX is COMPLEX array, dimension (1+(N-1)*abs(INCX)) The n-element vector x.
[in]	INCX	INCX is INTEGER The increment between successive values of the vector SX. > 0: SX(1) = X(1) and SX(1+(i-1)*INCX) = x(i), 1< i<= n

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

September 2012

Definition at line 86 of file csrscl.f.

*
*  -- LAPACK auxiliary routine (version 3.4.2) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     September 2012
*
*     .. Scalar Arguments ..
      INTEGER            incx, n
      REAL               sa
*     ..
*     .. Array Arguments ..
      COMPLEX            sx( * )
*     ..
*
* =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter                ( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            done
      REAL               bignum, cden, cden1, cnum, cnum1, mul, smlnum
*     ..
*     .. External Functions ..
      REAL               slamch
      EXTERNAL           slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           csscal, slabad
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( n.LE.0 )
     $   RETURN
*
*     Get machine parameters
*
      smlnum = slamch( 'S' )
      bignum = one / smlnum
      CALL slabad( smlnum, bignum )
*
*     Initialize the denominator to SA and the numerator to 1.
*
      cden = sa
      cnum = one
*
   10 CONTINUE
      cden1 = cden*smlnum
      cnum1 = cnum / bignum
      IF( abs( cden1 ).GT.abs( cnum ) .AND. cnum.NE.zero ) THEN
*
*        Pre-multiply X by SMLNUM if CDEN is large compared to CNUM.
*
         mul = smlnum
         done = .false.
         cden = cden1
      ELSE IF( abs( cnum1 ).GT.abs( cden ) ) THEN
*
*        Pre-multiply X by BIGNUM if CDEN is small compared to CNUM.
*
         mul = bignum
         done = .false.
         cnum = cnum1
      ELSE
*
*        Multiply X by CNUM / CDEN and return.
*
         mul = cnum / cden
         done = .true.
      END IF
*
*     Scale the vector X by MUL
*
      CALL csscal( n, mul, sx, incx )
*
      IF( .NOT.done )
     $   GO TO 10
*
      RETURN
*
*     End of CSRSCL
*

Here is the call graph for this function:

Here is the caller graph for this function: