zgbt01.f

Go to the documentation of this file.

*> \brief \b ZGBT01
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZGBT01( M, N, KL, KU, A, LDA, AFAC, LDAFAC, IPIV, WORK,
*                          RESID )
* 
*       .. Scalar Arguments ..
*       INTEGER            KL, KU, LDA, LDAFAC, M, N
*       DOUBLE PRECISION   RESID
*       ..
*       .. Array Arguments ..
*       INTEGER            IPIV( * )
*       COMPLEX*16         A( LDA, * ), AFAC( LDAFAC, * ), WORK( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZGBT01 reconstructs a band matrix  A  from its L*U factorization and
*> computes the residual:
*>    norm(L*U - A) / ( N * norm(A) * EPS ),
*> where EPS is the machine epsilon.
*>
*> The expression L*U - A is computed one column at a time, so A and
*> AFAC are not modified.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix A.  M >= 0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] KL
*> \verbatim
*>          KL is INTEGER
*>          The number of subdiagonals within the band of A.  KL >= 0.
*> \endverbatim
*>
*> \param[in] KU
*> \verbatim
*>          KU is INTEGER
*>          The number of superdiagonals within the band of A.  KU >= 0.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (LDA,N)
*>          The original matrix A in band storage, stored in rows 1 to
*>          KL+KU+1.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER.
*>          The leading dimension of the array A.  LDA >= max(1,KL+KU+1).
*> \endverbatim
*>
*> \param[in] AFAC
*> \verbatim
*>          AFAC is COMPLEX*16 array, dimension (LDAFAC,N)
*>          The factored form of the matrix A.  AFAC contains the banded
*>          factors L and U from the L*U factorization, as computed by
*>          ZGBTRF.  U is stored as an upper triangular band matrix with
*>          KL+KU superdiagonals in rows 1 to KL+KU+1, and the
*>          multipliers used during the factorization are stored in rows
*>          KL+KU+2 to 2*KL+KU+1.  See ZGBTRF for further details.
*> \endverbatim
*>
*> \param[in] LDAFAC
*> \verbatim
*>          LDAFAC is INTEGER
*>          The leading dimension of the array AFAC.
*>          LDAFAC >= max(1,2*KL*KU+1).
*> \endverbatim
*>
*> \param[in] IPIV
*> \verbatim
*>          IPIV is INTEGER array, dimension (min(M,N))
*>          The pivot indices from ZGBTRF.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX*16 array, dimension (2*KL+KU+1)
*> \endverbatim
*>
*> \param[out] RESID
*> \verbatim
*>          RESID is DOUBLE PRECISION
*>          norm(L*U - A) / ( N * norm(A) * EPS )
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup complex16_lin
*
*  =====================================================================
      SUBROUTINE zgbt01( M, N, KL, KU, A, LDA, AFAC, LDAFAC, IPIV, WORK,
     $                   resid )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            kl, ku, lda, ldafac, m, n
      DOUBLE PRECISION   resid
*     ..
*     .. Array Arguments ..
      INTEGER            ipiv( * )
      COMPLEX*16         a( lda, * ), afac( ldafac, * ), work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, i1, i2, il, ip, iw, j, jl, ju, jua, kd, lenj
      DOUBLE PRECISION   anorm, eps
      COMPLEX*16         t
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch, dzasum
      EXTERNAL           dlamch, dzasum
*     ..
*     .. External Subroutines ..
      EXTERNAL           zaxpy, zcopy
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dcmplx, max, min
*     ..
*     .. Executable Statements ..
*
*     Quick exit if M = 0 or N = 0.
*
      resid = zero
      IF( m.LE.0 .OR. n.LE.0 )
     $   return
*
*     Determine EPS and the norm of A.
*
      eps = dlamch( 'Epsilon' )
      kd = ku + 1
      anorm = zero
      DO 10 j = 1, n
         i1 = max( kd+1-j, 1 )
         i2 = min( kd+m-j, kl+kd )
         IF( i2.GE.i1 )
     $      anorm = max( anorm, dzasum( i2-i1+1, a( i1, j ), 1 ) )
   10 continue
*
*     Compute one column at a time of L*U - A.
*
      kd = kl + ku + 1
      DO 40 j = 1, n
*
*        Copy the J-th column of U to WORK.
*
         ju = min( kl+ku, j-1 )
         jl = min( kl, m-j )
         lenj = min( m, j ) - j + ju + 1
         IF( lenj.GT.0 ) THEN
            CALL zcopy( lenj, afac( kd-ju, j ), 1, work, 1 )
            DO 20 i = lenj + 1, ju + jl + 1
               work( i ) = zero
   20       continue
*
*           Multiply by the unit lower triangular matrix L.  Note that L
*           is stored as a product of transformations and permutations.
*
            DO 30 i = min( m-1, j ), j - ju, -1
               il = min( kl, m-i )
               IF( il.GT.0 ) THEN
                  iw = i - j + ju + 1
                  t = work( iw )
                  CALL zaxpy( il, t, afac( kd+1, i ), 1, work( iw+1 ),
     $                        1 )
                  ip = ipiv( i )
                  IF( i.NE.ip ) THEN
                     ip = ip - j + ju + 1
                     work( iw ) = work( ip )
                     work( ip ) = t
                  END IF
               END IF
   30       continue
*
*           Subtract the corresponding column of A.
*
            jua = min( ju, ku )
            IF( jua+jl+1.GT.0 )
     $         CALL zaxpy( jua+jl+1, -dcmplx( one ), a( ku+1-jua, j ),
     $                     1, work( ju+1-jua ), 1 )
*
*           Compute the 1-norm of the column.
*
            resid = max( resid, dzasum( ju+jl+1, work, 1 ) )
         END IF
   40 continue
*
*     Compute norm( L*U - A ) / ( N * norm(A) * EPS )
*
      IF( anorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         resid = ( ( resid / dble( n ) ) / anorm ) / eps
      END IF
*
      return
*
*     End of ZGBT01
*
      END