zhpt21.f

Go to the documentation of this file.

*> \brief \b ZHPT21
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZHPT21( ITYPE, UPLO, N, KBAND, AP, D, E, U, LDU, VP,
*                          TAU, WORK, RWORK, RESULT )
* 
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            ITYPE, KBAND, LDU, N
*       ..
*       .. Array Arguments ..
*       DOUBLE PRECISION   D( * ), E( * ), RESULT( 2 ), RWORK( * )
*       COMPLEX*16         AP( * ), TAU( * ), U( LDU, * ), VP( * ),
*      $                   WORK( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZHPT21  generally checks a decomposition of the form
*>
*>         A = U S UC>
*> where * means conjugate transpose, A is hermitian, U is
*> unitary, and S is diagonal (if KBAND=0) or (real) symmetric
*> tridiagonal (if KBAND=1).  If ITYPE=1, then U is represented as
*> a dense matrix, otherwise the U is expressed as a product of
*> Householder transformations, whose vectors are stored in the
*> array "V" and whose scaling constants are in "TAU"; we shall
*> use the letter "V" to refer to the product of Householder
*> transformations (which should be equal to U).
*>
*> Specifically, if ITYPE=1, then:
*>
*>         RESULT(1) = | A - U S U* | / ( |A| n ulp ) *andC>         RESULT(2) = | I - UU* | / ( n ulp )
*>
*> If ITYPE=2, then:
*>
*>         RESULT(1) = | A - V S V* | / ( |A| n ulp )
*>
*> If ITYPE=3, then:
*>
*>         RESULT(1) = | I - UV* | / ( n ulp )
*>
*> Packed storage means that, for example, if UPLO='U', then the columns
*> of the upper triangle of A are stored one after another, so that
*> A(1,j+1) immediately follows A(j,j) in the array AP.  Similarly, if
*> UPLO='L', then the columns of the lower triangle of A are stored one
*> after another in AP, so that A(j+1,j+1) immediately follows A(n,j)
*> in the array AP.  This means that A(i,j) is stored in:
*>
*>    AP( i + j*(j-1)/2 )                 if UPLO='U'
*>
*>    AP( i + (2*n-j)*(j-1)/2 )           if UPLO='L'
*>
*> The array VP bears the same relation to the matrix V that A does to
*> AP.
*>
*> For ITYPE > 1, the transformation U is expressed as a product
*> of Householder transformations:
*>
*>    If UPLO='U', then  V = H(n-1)...H(1),  where
*>
*>        H(j) = I  -  tau(j) v(j) v(j)C>
*>    and the first j-1 elements of v(j) are stored in V(1:j-1,j+1),
*>    (i.e., VP( j*(j+1)/2 + 1 : j*(j+1)/2 + j-1 ) ),
*>    the j-th element is 1, and the last n-j elements are 0.
*>
*>    If UPLO='L', then  V = H(1)...H(n-1),  where
*>
*>        H(j) = I  -  tau(j) v(j) v(j)C>
*>    and the first j elements of v(j) are 0, the (j+1)-st is 1, and the
*>    (j+2)-nd through n-th elements are stored in V(j+2:n,j) (i.e.,
*>    in VP( (2*n-j)*(j-1)/2 + j+2 : (2*n-j)*(j-1)/2 + n ) .)
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] ITYPE
*> \verbatim
*>          ITYPE is INTEGER
*>          Specifies the type of tests to be performed.
*>          1: U expressed as a dense unitary matrix:
*>             RESULT(1) = | A - U S U* | / ( |A| n ulp )   *andC>             RESULT(2) = | I - UU* | / ( n ulp )
*>
*>          2: U expressed as a product V of Housholder transformations:
*>             RESULT(1) = | A - V S V* | / ( |A| n ulp )
*>
*>          3: U expressed both as a dense unitary matrix and
*>             as a product of Housholder transformations:
*>             RESULT(1) = | I - UV* | / ( n ulp )
*> \endverbatim
*>
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER
*>          If UPLO='U', the upper triangle of A and V will be used and
*>          the (strictly) lower triangle will not be referenced.
*>          If UPLO='L', the lower triangle of A and V will be used and
*>          the (strictly) upper triangle will not be referenced.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The size of the matrix.  If it is zero, ZHPT21 does nothing.
*>          It must be at least zero.
*> \endverbatim
*>
*> \param[in] KBAND
*> \verbatim
*>          KBAND is INTEGER
*>          The bandwidth of the matrix.  It may only be zero or one.
*>          If zero, then S is diagonal, and E is not referenced.  If
*>          one, then S is symmetric tri-diagonal.
*> \endverbatim
*>
*> \param[in] AP
*> \verbatim
*>          AP is COMPLEX*16 array, dimension (N*(N+1)/2)
*>          The original (unfactored) matrix.  It is assumed to be
*>          hermitian, and contains the columns of just the upper
*>          triangle (UPLO='U') or only the lower triangle (UPLO='L'),
*>          packed one after another.
*> \endverbatim
*>
*> \param[in] D
*> \verbatim
*>          D is DOUBLE PRECISION array, dimension (N)
*>          The diagonal of the (symmetric tri-) diagonal matrix.
*> \endverbatim
*>
*> \param[in] E
*> \verbatim
*>          E is DOUBLE PRECISION array, dimension (N)
*>          The off-diagonal of the (symmetric tri-) diagonal matrix.
*>          E(1) is the (1,2) and (2,1) element, E(2) is the (2,3) and
*>          (3,2) element, etc.
*>          Not referenced if KBAND=0.
*> \endverbatim
*>
*> \param[in] U
*> \verbatim
*>          U is COMPLEX*16 array, dimension (LDU, N)
*>          If ITYPE=1 or 3, this contains the unitary matrix in
*>          the decomposition, expressed as a dense matrix.  If ITYPE=2,
*>          then it is not referenced.
*> \endverbatim
*>
*> \param[in] LDU
*> \verbatim
*>          LDU is INTEGER
*>          The leading dimension of U.  LDU must be at least N and
*>          at least 1.
*> \endverbatim
*>
*> \param[in] VP
*> \verbatim
*>          VP is DOUBLE PRECISION array, dimension (N*(N+1)/2)
*>          If ITYPE=2 or 3, the columns of this array contain the
*>          Householder vectors used to describe the unitary matrix
*>          in the decomposition, as described in purpose.
*>          *NOTE* If ITYPE=2 or 3, V is modified and restored.  The
*>          subdiagonal (if UPLO='L') or the superdiagonal (if UPLO='U')
*>          is set to one, and later reset to its original value, during
*>          the course of the calculation.
*>          If ITYPE=1, then it is neither referenced nor modified.
*> \endverbatim
*>
*> \param[in] TAU
*> \verbatim
*>          TAU is COMPLEX*16 array, dimension (N)
*>          If ITYPE >= 2, then TAU(j) is the scalar factor of
*>          v(j) v(j)* in the Householder transformation H(j) of
*>          the product  U = H(1)...H(n-2)
*>          If ITYPE < 2, then TAU is not referenced.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX*16 array, dimension (N**2)
*>          Workspace.
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is DOUBLE PRECISION array, dimension (N)
*>          Workspace.
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is DOUBLE PRECISION array, dimension (2)
*>          The values computed by the two tests described above.  The
*>          values are currently limited to 1/ulp, to avoid overflow.
*>          RESULT(1) is always modified.  RESULT(2) is modified only
*>          if ITYPE=1.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup complex16_eig
*
*  =====================================================================
      SUBROUTINE zhpt21( ITYPE, UPLO, N, KBAND, AP, D, E, U, LDU, VP,
     $                   tau, work, rwork, result )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            itype, kband, ldu, n
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   d( * ), e( * ), result( 2 ), rwork( * )
      COMPLEX*16         ap( * ), tau( * ), u( ldu, * ), vp( * ),
     $                   work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one, ten
      parameter( zero = 0.0d+0, one = 1.0d+0, ten = 10.0d+0 )
      DOUBLE PRECISION   half
      parameter( half = 1.0d+0 / 2.0d+0 )
      COMPLEX*16         czero, cone
      parameter( czero = ( 0.0d+0, 0.0d+0 ),
     $                   cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            lower
      CHARACTER          cuplo
      INTEGER            iinfo, j, jp, jp1, jr, lap
      DOUBLE PRECISION   anorm, ulp, unfl, wnorm
      COMPLEX*16         temp, vsave
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      DOUBLE PRECISION   dlamch, zlange, zlanhp
      COMPLEX*16         zdotc
      EXTERNAL           lsame, dlamch, zlange, zlanhp, zdotc
*     ..
*     .. External Subroutines ..
      EXTERNAL           zaxpy, zcopy, zgemm, zhpmv, zhpr, zhpr2,
     $                   zlacpy, zlaset, zupmtr
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dcmplx, max, min
*     ..
*     .. Executable Statements ..
*
*     Constants
*
      result( 1 ) = zero
      IF( itype.EQ.1 )
     $   result( 2 ) = zero
      IF( n.LE.0 )
     $   return
*
      lap = ( n*( n+1 ) ) / 2
*
      IF( lsame( uplo, 'U' ) ) THEN
         lower = .false.
         cuplo = 'U'
      ELSE
         lower = .true.
         cuplo = 'L'
      END IF
*
      unfl = dlamch( 'Safe minimum' )
      ulp = dlamch( 'Epsilon' )*dlamch( 'Base' )
*
*     Some Error Checks
*
      IF( itype.LT.1 .OR. itype.GT.3 ) THEN
         result( 1 ) = ten / ulp
         return
      END IF
*
*     Do Test 1
*
*     Norm of A:
*
      IF( itype.EQ.3 ) THEN
         anorm = one
      ELSE
         anorm = max( zlanhp( '1', cuplo, n, ap, rwork ), unfl )
      END IF
*
*     Compute error matrix:
*
      IF( itype.EQ.1 ) THEN
*
*        ITYPE=1: error = A - U S U*
*
         CALL zlaset( 'Full', n, n, czero, czero, work, n )
         CALL zcopy( lap, ap, 1, work, 1 )
*
         DO 10 j = 1, n
            CALL zhpr( cuplo, n, -d( j ), u( 1, j ), 1, work )
   10    continue
*
         IF( n.GT.1 .AND. kband.EQ.1 ) THEN
            DO 20 j = 1, n - 1
               CALL zhpr2( cuplo, n, -dcmplx( e( j ) ), u( 1, j ), 1,
     $                     u( 1, j-1 ), 1, work )
   20       continue
         END IF
         wnorm = zlanhp( '1', cuplo, n, work, rwork )
*
      ELSE IF( itype.EQ.2 ) THEN
*
*        ITYPE=2: error = V S V* - A
*
         CALL zlaset( 'Full', n, n, czero, czero, work, n )
*
         IF( lower ) THEN
            work( lap ) = d( n )
            DO 40 j = n - 1, 1, -1
               jp = ( ( 2*n-j )*( j-1 ) ) / 2
               jp1 = jp + n - j
               IF( kband.EQ.1 ) THEN
                  work( jp+j+1 ) = ( cone-tau( j ) )*e( j )
                  DO 30 jr = j + 2, n
                     work( jp+jr ) = -tau( j )*e( j )*vp( jp+jr )
   30             continue
               END IF
*
               IF( tau( j ).NE.czero ) THEN
                  vsave = vp( jp+j+1 )
                  vp( jp+j+1 ) = cone
                  CALL zhpmv( 'L', n-j, cone, work( jp1+j+1 ),
     $                        vp( jp+j+1 ), 1, czero, work( lap+1 ), 1 )
                  temp = -half*tau( j )*zdotc( n-j, work( lap+1 ), 1,
     $                   vp( jp+j+1 ), 1 )
                  CALL zaxpy( n-j, temp, vp( jp+j+1 ), 1, work( lap+1 ),
     $                        1 )
                  CALL zhpr2( 'L', n-j, -tau( j ), vp( jp+j+1 ), 1,
     $                        work( lap+1 ), 1, work( jp1+j+1 ) )
*
                  vp( jp+j+1 ) = vsave
               END IF
               work( jp+j ) = d( j )
   40       continue
         ELSE
            work( 1 ) = d( 1 )
            DO 60 j = 1, n - 1
               jp = ( j*( j-1 ) ) / 2
               jp1 = jp + j
               IF( kband.EQ.1 ) THEN
                  work( jp1+j ) = ( cone-tau( j ) )*e( j )
                  DO 50 jr = 1, j - 1
                     work( jp1+jr ) = -tau( j )*e( j )*vp( jp1+jr )
   50             continue
               END IF
*
               IF( tau( j ).NE.czero ) THEN
                  vsave = vp( jp1+j )
                  vp( jp1+j ) = cone
                  CALL zhpmv( 'U', j, cone, work, vp( jp1+1 ), 1, czero,
     $                        work( lap+1 ), 1 )
                  temp = -half*tau( j )*zdotc( j, work( lap+1 ), 1,
     $                   vp( jp1+1 ), 1 )
                  CALL zaxpy( j, temp, vp( jp1+1 ), 1, work( lap+1 ),
     $                        1 )
                  CALL zhpr2( 'U', j, -tau( j ), vp( jp1+1 ), 1,
     $                        work( lap+1 ), 1, work )
                  vp( jp1+j ) = vsave
               END IF
               work( jp1+j+1 ) = d( j+1 )
   60       continue
         END IF
*
         DO 70 j = 1, lap
            work( j ) = work( j ) - ap( j )
   70    continue
         wnorm = zlanhp( '1', cuplo, n, work, rwork )
*
      ELSE IF( itype.EQ.3 ) THEN
*
*        ITYPE=3: error = U V* - I
*
         IF( n.LT.2 )
     $      return
         CALL zlacpy( ' ', n, n, u, ldu, work, n )
         CALL zupmtr( 'R', cuplo, 'C', n, n, vp, tau, work, n,
     $                work( n**2+1 ), iinfo )
         IF( iinfo.NE.0 ) THEN
            result( 1 ) = ten / ulp
            return
         END IF
*
         DO 80 j = 1, n
            work( ( n+1 )*( j-1 )+1 ) = work( ( n+1 )*( j-1 )+1 ) - cone
   80    continue
*
         wnorm = zlange( '1', n, n, work, n, rwork )
      END IF
*
      IF( anorm.GT.wnorm ) THEN
         result( 1 ) = ( wnorm / anorm ) / ( n*ulp )
      ELSE
         IF( anorm.LT.one ) THEN
            result( 1 ) = ( min( wnorm, n*anorm ) / anorm ) / ( n*ulp )
         ELSE
            result( 1 ) = min( wnorm / anorm, dble( n ) ) / ( n*ulp )
         END IF
      END IF
*
*     Do Test 2
*
*     Compute  UU* - I
*
      IF( itype.EQ.1 ) THEN
         CALL zgemm( 'N', 'C', n, n, n, cone, u, ldu, u, ldu, czero,
     $               work, n )
*
         DO 90 j = 1, n
            work( ( n+1 )*( j-1 )+1 ) = work( ( n+1 )*( j-1 )+1 ) - cone
   90    continue
*
         result( 2 ) = min( zlange( '1', n, n, work, n, rwork ),
     $                 dble( n ) ) / ( n*ulp )
      END IF
*
      return
*
*     End of ZHPT21
*
      END