zchkps.f

Go to the documentation of this file.

*> \brief \b ZCHKPS
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZCHKPS( DOTYPE, NN, NVAL, NNB, NBVAL, NRANK, RANKVAL,
*                          THRESH, TSTERR, NMAX, A, AFAC, PERM, PIV, WORK,
*                          RWORK, NOUT )
* 
*       .. Scalar Arguments ..
*       DOUBLE PRECISION   THRESH
*       INTEGER            NMAX, NN, NNB, NOUT, NRANK
*       LOGICAL            TSTERR
*       ..
*       .. Array Arguments ..
*       COMPLEX*16         A( * ), AFAC( * ), PERM( * ), WORK( * )
*       DOUBLE PRECISION   RWORK( * )
*       INTEGER            NBVAL( * ), NVAL( * ), PIV( * ), RANKVAL( * )
*       LOGICAL            DOTYPE( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZCHKPS tests ZPSTRF.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          The matrix types to be used for testing.  Matrices of type j
*>          (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) =
*>          .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER
*>          The number of values of N contained in the vector NVAL.
*> \endverbatim
*>
*> \param[in] NVAL
*> \verbatim
*>          NVAL is INTEGER array, dimension (NN)
*>          The values of the matrix dimension N.
*> \endverbatim
*>
*> \param[in] NNB
*> \verbatim
*>          NNB is INTEGER
*>          The number of values of NB contained in the vector NBVAL.
*> \endverbatim
*>
*> \param[in] NBVAL
*> \verbatim
*>          NBVAL is INTEGER array, dimension (NBVAL)
*>          The values of the block size NB.
*> \endverbatim
*>
*> \param[in] NRANK
*> \verbatim
*>          NRANK is INTEGER
*>          The number of values of RANK contained in the vector RANKVAL.
*> \endverbatim
*>
*> \param[in] RANKVAL
*> \verbatim
*>          RANKVAL is INTEGER array, dimension (NBVAL)
*>          The values of the block size NB.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is DOUBLE PRECISION
*>          The threshold value for the test ratios.  A result is
*>          included in the output file if RESULT >= THRESH.  To have
*>          every test ratio printed, use THRESH = 0.
*> \endverbatim
*>
*> \param[in] TSTERR
*> \verbatim
*>          TSTERR is LOGICAL
*>          Flag that indicates whether error exits are to be tested.
*> \endverbatim
*>
*> \param[in] NMAX
*> \verbatim
*>          NMAX is INTEGER
*>          The maximum value permitted for N, used in dimensioning the
*>          work arrays.
*> \endverbatim
*>
*> \param[out] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] AFAC
*> \verbatim
*>          AFAC is COMPLEX*16 array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] PERM
*> \verbatim
*>          PERM is COMPLEX*16 array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] PIV
*> \verbatim
*>          PIV is INTEGER array, dimension (NMAX)
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX*16 array, dimension (NMAX*3)
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is DOUBLE PRECISION array, dimension (NMAX)
*> \endverbatim
*>
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>          The unit number for output.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup complex16_lin
*
*  =====================================================================
      SUBROUTINE zchkps( DOTYPE, NN, NVAL, NNB, NBVAL, NRANK, RANKVAL,
     $                   thresh, tsterr, nmax, a, afac, perm, piv, work,
     $                   rwork, nout )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      DOUBLE PRECISION   thresh
      INTEGER            nmax, nn, nnb, nout, nrank
      LOGICAL            tsterr
*     ..
*     .. Array Arguments ..
      COMPLEX*16         a( * ), afac( * ), perm( * ), work( * )
      DOUBLE PRECISION   rwork( * )
      INTEGER            nbval( * ), nval( * ), piv( * ), rankval( * )
      LOGICAL            dotype( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   one
      parameter( one = 1.0e+0 )
      INTEGER            ntypes
      parameter( ntypes = 9 )
*     ..
*     .. Local Scalars ..
      DOUBLE PRECISION   anorm, cndnum, result, tol
      INTEGER            comprank, i, imat, in, inb, info, irank, iuplo,
     $                   izero, kl, ku, lda, mode, n, nb, nerrs, nfail,
     $                   nimat, nrun, rank, rankdiff
      CHARACTER          dist, type, uplo
      CHARACTER*3        path
*     ..
*     .. Local Arrays ..
      INTEGER            iseed( 4 ), iseedy( 4 )
      CHARACTER          uplos( 2 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           alaerh, alahd, alasum, xlaenv, zerrps, zlacpy,
     $                   zlatb5, zlatmt, zpst01, zpstrf
*     ..
*     .. Scalars in Common ..
      INTEGER            infot, nunit
      LOGICAL            lerr, ok
      CHARACTER*32       srnamt
*     ..
*     .. Common blocks ..
      common             / infoc / infot, nunit, ok, lerr
      common             / srnamc / srnamt
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max, ceiling
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
      DATA               uplos / 'U', 'L' /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      path( 1: 1 ) = 'Zomplex Precision'
      path( 2: 3 ) = 'PS'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 100 i = 1, 4
         iseed( i ) = iseedy( i )
  100 continue
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL zerrps( path, nout )
      infot = 0
*
*     Do for each value of N in NVAL
*
      DO 150 in = 1, nn
         n = nval( in )
         lda = max( n, 1 )
         nimat = ntypes
         IF( n.LE.0 )
     $      nimat = 1
*
         izero = 0
         DO 140 imat = 1, nimat
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         go to 140
*
*              Do for each value of RANK in RANKVAL
*
            DO 130 irank = 1, nrank
*
*              Only repeat test 3 to 5 for different ranks
*              Other tests use full rank
*
               IF( ( imat.LT.3 .OR. imat.GT.5 ) .AND. irank.GT.1 )
     $            go to 130
*
               rank = ceiling( ( n * dble( rankval( irank ) ) )
     $              / 100.e+0 )
*
*
*           Do first for UPLO = 'U', then for UPLO = 'L'
*
               DO 120 iuplo = 1, 2
                  uplo = uplos( iuplo )
*
*              Set up parameters with ZLATB5 and generate a test matrix
*              with ZLATMT.
*
                  CALL zlatb5( path, imat, n, type, kl, ku, anorm,
     $                         mode, cndnum, dist )
*
                  srnamt = 'ZLATMT'
                  CALL zlatmt( n, n, dist, iseed, type, rwork, mode,
     $                         cndnum, anorm, rank, kl, ku, uplo, a,
     $                         lda, work, info )
*
*              Check error code from ZLATMT.
*
                  IF( info.NE.0 ) THEN
                    CALL alaerh( path, 'ZLATMT', info, 0, uplo, n,
     $                           n, -1, -1, -1, imat, nfail, nerrs,
     $                           nout )
                     go to 120
                  END IF
*
*              Do for each value of NB in NBVAL
*
                  DO 110 inb = 1, nnb
                     nb = nbval( inb )
                     CALL xlaenv( 1, nb )
*
*                 Compute the pivoted L*L' or U'*U factorization
*                 of the matrix.
*
                     CALL zlacpy( uplo, n, n, a, lda, afac, lda )
                     srnamt = 'ZPSTRF'
*
*                 Use default tolerance
*
                     tol = -one
                     CALL zpstrf( uplo, n, afac, lda, piv, comprank,
     $                            tol, rwork, info )
*
*                 Check error code from ZPSTRF.
*
                     IF( (info.LT.izero)
     $                    .OR.(info.NE.izero.AND.rank.EQ.n)
     $                    .OR.(info.LE.izero.AND.rank.LT.n) ) THEN
                        CALL alaerh( path, 'ZPSTRF', info, izero,
     $                               uplo, n, n, -1, -1, nb, imat,
     $                               nfail, nerrs, nout )
                        go to 110
                     END IF
*
*                 Skip the test if INFO is not 0.
*
                     IF( info.NE.0 )
     $                  go to 110
*
*                 Reconstruct matrix from factors and compute residual.
*
*                 PERM holds permuted L*L^T or U^T*U
*
                     CALL zpst01( uplo, n, a, lda, afac, lda, perm, lda,
     $                            piv, rwork, result, comprank )
*
*                 Print information about the tests that did not pass
*                 the threshold or where computed rank was not RANK.
*
                     IF( n.EQ.0 )
     $                  comprank = 0
                     rankdiff = rank - comprank
                     IF( result.GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9999 )uplo, n, rank,
     $                     rankdiff, nb, imat, result
                        nfail = nfail + 1
                     END IF
                     nrun = nrun + 1
  110             continue
*
  120          continue
  130       continue
  140    continue
  150 continue
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 format( ' UPLO = ''', a1, ''', N =', i5, ', RANK =', i3,
     $      ', Diff =', i5, ', NB =', i4, ', type ', i2, ', Ratio =',
     $      g12.5 )
      return
*
*     End of ZCHKPS
*
      END