chptrs.f

Go to the documentation of this file.

*> \brief \b CHPTRS
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*> \htmlonly
*> Download CHPTRS + dependencies 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/chptrs.f"> 
*> [TGZ]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/chptrs.f"> 
*> [ZIP]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/chptrs.f"> 
*> [TXT]</a>
*> \endhtmlonly 
*
*  Definition:
*  ===========
*
*       SUBROUTINE CHPTRS( UPLO, N, NRHS, AP, IPIV, B, LDB, INFO )
* 
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            INFO, LDB, N, NRHS
*       ..
*       .. Array Arguments ..
*       INTEGER            IPIV( * )
*       COMPLEX            AP( * ), B( LDB, * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CHPTRS solves a system of linear equations A*X = B with a complex
*> Hermitian matrix A stored in packed format using the factorization
*> A = U*D*U**H or A = L*D*L**H computed by CHPTRF.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the details of the factorization are stored
*>          as an upper or lower triangular matrix.
*>          = 'U':  Upper triangular, form is A = U*D*U**H;
*>          = 'L':  Lower triangular, form is A = L*D*L**H.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>          The number of right hand sides, i.e., the number of columns
*>          of the matrix B.  NRHS >= 0.
*> \endverbatim
*>
*> \param[in] AP
*> \verbatim
*>          AP is COMPLEX array, dimension (N*(N+1)/2)
*>          The block diagonal matrix D and the multipliers used to
*>          obtain the factor U or L as computed by CHPTRF, stored as a
*>          packed triangular matrix.
*> \endverbatim
*>
*> \param[in] IPIV
*> \verbatim
*>          IPIV is INTEGER array, dimension (N)
*>          Details of the interchanges and the block structure of D
*>          as determined by CHPTRF.
*> \endverbatim
*>
*> \param[in,out] B
*> \verbatim
*>          B is COMPLEX array, dimension (LDB,NRHS)
*>          On entry, the right hand side matrix B.
*>          On exit, the solution matrix X.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B.  LDB >= max(1,N).
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit
*>          < 0: if INFO = -i, the i-th argument had an illegal value
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup complexOTHERcomputational
*
*  =====================================================================
      SUBROUTINE chptrs( UPLO, N, NRHS, AP, IPIV, B, LDB, INFO )
*
*  -- LAPACK computational routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            info, ldb, n, nrhs
*     ..
*     .. Array Arguments ..
      INTEGER            ipiv( * )
      COMPLEX            ap( * ), b( ldb, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            one
      parameter( one = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            upper
      INTEGER            j, k, kc, kp
      REAL               s
      COMPLEX            ak, akm1, akm1k, bk, bkm1, denom
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemv, cgeru, clacgv, csscal, cswap, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          conjg, max, real
*     ..
*     .. Executable Statements ..
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( nrhs.LT.0 ) THEN
         info = -3
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -7
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CHPTRS', -info )
         return
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 .OR. nrhs.EQ.0 )
     $   return
*
      IF( upper ) THEN
*
*        Solve A*X = B, where A = U*D*U**H.
*
*        First solve U*D*X = B, overwriting B with X.
*
*        K is the main loop index, decreasing from N to 1 in steps of
*        1 or 2, depending on the size of the diagonal blocks.
*
         k = n
         kc = n*( n+1 ) / 2 + 1
   10    continue
*
*        If K < 1, exit from loop.
*
         IF( k.LT.1 )
     $      go to 30
*
         kc = kc - k
         IF( ipiv( k ).GT.0 ) THEN
*
*           1 x 1 diagonal block
*
*           Interchange rows K and IPIV(K).
*
            kp = ipiv( k )
            IF( kp.NE.k )
     $         CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
*
*           Multiply by inv(U(K)), where U(K) is the transformation
*           stored in column K of A.
*
            CALL cgeru( k-1, nrhs, -one, ap( kc ), 1, b( k, 1 ), ldb,
     $                  b( 1, 1 ), ldb )
*
*           Multiply by the inverse of the diagonal block.
*
            s = REAL( ONE ) / REAL( AP( KC+K-1 ) )
            CALL csscal( nrhs, s, b( k, 1 ), ldb )
            k = k - 1
         ELSE
*
*           2 x 2 diagonal block
*
*           Interchange rows K-1 and -IPIV(K).
*
            kp = -ipiv( k )
            IF( kp.NE.k-1 )
     $         CALL cswap( nrhs, b( k-1, 1 ), ldb, b( kp, 1 ), ldb )
*
*           Multiply by inv(U(K)), where U(K) is the transformation
*           stored in columns K-1 and K of A.
*
            CALL cgeru( k-2, nrhs, -one, ap( kc ), 1, b( k, 1 ), ldb,
     $                  b( 1, 1 ), ldb )
            CALL cgeru( k-2, nrhs, -one, ap( kc-( k-1 ) ), 1,
     $                  b( k-1, 1 ), ldb, b( 1, 1 ), ldb )
*
*           Multiply by the inverse of the diagonal block.
*
            akm1k = ap( kc+k-2 )
            akm1 = ap( kc-1 ) / akm1k
            ak = ap( kc+k-1 ) / conjg( akm1k )
            denom = akm1*ak - one
            DO 20 j = 1, nrhs
               bkm1 = b( k-1, j ) / akm1k
               bk = b( k, j ) / conjg( akm1k )
               b( k-1, j ) = ( ak*bkm1-bk ) / denom
               b( k, j ) = ( akm1*bk-bkm1 ) / denom
   20       continue
            kc = kc - k + 1
            k = k - 2
         END IF
*
         go to 10
   30    continue
*
*        Next solve U**H *X = B, overwriting B with X.
*
*        K is the main loop index, increasing from 1 to N in steps of
*        1 or 2, depending on the size of the diagonal blocks.
*
         k = 1
         kc = 1
   40    continue
*
*        If K > N, exit from loop.
*
         IF( k.GT.n )
     $      go to 50
*
         IF( ipiv( k ).GT.0 ) THEN
*
*           1 x 1 diagonal block
*
*           Multiply by inv(U**H(K)), where U(K) is the transformation
*           stored in column K of A.
*
            IF( k.GT.1 ) THEN
               CALL clacgv( nrhs, b( k, 1 ), ldb )
               CALL cgemv( 'Conjugate transpose', k-1, nrhs, -one, b,
     $                     ldb, ap( kc ), 1, one, b( k, 1 ), ldb )
               CALL clacgv( nrhs, b( k, 1 ), ldb )
            END IF
*
*           Interchange rows K and IPIV(K).
*
            kp = ipiv( k )
            IF( kp.NE.k )
     $         CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
            kc = kc + k
            k = k + 1
         ELSE
*
*           2 x 2 diagonal block
*
*           Multiply by inv(U**H(K+1)), where U(K+1) is the transformation
*           stored in columns K and K+1 of A.
*
            IF( k.GT.1 ) THEN
               CALL clacgv( nrhs, b( k, 1 ), ldb )
               CALL cgemv( 'Conjugate transpose', k-1, nrhs, -one, b,
     $                     ldb, ap( kc ), 1, one, b( k, 1 ), ldb )
               CALL clacgv( nrhs, b( k, 1 ), ldb )
*
               CALL clacgv( nrhs, b( k+1, 1 ), ldb )
               CALL cgemv( 'Conjugate transpose', k-1, nrhs, -one, b,
     $                     ldb, ap( kc+k ), 1, one, b( k+1, 1 ), ldb )
               CALL clacgv( nrhs, b( k+1, 1 ), ldb )
            END IF
*
*           Interchange rows K and -IPIV(K).
*
            kp = -ipiv( k )
            IF( kp.NE.k )
     $         CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
            kc = kc + 2*k + 1
            k = k + 2
         END IF
*
         go to 40
   50    continue
*
      ELSE
*
*        Solve A*X = B, where A = L*D*L**H.
*
*        First solve L*D*X = B, overwriting B with X.
*
*        K is the main loop index, increasing from 1 to N in steps of
*        1 or 2, depending on the size of the diagonal blocks.
*
         k = 1
         kc = 1
   60    continue
*
*        If K > N, exit from loop.
*
         IF( k.GT.n )
     $      go to 80
*
         IF( ipiv( k ).GT.0 ) THEN
*
*           1 x 1 diagonal block
*
*           Interchange rows K and IPIV(K).
*
            kp = ipiv( k )
            IF( kp.NE.k )
     $         CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
*
*           Multiply by inv(L(K)), where L(K) is the transformation
*           stored in column K of A.
*
            IF( k.LT.n )
     $         CALL cgeru( n-k, nrhs, -one, ap( kc+1 ), 1, b( k, 1 ),
     $                     ldb, b( k+1, 1 ), ldb )
*
*           Multiply by the inverse of the diagonal block.
*
            s = REAL( ONE ) / REAL( AP( KC ) )
            CALL csscal( nrhs, s, b( k, 1 ), ldb )
            kc = kc + n - k + 1
            k = k + 1
         ELSE
*
*           2 x 2 diagonal block
*
*           Interchange rows K+1 and -IPIV(K).
*
            kp = -ipiv( k )
            IF( kp.NE.k+1 )
     $         CALL cswap( nrhs, b( k+1, 1 ), ldb, b( kp, 1 ), ldb )
*
*           Multiply by inv(L(K)), where L(K) is the transformation
*           stored in columns K and K+1 of A.
*
            IF( k.LT.n-1 ) THEN
               CALL cgeru( n-k-1, nrhs, -one, ap( kc+2 ), 1, b( k, 1 ),
     $                     ldb, b( k+2, 1 ), ldb )
               CALL cgeru( n-k-1, nrhs, -one, ap( kc+n-k+2 ), 1,
     $                     b( k+1, 1 ), ldb, b( k+2, 1 ), ldb )
            END IF
*
*           Multiply by the inverse of the diagonal block.
*
            akm1k = ap( kc+1 )
            akm1 = ap( kc ) / conjg( akm1k )
            ak = ap( kc+n-k+1 ) / akm1k
            denom = akm1*ak - one
            DO 70 j = 1, nrhs
               bkm1 = b( k, j ) / conjg( akm1k )
               bk = b( k+1, j ) / akm1k
               b( k, j ) = ( ak*bkm1-bk ) / denom
               b( k+1, j ) = ( akm1*bk-bkm1 ) / denom
   70       continue
            kc = kc + 2*( n-k ) + 1
            k = k + 2
         END IF
*
         go to 60
   80    continue
*
*        Next solve L**H *X = B, overwriting B with X.
*
*        K is the main loop index, decreasing from N to 1 in steps of
*        1 or 2, depending on the size of the diagonal blocks.
*
         k = n
         kc = n*( n+1 ) / 2 + 1
   90    continue
*
*        If K < 1, exit from loop.
*
         IF( k.LT.1 )
     $      go to 100
*
         kc = kc - ( n-k+1 )
         IF( ipiv( k ).GT.0 ) THEN
*
*           1 x 1 diagonal block
*
*           Multiply by inv(L**H(K)), where L(K) is the transformation
*           stored in column K of A.
*
            IF( k.LT.n ) THEN
               CALL clacgv( nrhs, b( k, 1 ), ldb )
               CALL cgemv( 'Conjugate transpose', n-k, nrhs, -one,
     $                     b( k+1, 1 ), ldb, ap( kc+1 ), 1, one,
     $                     b( k, 1 ), ldb )
               CALL clacgv( nrhs, b( k, 1 ), ldb )
            END IF
*
*           Interchange rows K and IPIV(K).
*
            kp = ipiv( k )
            IF( kp.NE.k )
     $         CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
            k = k - 1
         ELSE
*
*           2 x 2 diagonal block
*
*           Multiply by inv(L**H(K-1)), where L(K-1) is the transformation
*           stored in columns K-1 and K of A.
*
            IF( k.LT.n ) THEN
               CALL clacgv( nrhs, b( k, 1 ), ldb )
               CALL cgemv( 'Conjugate transpose', n-k, nrhs, -one,
     $                     b( k+1, 1 ), ldb, ap( kc+1 ), 1, one,
     $                     b( k, 1 ), ldb )
               CALL clacgv( nrhs, b( k, 1 ), ldb )
*
               CALL clacgv( nrhs, b( k-1, 1 ), ldb )
               CALL cgemv( 'Conjugate transpose', n-k, nrhs, -one,
     $                     b( k+1, 1 ), ldb, ap( kc-( n-k ) ), 1, one,
     $                     b( k-1, 1 ), ldb )
               CALL clacgv( nrhs, b( k-1, 1 ), ldb )
            END IF
*
*           Interchange rows K and -IPIV(K).
*
            kp = -ipiv( k )
            IF( kp.NE.k )
     $         CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
            kc = kc - ( n-k+2 )
            k = k - 2
         END IF
*
         go to 90
  100    continue
      END IF
*
      return
*
*     End of CHPTRS
*
      END