ztzt01.f

Go to the documentation of this file.

*> \brief \b ZTZT01
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       DOUBLE PRECISION FUNCTION ZTZT01( M, N, A, AF, LDA, TAU, WORK,
*                        LWORK )
* 
*       .. Scalar Arguments ..
*       INTEGER            LDA, LWORK, M, N
*       ..
*       .. Array Arguments ..
*       COMPLEX*16         A( LDA, * ), AF( LDA, * ), TAU( * ),
*      $                   WORK( LWORK )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZTZT01 returns
*>      || A - R*Q || / ( M * eps * ||A|| )
*> for an upper trapezoidal A that was factored with ZTZRQF.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrices A and AF.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrices A and AF.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (LDA,N)
*>          The original upper trapezoidal M by N matrix A.
*> \endverbatim
*>
*> \param[in] AF
*> \verbatim
*>          AF is COMPLEX*16 array, dimension (LDA,N)
*>          The output of ZTZRQF for input matrix A.
*>          The lower triangle is not referenced.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the arrays A and AF.
*> \endverbatim
*>
*> \param[in] TAU
*> \verbatim
*>          TAU is COMPLEX*16 array, dimension (M)
*>          Details of the  Householder transformations as returned by
*>          ZTZRQF.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX*16 array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The length of the array WORK.  LWORK >= m*n + m.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup complex16_lin
*
*  =====================================================================
      DOUBLE PRECISION FUNCTION ztzt01( M, N, A, AF, LDA, TAU, WORK,
     $                 lwork )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            lda, lwork, m, n
*     ..
*     .. Array Arguments ..
      COMPLEX*16         a( lda, * ), af( lda, * ), tau( * ),
     $                   work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter( zero = 0.0d0, one = 1.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, j
      DOUBLE PRECISION   norma
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   rwork( 1 )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch, zlange
      EXTERNAL           dlamch, zlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zaxpy, zlaset, zlatzm
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dcmplx, max
*     ..
*     .. Executable Statements ..
*
      ztzt01 = zero
*
      IF( lwork.LT.m*n+m ) THEN
         CALL xerbla( 'ZTZT01', 8 )
         return
      END IF
*
*     Quick return if possible
*
      IF( m.LE.0 .OR. n.LE.0 )
     $   return
*
      norma = zlange( 'One-norm', m, n, a, lda, rwork )
*
*     Copy upper triangle R
*
      CALL zlaset( 'Full', m, n, dcmplx( zero ), dcmplx( zero ), work,
     $             m )
      DO 20 j = 1, m
         DO 10 i = 1, j
            work( ( j-1 )*m+i ) = af( i, j )
   10    continue
   20 continue
*
*     R = R * P(1) * ... *P(m)
*
      DO 30 i = 1, m
         CALL zlatzm( 'Right', i, n-m+1, af( i, m+1 ), lda, tau( i ),
     $                work( ( i-1 )*m+1 ), work( m*m+1 ), m,
     $                work( m*n+1 ) )
   30 continue
*
*     R = R - A
*
      DO 40 i = 1, n
         CALL zaxpy( m, dcmplx( -one ), a( 1, i ), 1,
     $               work( ( i-1 )*m+1 ), 1 )
   40 continue
*
      ztzt01 = zlange( 'One-norm', m, n, work, m, rwork )
*
      ztzt01 = ztzt01 / ( dlamch( 'Epsilon' )*dble( max( m, n ) ) )
      IF( norma.NE.zero )
     $   ztzt01 = ztzt01 / norma
*
      return
*
*     End of ZTZT01
*
      END