zchkq3.f

Go to the documentation of this file.

*> \brief \b ZCHKQ3
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZCHKQ3( DOTYPE, NM, MVAL, NN, NVAL, NNB, NBVAL, NXVAL,
*                          THRESH, A, COPYA, S, TAU, WORK, RWORK,
*                          IWORK, NOUT )
* 
*       .. Scalar Arguments ..
*       INTEGER            NM, NN, NNB, NOUT
*       DOUBLE PRECISION   THRESH
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * )
*       INTEGER            IWORK( * ), MVAL( * ), NBVAL( * ), NVAL( * ),
*      $                   NXVAL( * )
*       DOUBLE PRECISION   S( * ), RWORK( * )
*       COMPLEX*16         A( * ), COPYA( * ), TAU( * ), WORK( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZCHKQ3 tests ZGEQP3.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          The matrix types to be used for testing.  Matrices of type j
*>          (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) =
*>          .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
*> \endverbatim
*>
*> \param[in] NM
*> \verbatim
*>          NM is INTEGER
*>          The number of values of M contained in the vector MVAL.
*> \endverbatim
*>
*> \param[in] MVAL
*> \verbatim
*>          MVAL is INTEGER array, dimension (NM)
*>          The values of the matrix row dimension M.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER
*>          The number of values of N contained in the vector NVAL.
*> \endverbatim
*>
*> \param[in] NVAL
*> \verbatim
*>          NVAL is INTEGER array, dimension (NN)
*>          The values of the matrix column dimension N.
*> \endverbatim
*>
*> \param[in] NNB
*> \verbatim
*>          NNB is INTEGER
*>          The number of values of NB and NX contained in the
*>          vectors NBVAL and NXVAL.  The blocking parameters are used
*>          in pairs (NB,NX).
*> \endverbatim
*>
*> \param[in] NBVAL
*> \verbatim
*>          NBVAL is INTEGER array, dimension (NNB)
*>          The values of the blocksize NB.
*> \endverbatim
*>
*> \param[in] NXVAL
*> \verbatim
*>          NXVAL is INTEGER array, dimension (NNB)
*>          The values of the crossover point NX.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is DOUBLE PRECISION
*>          The threshold value for the test ratios.  A result is
*>          included in the output file if RESULT >= THRESH.  To have
*>          every test ratio printed, use THRESH = 0.
*> \endverbatim
*>
*> \param[out] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (MMAX*NMAX)
*>          where MMAX is the maximum value of M in MVAL and NMAX is the
*>          maximum value of N in NVAL.
*> \endverbatim
*>
*> \param[out] COPYA
*> \verbatim
*>          COPYA is COMPLEX*16 array, dimension (MMAX*NMAX)
*> \endverbatim
*>
*> \param[out] S
*> \verbatim
*>          S is DOUBLE PRECISION array, dimension
*>                      (min(MMAX,NMAX))
*> \endverbatim
*>
*> \param[out] TAU
*> \verbatim
*>          TAU is COMPLEX*16 array, dimension (MMAX)
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX*16 array, dimension
*>                      (max(M*max(M,N) + 4*min(M,N) + max(M,N)))
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is DOUBLE PRECISION array, dimension (4*NMAX)
*> \endverbatim
*>
*> \param[out] IWORK
*> \verbatim
*>          IWORK is INTEGER array, dimension (2*NMAX)
*> \endverbatim
*>
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>          The unit number for output.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup complex16_lin
*
*  =====================================================================
      SUBROUTINE zchkq3( DOTYPE, NM, MVAL, NN, NVAL, NNB, NBVAL, NXVAL,
     $                   thresh, a, copya, s, tau, work, rwork,
     $                   iwork, nout )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            nm, nn, nnb, nout
      DOUBLE PRECISION   thresh
*     ..
*     .. Array Arguments ..
      LOGICAL            dotype( * )
      INTEGER            iwork( * ), mval( * ), nbval( * ), nval( * ),
     $                   nxval( * )
      DOUBLE PRECISION   s( * ), rwork( * )
      COMPLEX*16         a( * ), copya( * ), tau( * ), work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            ntypes
      parameter( ntypes = 6 )
      INTEGER            ntests
      parameter( ntests = 3 )
      DOUBLE PRECISION   one, zero
      COMPLEX*16         czero
      parameter( one = 1.0d+0, zero = 0.0d+0,
     $                   czero = ( 0.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      CHARACTER*3        path
      INTEGER            i, ihigh, ilow, im, imode, in, inb, info,
     $                   istep, k, lda, lw, lwork, m, mnmin, mode, n,
     $                   nb, nerrs, nfail, nrun, nx
      DOUBLE PRECISION   eps
*     ..
*     .. Local Arrays ..
      INTEGER            iseed( 4 ), iseedy( 4 )
      DOUBLE PRECISION   result( ntests )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch, zqpt01, zqrt11, zqrt12
      EXTERNAL           dlamch, zqpt01, zqrt11, zqrt12
*     ..
*     .. External Subroutines ..
      EXTERNAL           alahd, alasum, dlaord, icopy, xlaenv, zgeqp3,
     $                   zlacpy, zlaset, zlatms
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Scalars in Common ..
      LOGICAL            lerr, ok
      CHARACTER*32       srnamt
      INTEGER            infot, iounit
*     ..
*     .. Common blocks ..
      common             / infoc / infot, iounit, ok, lerr
      common             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      path( 1: 1 ) = 'Zomplex precision'
      path( 2: 3 ) = 'Q3'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 continue
      eps = dlamch( 'Epsilon' )
      infot = 0
*
      DO 90 im = 1, nm
*
*        Do for each value of M in MVAL.
*
         m = mval( im )
         lda = max( 1, m )
*
         DO 80 in = 1, nn
*
*           Do for each value of N in NVAL.
*
            n = nval( in )
            mnmin = min( m, n )
            lwork = max( 1, m*max( m, n )+4*mnmin+max( m, n ) )
*
            DO 70 imode = 1, ntypes
               IF( .NOT.dotype( imode ) )
     $            go to 70
*
*              Do for each type of matrix
*                 1:  zero matrix
*                 2:  one small singular value
*                 3:  geometric distribution of singular values
*                 4:  first n/2 columns fixed
*                 5:  last n/2 columns fixed
*                 6:  every second column fixed
*
               mode = imode
               IF( imode.GT.3 )
     $            mode = 1
*
*              Generate test matrix of size m by n using
*              singular value distribution indicated by `mode'.
*
               DO 20 i = 1, n
                  iwork( i ) = 0
   20          continue
               IF( imode.EQ.1 ) THEN
                  CALL zlaset( 'Full', m, n, czero, czero, copya, lda )
                  DO 30 i = 1, mnmin
                     s( i ) = zero
   30             continue
               ELSE
                  CALL zlatms( m, n, 'Uniform', iseed, 'Nonsymm', s,
     $                         mode, one / eps, one, m, n, 'No packing',
     $                         copya, lda, work, info )
                  IF( imode.GE.4 ) THEN
                     IF( imode.EQ.4 ) THEN
                        ilow = 1
                        istep = 1
                        ihigh = max( 1, n / 2 )
                     ELSE IF( imode.EQ.5 ) THEN
                        ilow = max( 1, n / 2 )
                        istep = 1
                        ihigh = n
                     ELSE IF( imode.EQ.6 ) THEN
                        ilow = 1
                        istep = 2
                        ihigh = n
                     END IF
                     DO 40 i = ilow, ihigh, istep
                        iwork( i ) = 1
   40                continue
                  END IF
                  CALL dlaord( 'Decreasing', mnmin, s, 1 )
               END IF
*
               DO 60 inb = 1, nnb
*
*                 Do for each pair of values (NB,NX) in NBVAL and NXVAL.
*
                  nb = nbval( inb )
                  CALL xlaenv( 1, nb )
                  nx = nxval( inb )
                  CALL xlaenv( 3, nx )
*
*                 Save A and its singular values and a copy of
*                 vector IWORK.
*
                  CALL zlacpy( 'All', m, n, copya, lda, a, lda )
                  CALL icopy( n, iwork( 1 ), 1, iwork( n+1 ), 1 )
*
*                 Workspace needed.
*
                  lw = nb*( n+1 )
*
                  srnamt = 'ZGEQP3'
                  CALL zgeqp3( m, n, a, lda, iwork( n+1 ), tau, work,
     $                         lw, rwork, info )
*
*                 Compute norm(svd(a) - svd(r))
*
                  result( 1 ) = zqrt12( m, n, a, lda, s, work,
     $                          lwork, rwork )
*
*                 Compute norm( A*P - Q*R )
*
                  result( 2 ) = zqpt01( m, n, mnmin, copya, a, lda, tau,
     $                          iwork( n+1 ), work, lwork )
*
*                 Compute Q'*Q
*
                  result( 3 ) = zqrt11( m, mnmin, a, lda, tau, work,
     $                          lwork )
*
*                 Print information about the tests that did not pass
*                 the threshold.
*
                  DO 50 k = 1, ntests
                     IF( result( k ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9999 )'ZGEQP3', m, n, nb,
     $                     imode, k, result( k )
                        nfail = nfail + 1
                     END IF
   50             continue
                  nrun = nrun + ntests
*
   60          continue
   70       continue
   80    continue
   90 continue
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 format( 1x, a, ' M =', i5, ', N =', i5, ', NB =', i4, ', type ',
     $      i2, ', test ', i2, ', ratio =', g12.5 )
*
*     End of ZCHKQ3
*
      END