ztrt05.f

Go to the documentation of this file.

*> \brief \b ZTRT05
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZTRT05( UPLO, TRANS, DIAG, N, NRHS, A, LDA, B, LDB, X,
*                          LDX, XACT, LDXACT, FERR, BERR, RESLTS )
* 
*       .. Scalar Arguments ..
*       CHARACTER          DIAG, TRANS, UPLO
*       INTEGER            LDA, LDB, LDX, LDXACT, N, NRHS
*       ..
*       .. Array Arguments ..
*       DOUBLE PRECISION   BERR( * ), FERR( * ), RESLTS( * )
*       COMPLEX*16         A( LDA, * ), B( LDB, * ), X( LDX, * ),
*      $                   XACT( LDXACT, * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZTRT05 tests the error bounds from iterative refinement for the
*> computed solution to a system of equations A*X = B, where A is a
*> triangular n by n matrix.
*>
*> RESLTS(1) = test of the error bound
*>           = norm(X - XACT) / ( norm(X) * FERR )
*>
*> A large value is returned if this ratio is not less than one.
*>
*> RESLTS(2) = residual from the iterative refinement routine
*>           = the maximum of BERR / ( (n+1)*EPS + (*) ), where
*>             (*) = (n+1)*UNFL / (min_i (abs(A)*abs(X) +abs(b))_i )
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the matrix A is upper or lower triangular.
*>          = 'U':  Upper triangular
*>          = 'L':  Lower triangular
*> \endverbatim
*>
*> \param[in] TRANS
*> \verbatim
*>          TRANS is CHARACTER*1
*>          Specifies the form of the system of equations.
*>          = 'N':  A * X = B  (No transpose)
*>          = 'T':  A'* X = B  (Transpose)
*>          = 'C':  A'* X = B  (Conjugate transpose = Transpose)
*> \endverbatim
*>
*> \param[in] DIAG
*> \verbatim
*>          DIAG is CHARACTER*1
*>          Specifies whether or not the matrix A is unit triangular.
*>          = 'N':  Non-unit triangular
*>          = 'U':  Unit triangular
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of rows of the matrices X, B, and XACT, and the
*>          order of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>          The number of columns of the matrices X, B, and XACT.
*>          NRHS >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (LDA,N)
*>          The triangular matrix A.  If UPLO = 'U', the leading n by n
*>          upper triangular part of the array A contains the upper
*>          triangular matrix, and the strictly lower triangular part of
*>          A is not referenced.  If UPLO = 'L', the leading n by n lower
*>          triangular part of the array A contains the lower triangular
*>          matrix, and the strictly upper triangular part of A is not
*>          referenced.  If DIAG = 'U', the diagonal elements of A are
*>          also not referenced and are assumed to be 1.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,N).
*> \endverbatim
*>
*> \param[in] B
*> \verbatim
*>          B is COMPLEX*16 array, dimension (LDB,NRHS)
*>          The right hand side vectors for the system of linear
*>          equations.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B.  LDB >= max(1,N).
*> \endverbatim
*>
*> \param[in] X
*> \verbatim
*>          X is COMPLEX*16 array, dimension (LDX,NRHS)
*>          The computed solution vectors.  Each vector is stored as a
*>          column of the matrix X.
*> \endverbatim
*>
*> \param[in] LDX
*> \verbatim
*>          LDX is INTEGER
*>          The leading dimension of the array X.  LDX >= max(1,N).
*> \endverbatim
*>
*> \param[in] XACT
*> \verbatim
*>          XACT is COMPLEX*16 array, dimension (LDX,NRHS)
*>          The exact solution vectors.  Each vector is stored as a
*>          column of the matrix XACT.
*> \endverbatim
*>
*> \param[in] LDXACT
*> \verbatim
*>          LDXACT is INTEGER
*>          The leading dimension of the array XACT.  LDXACT >= max(1,N).
*> \endverbatim
*>
*> \param[in] FERR
*> \verbatim
*>          FERR is DOUBLE PRECISION array, dimension (NRHS)
*>          The estimated forward error bounds for each solution vector
*>          X.  If XTRUE is the true solution, FERR bounds the magnitude
*>          of the largest entry in (X - XTRUE) divided by the magnitude
*>          of the largest entry in X.
*> \endverbatim
*>
*> \param[in] BERR
*> \verbatim
*>          BERR is DOUBLE PRECISION array, dimension (NRHS)
*>          The componentwise relative backward error of each solution
*>          vector (i.e., the smallest relative change in any entry of A
*>          or B that makes X an exact solution).
*> \endverbatim
*>
*> \param[out] RESLTS
*> \verbatim
*>          RESLTS is DOUBLE PRECISION array, dimension (2)
*>          The maximum over the NRHS solution vectors of the ratios:
*>          RESLTS(1) = norm(X - XACT) / ( norm(X) * FERR )
*>          RESLTS(2) = BERR / ( (n+1)*EPS + (*) )
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup complex16_lin
*
*  =====================================================================
      SUBROUTINE ztrt05( UPLO, TRANS, DIAG, N, NRHS, A, LDA, B, LDB, X,
     $                   ldx, xact, ldxact, ferr, berr, reslts )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          diag, trans, uplo
      INTEGER            lda, ldb, ldx, ldxact, n, nrhs
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   berr( * ), ferr( * ), reslts( * )
      COMPLEX*16         a( lda, * ), b( ldb, * ), x( ldx, * ),
     $                   xact( ldxact, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            notran, unit, upper
      INTEGER            i, ifu, imax, j, k
      DOUBLE PRECISION   axbi, diff, eps, errbnd, ovfl, tmp, unfl, xnorm
      COMPLEX*16         zdum
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      INTEGER            izamax
      DOUBLE PRECISION   dlamch
      EXTERNAL           lsame, izamax, dlamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dimag, max, min
*     ..
*     .. Statement Functions ..
      DOUBLE PRECISION   cabs1
*     ..
*     .. Statement Function definitions ..
      cabs1( zdum ) = abs( dble( zdum ) ) + abs( dimag( zdum ) )
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0 or NRHS = 0.
*
      IF( n.LE.0 .OR. nrhs.LE.0 ) THEN
         reslts( 1 ) = zero
         reslts( 2 ) = zero
         return
      END IF
*
      eps = dlamch( 'Epsilon' )
      unfl = dlamch( 'Safe minimum' )
      ovfl = one / unfl
      upper = lsame( uplo, 'U' )
      notran = lsame( trans, 'N' )
      unit = lsame( diag, 'U' )
*
*     Test 1:  Compute the maximum of
*        norm(X - XACT) / ( norm(X) * FERR )
*     over all the vectors X and XACT using the infinity-norm.
*
      errbnd = zero
      DO 30 j = 1, nrhs
         imax = izamax( n, x( 1, j ), 1 )
         xnorm = max( cabs1( x( imax, j ) ), unfl )
         diff = zero
         DO 10 i = 1, n
            diff = max( diff, cabs1( x( i, j )-xact( i, j ) ) )
   10    continue
*
         IF( xnorm.GT.one ) THEN
            go to 20
         ELSE IF( diff.LE.ovfl*xnorm ) THEN
            go to 20
         ELSE
            errbnd = one / eps
            go to 30
         END IF
*
   20    continue
         IF( diff / xnorm.LE.ferr( j ) ) THEN
            errbnd = max( errbnd, ( diff / xnorm ) / ferr( j ) )
         ELSE
            errbnd = one / eps
         END IF
   30 continue
      reslts( 1 ) = errbnd
*
*     Test 2:  Compute the maximum of BERR / ( (n+1)*EPS + (*) ), where
*     (*) = (n+1)*UNFL / (min_i (abs(A)*abs(X) +abs(b))_i )
*
      ifu = 0
      IF( unit )
     $   ifu = 1
      DO 90 k = 1, nrhs
         DO 80 i = 1, n
            tmp = cabs1( b( i, k ) )
            IF( upper ) THEN
               IF( .NOT.notran ) THEN
                  DO 40 j = 1, i - ifu
                     tmp = tmp + cabs1( a( j, i ) )*cabs1( x( j, k ) )
   40             continue
                  IF( unit )
     $               tmp = tmp + cabs1( x( i, k ) )
               ELSE
                  IF( unit )
     $               tmp = tmp + cabs1( x( i, k ) )
                  DO 50 j = i + ifu, n
                     tmp = tmp + cabs1( a( i, j ) )*cabs1( x( j, k ) )
   50             continue
               END IF
            ELSE
               IF( notran ) THEN
                  DO 60 j = 1, i - ifu
                     tmp = tmp + cabs1( a( i, j ) )*cabs1( x( j, k ) )
   60             continue
                  IF( unit )
     $               tmp = tmp + cabs1( x( i, k ) )
               ELSE
                  IF( unit )
     $               tmp = tmp + cabs1( x( i, k ) )
                  DO 70 j = i + ifu, n
                     tmp = tmp + cabs1( a( j, i ) )*cabs1( x( j, k ) )
   70             continue
               END IF
            END IF
            IF( i.EQ.1 ) THEN
               axbi = tmp
            ELSE
               axbi = min( axbi, tmp )
            END IF
   80    continue
         tmp = berr( k ) / ( ( n+1 )*eps+( n+1 )*unfl /
     $         max( axbi, ( n+1 )*unfl ) )
         IF( k.EQ.1 ) THEN
            reslts( 2 ) = tmp
         ELSE
            reslts( 2 ) = max( reslts( 2 ), tmp )
         END IF
   90 continue
*
      return
*
*     End of ZTRT05
*
      END