chegs2.f

Go to the documentation of this file.

*> \brief \b CHEGS2 reduces a Hermitian definite generalized eigenproblem to standard form, using the factorization results obtained from cpotrf (unblocked algorithm).
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*> \htmlonly
*> Download CHEGS2 + dependencies 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/chegs2.f"> 
*> [TGZ]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/chegs2.f"> 
*> [ZIP]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/chegs2.f"> 
*> [TXT]</a>
*> \endhtmlonly 
*
*  Definition:
*  ===========
*
*       SUBROUTINE CHEGS2( ITYPE, UPLO, N, A, LDA, B, LDB, INFO )
* 
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            INFO, ITYPE, LDA, LDB, N
*       ..
*       .. Array Arguments ..
*       COMPLEX            A( LDA, * ), B( LDB, * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CHEGS2 reduces a complex Hermitian-definite generalized
*> eigenproblem to standard form.
*>
*> If ITYPE = 1, the problem is A*x = lambda*B*x,
*> and A is overwritten by inv(U**H)*A*inv(U) or inv(L)*A*inv(L**H)
*>
*> If ITYPE = 2 or 3, the problem is A*B*x = lambda*x or
*> B*A*x = lambda*x, and A is overwritten by U*A*U**H or L**H *A*L.
*>
*> B must have been previously factorized as U**H *U or L*L**H by ZPOTRF.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] ITYPE
*> \verbatim
*>          ITYPE is INTEGER
*>          = 1: compute inv(U**H)*A*inv(U) or inv(L)*A*inv(L**H);
*>          = 2 or 3: compute U*A*U**H or L**H *A*L.
*> \endverbatim
*>
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the upper or lower triangular part of the
*>          Hermitian matrix A is stored, and how B has been factorized.
*>          = 'U':  Upper triangular
*>          = 'L':  Lower triangular
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrices A and B.  N >= 0.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is COMPLEX array, dimension (LDA,N)
*>          On entry, the Hermitian matrix A.  If UPLO = 'U', the leading
*>          n by n upper triangular part of A contains the upper
*>          triangular part of the matrix A, and the strictly lower
*>          triangular part of A is not referenced.  If UPLO = 'L', the
*>          leading n by n lower triangular part of A contains the lower
*>          triangular part of the matrix A, and the strictly upper
*>          triangular part of A is not referenced.
*>
*>          On exit, if INFO = 0, the transformed matrix, stored in the
*>          same format as A.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,N).
*> \endverbatim
*>
*> \param[in,out] B
*> \verbatim
*>          B is COMPLEX array, dimension (LDB,N)
*>          The triangular factor from the Cholesky factorization of B,
*>          as returned by CPOTRF.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B.  LDB >= max(1,N).
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit.
*>          < 0:  if INFO = -i, the i-th argument had an illegal value.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date September 2012
*
*> \ingroup complexHEcomputational
*
*  =====================================================================
      SUBROUTINE chegs2( ITYPE, UPLO, N, A, LDA, B, LDB, INFO )
*
*  -- LAPACK computational routine (version 3.4.2) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     September 2012
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            info, itype, lda, ldb, n
*     ..
*     .. Array Arguments ..
      COMPLEX            a( lda, * ), b( ldb, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               one, half
      parameter( one = 1.0e+0, half = 0.5e+0 )
      COMPLEX            cone
      parameter( cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            upper
      INTEGER            k
      REAL               akk, bkk
      COMPLEX            ct
*     ..
*     .. External Subroutines ..
      EXTERNAL           caxpy, cher2, clacgv, csscal, ctrmv, ctrsv,
     $                   xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      EXTERNAL           lsame
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( itype.LT.1 .OR. itype.GT.3 ) THEN
         info = -1
      ELSE IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -7
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CHEGS2', -info )
         return
      END IF
*
      IF( itype.EQ.1 ) THEN
         IF( upper ) THEN
*
*           Compute inv(U**H)*A*inv(U)
*
            DO 10 k = 1, n
*
*              Update the upper triangle of A(k:n,k:n)
*
               akk = a( k, k )
               bkk = b( k, k )
               akk = akk / bkk**2
               a( k, k ) = akk
               IF( k.LT.n ) THEN
                  CALL csscal( n-k, one / bkk, a( k, k+1 ), lda )
                  ct = -half*akk
                  CALL clacgv( n-k, a( k, k+1 ), lda )
                  CALL clacgv( n-k, b( k, k+1 ), ldb )
                  CALL caxpy( n-k, ct, b( k, k+1 ), ldb, a( k, k+1 ),
     $                        lda )
                  CALL cher2( uplo, n-k, -cone, a( k, k+1 ), lda,
     $                        b( k, k+1 ), ldb, a( k+1, k+1 ), lda )
                  CALL caxpy( n-k, ct, b( k, k+1 ), ldb, a( k, k+1 ),
     $                        lda )
                  CALL clacgv( n-k, b( k, k+1 ), ldb )
                  CALL ctrsv( uplo, 'Conjugate transpose', 'Non-unit',
     $                        n-k, b( k+1, k+1 ), ldb, a( k, k+1 ),
     $                        lda )
                  CALL clacgv( n-k, a( k, k+1 ), lda )
               END IF
   10       continue
         ELSE
*
*           Compute inv(L)*A*inv(L**H)
*
            DO 20 k = 1, n
*
*              Update the lower triangle of A(k:n,k:n)
*
               akk = a( k, k )
               bkk = b( k, k )
               akk = akk / bkk**2
               a( k, k ) = akk
               IF( k.LT.n ) THEN
                  CALL csscal( n-k, one / bkk, a( k+1, k ), 1 )
                  ct = -half*akk
                  CALL caxpy( n-k, ct, b( k+1, k ), 1, a( k+1, k ), 1 )
                  CALL cher2( uplo, n-k, -cone, a( k+1, k ), 1,
     $                        b( k+1, k ), 1, a( k+1, k+1 ), lda )
                  CALL caxpy( n-k, ct, b( k+1, k ), 1, a( k+1, k ), 1 )
                  CALL ctrsv( uplo, 'No transpose', 'Non-unit', n-k,
     $                        b( k+1, k+1 ), ldb, a( k+1, k ), 1 )
               END IF
   20       continue
         END IF
      ELSE
         IF( upper ) THEN
*
*           Compute U*A*U**H
*
            DO 30 k = 1, n
*
*              Update the upper triangle of A(1:k,1:k)
*
               akk = a( k, k )
               bkk = b( k, k )
               CALL ctrmv( uplo, 'No transpose', 'Non-unit', k-1, b,
     $                     ldb, a( 1, k ), 1 )
               ct = half*akk
               CALL caxpy( k-1, ct, b( 1, k ), 1, a( 1, k ), 1 )
               CALL cher2( uplo, k-1, cone, a( 1, k ), 1, b( 1, k ), 1,
     $                     a, lda )
               CALL caxpy( k-1, ct, b( 1, k ), 1, a( 1, k ), 1 )
               CALL csscal( k-1, bkk, a( 1, k ), 1 )
               a( k, k ) = akk*bkk**2
   30       continue
         ELSE
*
*           Compute L**H *A*L
*
            DO 40 k = 1, n
*
*              Update the lower triangle of A(1:k,1:k)
*
               akk = a( k, k )
               bkk = b( k, k )
               CALL clacgv( k-1, a( k, 1 ), lda )
               CALL ctrmv( uplo, 'Conjugate transpose', 'Non-unit', k-1,
     $                     b, ldb, a( k, 1 ), lda )
               ct = half*akk
               CALL clacgv( k-1, b( k, 1 ), ldb )
               CALL caxpy( k-1, ct, b( k, 1 ), ldb, a( k, 1 ), lda )
               CALL cher2( uplo, k-1, cone, a( k, 1 ), lda, b( k, 1 ),
     $                     ldb, a, lda )
               CALL caxpy( k-1, ct, b( k, 1 ), ldb, a( k, 1 ), lda )
               CALL clacgv( k-1, b( k, 1 ), ldb )
               CALL csscal( k-1, bkk, a( k, 1 ), lda )
               CALL clacgv( k-1, a( k, 1 ), lda )
               a( k, k ) = akk*bkk**2
   40       continue
         END IF
      END IF
      return
*
*     End of CHEGS2
*
      END