001:       REAL             FUNCTION CLANHB( NORM, UPLO, N, K, AB, LDAB,
002:      $                 WORK )
003: *
004: *  -- LAPACK auxiliary routine (version 3.2) --
005: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
006: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
007: *     November 2006
008: *
009: *     .. Scalar Arguments ..
010:       CHARACTER          NORM, UPLO
011:       INTEGER            K, LDAB, N
012: *     ..
013: *     .. Array Arguments ..
014:       REAL               WORK( * )
015:       COMPLEX            AB( LDAB, * )
016: *     ..
017: *
018: *  Purpose
019: *  =======
020: *
021: *  CLANHB  returns the value of the one norm,  or the Frobenius norm, or
022: *  the  infinity norm,  or the element of  largest absolute value  of an
023: *  n by n hermitian band matrix A,  with k super-diagonals.
024: *
025: *  Description
026: *  ===========
027: *
028: *  CLANHB returns the value
029: *
030: *     CLANHB = ( max(abs(A(i,j))), NORM = 'M' or 'm'
031: *              (
032: *              ( norm1(A),         NORM = '1', 'O' or 'o'
033: *              (
034: *              ( normI(A),         NORM = 'I' or 'i'
035: *              (
036: *              ( normF(A),         NORM = 'F', 'f', 'E' or 'e'
037: *
038: *  where  norm1  denotes the  one norm of a matrix (maximum column sum),
039: *  normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
040: *  normF  denotes the  Frobenius norm of a matrix (square root of sum of
041: *  squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
042: *
043: *  Arguments
044: *  =========
045: *
046: *  NORM    (input) CHARACTER*1
047: *          Specifies the value to be returned in CLANHB as described
048: *          above.
049: *
050: *  UPLO    (input) CHARACTER*1
051: *          Specifies whether the upper or lower triangular part of the
052: *          band matrix A is supplied.
053: *          = 'U':  Upper triangular
054: *          = 'L':  Lower triangular
055: *
056: *  N       (input) INTEGER
057: *          The order of the matrix A.  N >= 0.  When N = 0, CLANHB is
058: *          set to zero.
059: *
060: *  K       (input) INTEGER
061: *          The number of super-diagonals or sub-diagonals of the
062: *          band matrix A.  K >= 0.
063: *
064: *  AB      (input) COMPLEX array, dimension (LDAB,N)
065: *          The upper or lower triangle of the hermitian band matrix A,
066: *          stored in the first K+1 rows of AB.  The j-th column of A is
067: *          stored in the j-th column of the array AB as follows:
068: *          if UPLO = 'U', AB(k+1+i-j,j) = A(i,j) for max(1,j-k)<=i<=j;
069: *          if UPLO = 'L', AB(1+i-j,j)   = A(i,j) for j<=i<=min(n,j+k).
070: *          Note that the imaginary parts of the diagonal elements need
071: *          not be set and are assumed to be zero.
072: *
073: *  LDAB    (input) INTEGER
074: *          The leading dimension of the array AB.  LDAB >= K+1.
075: *
076: *  WORK    (workspace) REAL array, dimension (MAX(1,LWORK)),
077: *          where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
078: *          WORK is not referenced.
079: *
080: * =====================================================================
081: *
082: *     .. Parameters ..
083:       REAL               ONE, ZERO
084:       PARAMETER          ( ONE = 1.0E+0, ZERO = 0.0E+0 )
085: *     ..
086: *     .. Local Scalars ..
087:       INTEGER            I, J, L
088:       REAL               ABSA, SCALE, SUM, VALUE
089: *     ..
090: *     .. External Functions ..
091:       LOGICAL            LSAME
092:       EXTERNAL           LSAME
093: *     ..
094: *     .. External Subroutines ..
095:       EXTERNAL           CLASSQ
096: *     ..
097: *     .. Intrinsic Functions ..
098:       INTRINSIC          ABS, MAX, MIN, REAL, SQRT
099: *     ..
100: *     .. Executable Statements ..
101: *
102:       IF( N.EQ.0 ) THEN
103:          VALUE = ZERO
104:       ELSE IF( LSAME( NORM, 'M' ) ) THEN
105: *
106: *        Find max(abs(A(i,j))).
107: *
108:          VALUE = ZERO
109:          IF( LSAME( UPLO, 'U' ) ) THEN
110:             DO 20 J = 1, N
111:                DO 10 I = MAX( K+2-J, 1 ), K
112:                   VALUE = MAX( VALUE, ABS( AB( I, J ) ) )
113:    10          CONTINUE
114:                VALUE = MAX( VALUE, ABS( REAL( AB( K+1, J ) ) ) )
115:    20       CONTINUE
116:          ELSE
117:             DO 40 J = 1, N
118:                VALUE = MAX( VALUE, ABS( REAL( AB( 1, J ) ) ) )
119:                DO 30 I = 2, MIN( N+1-J, K+1 )
120:                   VALUE = MAX( VALUE, ABS( AB( I, J ) ) )
121:    30          CONTINUE
122:    40       CONTINUE
123:          END IF
124:       ELSE IF( ( LSAME( NORM, 'I' ) ) .OR. ( LSAME( NORM, 'O' ) ) .OR.
125:      $         ( NORM.EQ.'1' ) ) THEN
126: *
127: *        Find normI(A) ( = norm1(A), since A is hermitian).
128: *
129:          VALUE = ZERO
130:          IF( LSAME( UPLO, 'U' ) ) THEN
131:             DO 60 J = 1, N
132:                SUM = ZERO
133:                L = K + 1 - J
134:                DO 50 I = MAX( 1, J-K ), J - 1
135:                   ABSA = ABS( AB( L+I, J ) )
136:                   SUM = SUM + ABSA
137:                   WORK( I ) = WORK( I ) + ABSA
138:    50          CONTINUE
139:                WORK( J ) = SUM + ABS( REAL( AB( K+1, J ) ) )
140:    60       CONTINUE
141:             DO 70 I = 1, N
142:                VALUE = MAX( VALUE, WORK( I ) )
143:    70       CONTINUE
144:          ELSE
145:             DO 80 I = 1, N
146:                WORK( I ) = ZERO
147:    80       CONTINUE
148:             DO 100 J = 1, N
149:                SUM = WORK( J ) + ABS( REAL( AB( 1, J ) ) )
150:                L = 1 - J
151:                DO 90 I = J + 1, MIN( N, J+K )
152:                   ABSA = ABS( AB( L+I, J ) )
153:                   SUM = SUM + ABSA
154:                   WORK( I ) = WORK( I ) + ABSA
155:    90          CONTINUE
156:                VALUE = MAX( VALUE, SUM )
157:   100       CONTINUE
158:          END IF
159:       ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
160: *
161: *        Find normF(A).
162: *
163:          SCALE = ZERO
164:          SUM = ONE
165:          IF( K.GT.0 ) THEN
166:             IF( LSAME( UPLO, 'U' ) ) THEN
167:                DO 110 J = 2, N
168:                   CALL CLASSQ( MIN( J-1, K ), AB( MAX( K+2-J, 1 ), J ),
169:      $                         1, SCALE, SUM )
170:   110          CONTINUE
171:                L = K + 1
172:             ELSE
173:                DO 120 J = 1, N - 1
174:                   CALL CLASSQ( MIN( N-J, K ), AB( 2, J ), 1, SCALE,
175:      $                         SUM )
176:   120          CONTINUE
177:                L = 1
178:             END IF
179:             SUM = 2*SUM
180:          ELSE
181:             L = 1
182:          END IF
183:          DO 130 J = 1, N
184:             IF( REAL( AB( L, J ) ).NE.ZERO ) THEN
185:                ABSA = ABS( REAL( AB( L, J ) ) )
186:                IF( SCALE.LT.ABSA ) THEN
187:                   SUM = ONE + SUM*( SCALE / ABSA )**2
188:                   SCALE = ABSA
189:                ELSE
190:                   SUM = SUM + ( ABSA / SCALE )**2
191:                END IF
192:             END IF
193:   130    CONTINUE
194:          VALUE = SCALE*SQRT( SUM )
195:       END IF
196: *
197:       CLANHB = VALUE
198:       RETURN
199: *
200: *     End of CLANHB
201: *
202:       END
203: