001:       REAL FUNCTION CLA_HERCOND_C( UPLO, N, A, LDA, AF, LDAF, IPIV, C,
002:      $                             CAPPLY, INFO, WORK, RWORK )
003: *
004: *     -- LAPACK routine (version 3.2.1)                                 --
005: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
006: *     -- Jason Riedy of Univ. of California Berkeley.                 --
007: *     -- April 2009                                                   --
008: *
009: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
010: *     -- Univ. of California Berkeley and NAG Ltd.                    --
011: *
012:       IMPLICIT NONE
013: *     ..
014: *     .. Scalar Arguments ..
015:       CHARACTER          UPLO
016:       LOGICAL            CAPPLY
017:       INTEGER            N, LDA, LDAF, INFO
018: *     ..
019: *     .. Array Arguments ..
020:       INTEGER            IPIV( * )
021:       COMPLEX            A( LDA, * ), AF( LDAF, * ), WORK( * )
022:       REAL               C ( * ), RWORK( * )
023: *     ..
024: *
025: *  Purpose
026: *  =======
027: *
028: *     CLA_HERCOND_C computes the infinity norm condition number of
029: *     op(A) * inv(diag(C)) where C is a REAL vector.
030: *
031: *  Arguments
032: *  =========
033: *
034: *     UPLO    (input) CHARACTER*1
035: *       = 'U':  Upper triangle of A is stored;
036: *       = 'L':  Lower triangle of A is stored.
037: *
038: *     N       (input) INTEGER
039: *     The number of linear equations, i.e., the order of the
040: *     matrix A.  N >= 0.
041: *
042: *     A       (input) COMPLEX array, dimension (LDA,N)
043: *     On entry, the N-by-N matrix A
044: *
045: *     LDA     (input) INTEGER
046: *     The leading dimension of the array A.  LDA >= max(1,N).
047: *
048: *     AF      (input) COMPLEX array, dimension (LDAF,N)
049: *     The block diagonal matrix D and the multipliers used to
050: *     obtain the factor U or L as computed by CHETRF.
051: *
052: *     LDAF    (input) INTEGER
053: *     The leading dimension of the array AF.  LDAF >= max(1,N).
054: *
055: *     IPIV    (input) INTEGER array, dimension (N)
056: *     Details of the interchanges and the block structure of D
057: *     as determined by CHETRF.
058: *
059: *     C       (input) REAL array, dimension (N)
060: *     The vector C in the formula op(A) * inv(diag(C)).
061: *
062: *     CAPPLY  (input) LOGICAL
063: *     If .TRUE. then access the vector C in the formula above.
064: *
065: *     INFO    (output) INTEGER
066: *       = 0:  Successful exit.
067: *     i > 0:  The ith argument is invalid.
068: *
069: *     WORK    (input) COMPLEX array, dimension (2*N).
070: *     Workspace.
071: *
072: *     RWORK   (input) REAL array, dimension (N).
073: *     Workspace.
074: *
075: *  =====================================================================
076: *
077: *     .. Local Scalars ..
078:       INTEGER            KASE, I, J
079:       REAL               AINVNM, ANORM, TMP
080:       LOGICAL            UP
081:       COMPLEX            ZDUM
082: *     ..
083: *     .. Local Arrays ..
084:       INTEGER            ISAVE( 3 )
085: *     ..
086: *     .. External Functions ..
087:       LOGICAL            LSAME
088:       EXTERNAL           LSAME
089: *     ..
090: *     .. External Subroutines ..
091:       EXTERNAL           CLACN2, CHETRS, XERBLA
092: *     ..
093: *     .. Intrinsic Functions ..
094:       INTRINSIC          ABS, MAX
095: *     ..
096: *     .. Statement Functions ..
097:       REAL               CABS1
098: *     ..
099: *     .. Statement Function Definitions ..
100:       CABS1( ZDUM ) = ABS( REAL( ZDUM ) ) + ABS( AIMAG( ZDUM ) )
101: *     ..
102: *     .. Executable Statements ..
103: *
104:       CLA_HERCOND_C = 0.0E+0
105: *
106:       INFO = 0
107:       IF( N.LT.0 ) THEN
108:          INFO = -2
109:       END IF
110:       IF( INFO.NE.0 ) THEN
111:          CALL XERBLA( 'CLA_HERCOND_C', -INFO )
112:          RETURN
113:       END IF
114:       UP = .FALSE.
115:       IF ( LSAME( UPLO, 'U' ) ) UP = .TRUE.
116: *
117: *     Compute norm of op(A)*op2(C).
118: *
119:       ANORM = 0.0E+0
120:       IF ( UP ) THEN
121:          DO I = 1, N
122:             TMP = 0.0E+0
123:             IF ( CAPPLY ) THEN
124:                DO J = 1, I
125:                   TMP = TMP + CABS1( A( J, I ) ) / C( J )
126:                END DO
127:                DO J = I+1, N
128:                   TMP = TMP + CABS1( A( I, J ) ) / C( J )
129:                END DO
130:             ELSE
131:                DO J = 1, I
132:                   TMP = TMP + CABS1( A( J, I ) )
133:                END DO
134:                DO J = I+1, N
135:                   TMP = TMP + CABS1( A( I, J ) )
136:                END DO
137:             END IF
138:             RWORK( I ) = TMP
139:             ANORM = MAX( ANORM, TMP )
140:          END DO
141:       ELSE
142:          DO I = 1, N
143:             TMP = 0.0E+0
144:             IF ( CAPPLY ) THEN
145:                DO J = 1, I
146:                   TMP = TMP + CABS1( A( I, J ) ) / C( J )
147:                END DO
148:                DO J = I+1, N
149:                   TMP = TMP + CABS1( A( J, I ) ) / C( J )
150:                END DO
151:             ELSE
152:                DO J = 1, I
153:                   TMP = TMP + CABS1( A( I, J ) )
154:                END DO
155:                DO J = I+1, N
156:                   TMP = TMP + CABS1( A( J, I ) )
157:                END DO
158:             END IF
159:             RWORK( I ) = TMP
160:             ANORM = MAX( ANORM, TMP )
161:          END DO
162:       END IF
163: *
164: *     Quick return if possible.
165: *
166:       IF( N.EQ.0 ) THEN
167:          CLA_HERCOND_C = 1.0E+0
168:          RETURN
169:       ELSE IF( ANORM .EQ. 0.0E+0 ) THEN
170:          RETURN
171:       END IF
172: *
173: *     Estimate the norm of inv(op(A)).
174: *
175:       AINVNM = 0.0E+0
176: *
177:       KASE = 0
178:    10 CONTINUE
179:       CALL CLACN2( N, WORK( N+1 ), WORK, AINVNM, KASE, ISAVE )
180:       IF( KASE.NE.0 ) THEN
181:          IF( KASE.EQ.2 ) THEN
182: *
183: *           Multiply by R.
184: *
185:             DO I = 1, N
186:                WORK( I ) = WORK( I ) * RWORK( I )
187:             END DO
188: *
189:             IF ( UP ) THEN
190:                CALL CHETRS( 'U', N, 1, AF, LDAF, IPIV,
191:      $            WORK, N, INFO )
192:             ELSE
193:                CALL CHETRS( 'L', N, 1, AF, LDAF, IPIV,
194:      $            WORK, N, INFO )
195:             ENDIF
196: *
197: *           Multiply by inv(C).
198: *
199:             IF ( CAPPLY ) THEN
200:                DO I = 1, N
201:                   WORK( I ) = WORK( I ) * C( I )
202:                END DO
203:             END IF
204:          ELSE
205: *
206: *           Multiply by inv(C').
207: *
208:             IF ( CAPPLY ) THEN
209:                DO I = 1, N
210:                   WORK( I ) = WORK( I ) * C( I )
211:                END DO
212:             END IF
213: *
214:             IF ( UP ) THEN
215:                CALL CHETRS( 'U', N, 1, AF, LDAF, IPIV,
216:      $            WORK, N, INFO )
217:             ELSE
218:                CALL CHETRS( 'L', N, 1, AF, LDAF, IPIV,
219:      $            WORK, N, INFO )
220:             END IF
221: *
222: *           Multiply by R.
223: *
224:             DO I = 1, N
225:                WORK( I ) = WORK( I ) * RWORK( I )
226:             END DO
227:          END IF
228:          GO TO 10
229:       END IF
230: *
231: *     Compute the estimate of the reciprocal condition number.
232: *
233:       IF( AINVNM .NE. 0.0E+0 )
234:      $   CLA_HERCOND_C = 1.0E+0 / AINVNM
235: *
236:       RETURN
237: *
238:       END
239: