001:       SUBROUTINE SORMQL( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
002:      $                   WORK, LWORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          SIDE, TRANS
010:       INTEGER            INFO, K, LDA, LDC, LWORK, M, N
011: *     ..
012: *     .. Array Arguments ..
013:       REAL               A( LDA, * ), C( LDC, * ), TAU( * ),
014:      $                   WORK( * )
015: *     ..
016: *
017: *  Purpose
018: *  =======
019: *
020: *  SORMQL overwrites the general real M-by-N matrix C with
021: *
022: *                  SIDE = 'L'     SIDE = 'R'
023: *  TRANS = 'N':      Q * C          C * Q
024: *  TRANS = 'T':      Q**T * C       C * Q**T
025: *
026: *  where Q is a real orthogonal matrix defined as the product of k
027: *  elementary reflectors
028: *
029: *        Q = H(k) . . . H(2) H(1)
030: *
031: *  as returned by SGEQLF. Q is of order M if SIDE = 'L' and of order N
032: *  if SIDE = 'R'.
033: *
034: *  Arguments
035: *  =========
036: *
037: *  SIDE    (input) CHARACTER*1
038: *          = 'L': apply Q or Q**T from the Left;
039: *          = 'R': apply Q or Q**T from the Right.
040: *
041: *  TRANS   (input) CHARACTER*1
042: *          = 'N':  No transpose, apply Q;
043: *          = 'T':  Transpose, apply Q**T.
044: *
045: *  M       (input) INTEGER
046: *          The number of rows of the matrix C. M >= 0.
047: *
048: *  N       (input) INTEGER
049: *          The number of columns of the matrix C. N >= 0.
050: *
051: *  K       (input) INTEGER
052: *          The number of elementary reflectors whose product defines
053: *          the matrix Q.
054: *          If SIDE = 'L', M >= K >= 0;
055: *          if SIDE = 'R', N >= K >= 0.
056: *
057: *  A       (input) REAL array, dimension (LDA,K)
058: *          The i-th column must contain the vector which defines the
059: *          elementary reflector H(i), for i = 1,2,...,k, as returned by
060: *          SGEQLF in the last k columns of its array argument A.
061: *          A is modified by the routine but restored on exit.
062: *
063: *  LDA     (input) INTEGER
064: *          The leading dimension of the array A.
065: *          If SIDE = 'L', LDA >= max(1,M);
066: *          if SIDE = 'R', LDA >= max(1,N).
067: *
068: *  TAU     (input) REAL array, dimension (K)
069: *          TAU(i) must contain the scalar factor of the elementary
070: *          reflector H(i), as returned by SGEQLF.
071: *
072: *  C       (input/output) REAL array, dimension (LDC,N)
073: *          On entry, the M-by-N matrix C.
074: *          On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
075: *
076: *  LDC     (input) INTEGER
077: *          The leading dimension of the array C. LDC >= max(1,M).
078: *
079: *  WORK    (workspace/output) REAL array, dimension (MAX(1,LWORK))
080: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
081: *
082: *  LWORK   (input) INTEGER
083: *          The dimension of the array WORK.
084: *          If SIDE = 'L', LWORK >= max(1,N);
085: *          if SIDE = 'R', LWORK >= max(1,M).
086: *          For optimum performance LWORK >= N*NB if SIDE = 'L', and
087: *          LWORK >= M*NB if SIDE = 'R', where NB is the optimal
088: *          blocksize.
089: *
090: *          If LWORK = -1, then a workspace query is assumed; the routine
091: *          only calculates the optimal size of the WORK array, returns
092: *          this value as the first entry of the WORK array, and no error
093: *          message related to LWORK is issued by XERBLA.
094: *
095: *  INFO    (output) INTEGER
096: *          = 0:  successful exit
097: *          < 0:  if INFO = -i, the i-th argument had an illegal value
098: *
099: *  =====================================================================
100: *
101: *     .. Parameters ..
102:       INTEGER            NBMAX, LDT
103:       PARAMETER          ( NBMAX = 64, LDT = NBMAX+1 )
104: *     ..
105: *     .. Local Scalars ..
106:       LOGICAL            LEFT, LQUERY, NOTRAN
107:       INTEGER            I, I1, I2, I3, IB, IINFO, IWS, LDWORK, LWKOPT,
108:      $                   MI, NB, NBMIN, NI, NQ, NW
109: *     ..
110: *     .. Local Arrays ..
111:       REAL               T( LDT, NBMAX )
112: *     ..
113: *     .. External Functions ..
114:       LOGICAL            LSAME
115:       INTEGER            ILAENV
116:       EXTERNAL           LSAME, ILAENV
117: *     ..
118: *     .. External Subroutines ..
119:       EXTERNAL           SLARFB, SLARFT, SORM2L, XERBLA
120: *     ..
121: *     .. Intrinsic Functions ..
122:       INTRINSIC          MAX, MIN
123: *     ..
124: *     .. Executable Statements ..
125: *
126: *     Test the input arguments
127: *
128:       INFO = 0
129:       LEFT = LSAME( SIDE, 'L' )
130:       NOTRAN = LSAME( TRANS, 'N' )
131:       LQUERY = ( LWORK.EQ.-1 )
132: *
133: *     NQ is the order of Q and NW is the minimum dimension of WORK
134: *
135:       IF( LEFT ) THEN
136:          NQ = M
137:          NW = MAX( 1, N )
138:       ELSE
139:          NQ = N
140:          NW = MAX( 1, M )
141:       END IF
142:       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
143:          INFO = -1
144:       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) ) THEN
145:          INFO = -2
146:       ELSE IF( M.LT.0 ) THEN
147:          INFO = -3
148:       ELSE IF( N.LT.0 ) THEN
149:          INFO = -4
150:       ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
151:          INFO = -5
152:       ELSE IF( LDA.LT.MAX( 1, NQ ) ) THEN
153:          INFO = -7
154:       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
155:          INFO = -10
156:       END IF
157: *
158:       IF( INFO.EQ.0 ) THEN
159:          IF( M.EQ.0 .OR. N.EQ.0 ) THEN
160:             LWKOPT = 1
161:          ELSE
162: *
163: *           Determine the block size.  NB may be at most NBMAX, where
164: *           NBMAX is used to define the local array T.
165: *
166: *
167:             NB = MIN( NBMAX, ILAENV( 1, 'SORMQL', SIDE // TRANS, M, N,
168:      $                               K, -1 ) )
169:             LWKOPT = NW*NB
170:          END IF
171:          WORK( 1 ) = LWKOPT
172: *
173:          IF( LWORK.LT.NW .AND. .NOT.LQUERY ) THEN
174:             INFO = -12
175:          END IF
176:       END IF
177: *
178:       IF( INFO.NE.0 ) THEN
179:          CALL XERBLA( 'SORMQL', -INFO )
180:          RETURN
181:       ELSE IF( LQUERY ) THEN
182:          RETURN
183:       END IF
184: *
185: *     Quick return if possible
186: *
187:       IF( M.EQ.0 .OR. N.EQ.0 ) THEN
188:          RETURN
189:       END IF
190: *
191:       NBMIN = 2
192:       LDWORK = NW
193:       IF( NB.GT.1 .AND. NB.LT.K ) THEN
194:          IWS = NW*NB
195:          IF( LWORK.LT.IWS ) THEN
196:             NB = LWORK / LDWORK
197:             NBMIN = MAX( 2, ILAENV( 2, 'SORMQL', SIDE // TRANS, M, N, K,
198:      $              -1 ) )
199:          END IF
200:       ELSE
201:          IWS = NW
202:       END IF
203: *
204:       IF( NB.LT.NBMIN .OR. NB.GE.K ) THEN
205: *
206: *        Use unblocked code
207: *
208:          CALL SORM2L( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK,
209:      $                IINFO )
210:       ELSE
211: *
212: *        Use blocked code
213: *
214:          IF( ( LEFT .AND. NOTRAN ) .OR.
215:      $       ( .NOT.LEFT .AND. .NOT.NOTRAN ) ) THEN
216:             I1 = 1
217:             I2 = K
218:             I3 = NB
219:          ELSE
220:             I1 = ( ( K-1 ) / NB )*NB + 1
221:             I2 = 1
222:             I3 = -NB
223:          END IF
224: *
225:          IF( LEFT ) THEN
226:             NI = N
227:          ELSE
228:             MI = M
229:          END IF
230: *
231:          DO 10 I = I1, I2, I3
232:             IB = MIN( NB, K-I+1 )
233: *
234: *           Form the triangular factor of the block reflector
235: *           H = H(i+ib-1) . . . H(i+1) H(i)
236: *
237:             CALL SLARFT( 'Backward', 'Columnwise', NQ-K+I+IB-1, IB,
238:      $                   A( 1, I ), LDA, TAU( I ), T, LDT )
239:             IF( LEFT ) THEN
240: *
241: *              H or H' is applied to C(1:m-k+i+ib-1,1:n)
242: *
243:                MI = M - K + I + IB - 1
244:             ELSE
245: *
246: *              H or H' is applied to C(1:m,1:n-k+i+ib-1)
247: *
248:                NI = N - K + I + IB - 1
249:             END IF
250: *
251: *           Apply H or H'
252: *
253:             CALL SLARFB( SIDE, TRANS, 'Backward', 'Columnwise', MI, NI,
254:      $                   IB, A( 1, I ), LDA, T, LDT, C, LDC, WORK,
255:      $                   LDWORK )
256:    10    CONTINUE
257:       END IF
258:       WORK( 1 ) = LWKOPT
259:       RETURN
260: *
261: *     End of SORMQL
262: *
263:       END
264: