001:       SUBROUTINE SORM2L( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
002:      $                   WORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          SIDE, TRANS
010:       INTEGER            INFO, K, LDA, LDC, M, N
011: *     ..
012: *     .. Array Arguments ..
013:       REAL               A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  SORM2L overwrites the general real m by n matrix C with
020: *
021: *        Q * C  if SIDE = 'L' and TRANS = 'N', or
022: *
023: *        Q'* C  if SIDE = 'L' and TRANS = 'T', or
024: *
025: *        C * Q  if SIDE = 'R' and TRANS = 'N', or
026: *
027: *        C * Q' if SIDE = 'R' and TRANS = 'T',
028: *
029: *  where Q is a real orthogonal matrix defined as the product of k
030: *  elementary reflectors
031: *
032: *        Q = H(k) . . . H(2) H(1)
033: *
034: *  as returned by SGEQLF. Q is of order m if SIDE = 'L' and of order n
035: *  if SIDE = 'R'.
036: *
037: *  Arguments
038: *  =========
039: *
040: *  SIDE    (input) CHARACTER*1
041: *          = 'L': apply Q or Q' from the Left
042: *          = 'R': apply Q or Q' from the Right
043: *
044: *  TRANS   (input) CHARACTER*1
045: *          = 'N': apply Q  (No transpose)
046: *          = 'T': apply Q' (Transpose)
047: *
048: *  M       (input) INTEGER
049: *          The number of rows of the matrix C. M >= 0.
050: *
051: *  N       (input) INTEGER
052: *          The number of columns of the matrix C. N >= 0.
053: *
054: *  K       (input) INTEGER
055: *          The number of elementary reflectors whose product defines
056: *          the matrix Q.
057: *          If SIDE = 'L', M >= K >= 0;
058: *          if SIDE = 'R', N >= K >= 0.
059: *
060: *  A       (input) REAL array, dimension (LDA,K)
061: *          The i-th column must contain the vector which defines the
062: *          elementary reflector H(i), for i = 1,2,...,k, as returned by
063: *          SGEQLF in the last k columns of its array argument A.
064: *          A is modified by the routine but restored on exit.
065: *
066: *  LDA     (input) INTEGER
067: *          The leading dimension of the array A.
068: *          If SIDE = 'L', LDA >= max(1,M);
069: *          if SIDE = 'R', LDA >= max(1,N).
070: *
071: *  TAU     (input) REAL array, dimension (K)
072: *          TAU(i) must contain the scalar factor of the elementary
073: *          reflector H(i), as returned by SGEQLF.
074: *
075: *  C       (input/output) REAL array, dimension (LDC,N)
076: *          On entry, the m by n matrix C.
077: *          On exit, C is overwritten by Q*C or Q'*C or C*Q' or C*Q.
078: *
079: *  LDC     (input) INTEGER
080: *          The leading dimension of the array C. LDC >= max(1,M).
081: *
082: *  WORK    (workspace) REAL array, dimension
083: *                                   (N) if SIDE = 'L',
084: *                                   (M) if SIDE = 'R'
085: *
086: *  INFO    (output) INTEGER
087: *          = 0: successful exit
088: *          < 0: if INFO = -i, the i-th argument had an illegal value
089: *
090: *  =====================================================================
091: *
092: *     .. Parameters ..
093:       REAL               ONE
094:       PARAMETER          ( ONE = 1.0E+0 )
095: *     ..
096: *     .. Local Scalars ..
097:       LOGICAL            LEFT, NOTRAN
098:       INTEGER            I, I1, I2, I3, MI, NI, NQ
099:       REAL               AII
100: *     ..
101: *     .. External Functions ..
102:       LOGICAL            LSAME
103:       EXTERNAL           LSAME
104: *     ..
105: *     .. External Subroutines ..
106:       EXTERNAL           SLARF, XERBLA
107: *     ..
108: *     .. Intrinsic Functions ..
109:       INTRINSIC          MAX
110: *     ..
111: *     .. Executable Statements ..
112: *
113: *     Test the input arguments
114: *
115:       INFO = 0
116:       LEFT = LSAME( SIDE, 'L' )
117:       NOTRAN = LSAME( TRANS, 'N' )
118: *
119: *     NQ is the order of Q
120: *
121:       IF( LEFT ) THEN
122:          NQ = M
123:       ELSE
124:          NQ = N
125:       END IF
126:       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
127:          INFO = -1
128:       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) ) THEN
129:          INFO = -2
130:       ELSE IF( M.LT.0 ) THEN
131:          INFO = -3
132:       ELSE IF( N.LT.0 ) THEN
133:          INFO = -4
134:       ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
135:          INFO = -5
136:       ELSE IF( LDA.LT.MAX( 1, NQ ) ) THEN
137:          INFO = -7
138:       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
139:          INFO = -10
140:       END IF
141:       IF( INFO.NE.0 ) THEN
142:          CALL XERBLA( 'SORM2L', -INFO )
143:          RETURN
144:       END IF
145: *
146: *     Quick return if possible
147: *
148:       IF( M.EQ.0 .OR. N.EQ.0 .OR. K.EQ.0 )
149:      $   RETURN
150: *
151:       IF( ( LEFT .AND. NOTRAN ) .OR. ( .NOT.LEFT .AND. .NOT.NOTRAN ) )
152:      $     THEN
153:          I1 = 1
154:          I2 = K
155:          I3 = 1
156:       ELSE
157:          I1 = K
158:          I2 = 1
159:          I3 = -1
160:       END IF
161: *
162:       IF( LEFT ) THEN
163:          NI = N
164:       ELSE
165:          MI = M
166:       END IF
167: *
168:       DO 10 I = I1, I2, I3
169:          IF( LEFT ) THEN
170: *
171: *           H(i) is applied to C(1:m-k+i,1:n)
172: *
173:             MI = M - K + I
174:          ELSE
175: *
176: *           H(i) is applied to C(1:m,1:n-k+i)
177: *
178:             NI = N - K + I
179:          END IF
180: *
181: *        Apply H(i)
182: *
183:          AII = A( NQ-K+I, I )
184:          A( NQ-K+I, I ) = ONE
185:          CALL SLARF( SIDE, MI, NI, A( 1, I ), 1, TAU( I ), C, LDC,
186:      $               WORK )
187:          A( NQ-K+I, I ) = AII
188:    10 CONTINUE
189:       RETURN
190: *
191: *     End of SORM2L
192: *
193:       END
194: