01:       REAL FUNCTION SDOT(N,SX,INCX,SY,INCY)
02: *     .. Scalar Arguments ..
03:       INTEGER INCX,INCY,N
04: *     ..
05: *     .. Array Arguments ..
06:       REAL SX(*),SY(*)
07: *     ..
08: *
09: *  Purpose
10: *  =======
11: *
12: *     forms the dot product of two vectors.
13: *     uses unrolled loops for increments equal to one.
14: *     jack dongarra, linpack, 3/11/78.
15: *     modified 12/3/93, array(1) declarations changed to array(*)
16: *
17: *
18: 
19: *     .. Local Scalars ..
20:       REAL STEMP
21:       INTEGER I,IX,IY,M,MP1
22: *     ..
23: *     .. Intrinsic Functions ..
24:       INTRINSIC MOD
25: *     ..
26:       STEMP = 0.0e0
27:       SDOT = 0.0e0
28:       IF (N.LE.0) RETURN
29:       IF (INCX.EQ.1 .AND. INCY.EQ.1) GO TO 20
30: *
31: *        code for unequal increments or equal increments
32: *          not equal to 1
33: *
34:       IX = 1
35:       IY = 1
36:       IF (INCX.LT.0) IX = (-N+1)*INCX + 1
37:       IF (INCY.LT.0) IY = (-N+1)*INCY + 1
38:       DO 10 I = 1,N
39:           STEMP = STEMP + SX(IX)*SY(IY)
40:           IX = IX + INCX
41:           IY = IY + INCY
42:    10 CONTINUE
43:       SDOT = STEMP
44:       RETURN
45: *
46: *        code for both increments equal to 1
47: *
48: *
49: *        clean-up loop
50: *
51:    20 M = MOD(N,5)
52:       IF (M.EQ.0) GO TO 40
53:       DO 30 I = 1,M
54:           STEMP = STEMP + SX(I)*SY(I)
55:    30 CONTINUE
56:       IF (N.LT.5) GO TO 60
57:    40 MP1 = M + 1
58:       DO 50 I = MP1,N,5
59:           STEMP = STEMP + SX(I)*SY(I) + SX(I+1)*SY(I+1) +
60:      +            SX(I+2)*SY(I+2) + SX(I+3)*SY(I+3) + SX(I+4)*SY(I+4)
61:    50 CONTINUE
62:    60 SDOT = STEMP
63:       RETURN
64:       END
65: