dpttrsv()

subroutine dpttrsv	(	character	trans,
		integer	n,
		integer	nrhs,
		double precision, dimension( * )	d,
		double precision, dimension( * )	e,
		double precision, dimension( ldb, * )	b,
		integer	ldb,
		integer	info
	)

Definition at line 1 of file dpttrsv.f.

*
*  -- ScaLAPACK auxiliary routine (version 2.0) --
*     Univ. of Tennessee, Univ. of California Berkeley, Univ. of Colorado Denver
*
*     Written by Andrew J. Cleary, University of Tennessee.
*     November, 1996.
*     Modified from DPTTRS:
*  -- LAPACK routine (preliminary version) --
*     Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
*     Courant Institute, Argonne National Lab, and Rice University
*
*     .. Scalar Arguments ..
      CHARACTER          TRANS
      INTEGER            INFO, LDB, N, NRHS
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   D( * )
      DOUBLE PRECISION   B( LDB, * ), E( * )
*     ..
*
*  Purpose
*  =======
*
*  DPTTRSV solves one of the triangular systems
*     L**T* X = B, or  L * X = B,
*  where L is the Cholesky factor of a Hermitian positive
*  definite tridiagonal matrix A such that
*  A = L*D*L**H (computed by DPTTRF).
*
*  Arguments
*  =========
*
*  TRANS   (input) CHARACTER
*          Specifies the form of the system of equations:
*          = 'N':  L * X = B     (No transpose)
*          = 'T':  L**T * X = B  (Transpose)
*
*  N       (input) INTEGER
*          The order of the tridiagonal matrix A.  N >= 0.
*
*  NRHS    (input) INTEGER
*          The number of right hand sides, i.e., the number of columns
*          of the matrix B.  NRHS >= 0.
*
*  D       (input) REAL array, dimension (N)
*          The n diagonal elements of the diagonal matrix D from the
*          factorization computed by DPTTRF.
*
*  E       (input) COMPLEX array, dimension (N-1)
*          The (n-1) off-diagonal elements of the unit bidiagonal
*          factor U or L from the factorization computed by DPTTRF
*          (see UPLO).
*
*  B       (input/output) COMPLEX array, dimension (LDB,NRHS)
*          On entry, the right hand side matrix B.
*          On exit, the solution matrix X.
*
*  LDB     (input) INTEGER
*          The leading dimension of the array B.  LDB >= max(1,N).
*
*  INFO    (output) INTEGER
*          = 0:  successful exit
*          < 0:  if INFO = -i, the i-th argument had an illegal value
*
*  =====================================================================
*
*     .. Local Scalars ..
      LOGICAL            NOTRAN
      INTEGER            I, J
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments.
*
      info = 0
      notran = lsame( trans, 'N' )
      IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( nrhs.LT.0 ) THEN
         info = -3
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -7
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DPTTRS', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
      IF( notran ) THEN
*
         DO 60 j = 1, nrhs
*
*           Solve L * x = b.
*
            DO 40 i = 2, n
               b( i, j ) = b( i, j ) - b( i-1, j )*e( i-1 )
   40       CONTINUE
   60    CONTINUE
*
      ELSE
*
         DO 65 j = 1, nrhs
*
*           Solve L**H * x = b.
*
            DO 50 i = n - 1, 1, -1
               b( i, j ) = b( i, j ) -
     $                     b( i+1, j )*( e( i ) )
   50       CONTINUE
   65    CONTINUE
      ENDIF
*
      RETURN
*
*     End of DPTTRS
*

Here is the caller graph for this function: