slcombine()

subroutine slcombine	(	integer	ictxt,
		character	scope,
		character	op,
		character	timetype,
		integer	n,
		integer	ibeg,
		double precision, dimension( n )	times
	)

Definition at line 265 of file sltimer.f.

*
*  -- ScaLAPACK tools routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          OP, SCOPE, TIMETYPE
      INTEGER            IBEG, ICTXT, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   TIMES( N )
*     ..
*
*  Purpose
*  =======
*
*  SLCOMBINE takes the timing information stored on a scope of processes
*  and combines them into the user's TIMES array.
*
*  Arguments
*  =========
*
*  ICTXT    (local input) INTEGER
*           The BLACS context handle.
*
*  SCOPE    (global input) CHARACTER
*           Controls what processes in grid participate in combine.
*           Options are 'Rowwise', 'Columnwise', or 'All'.
*
*  OP       (global input) CHARACTER
*           Controls what combine should be done:
*           = '>': get maximal time on any process (default),
*           = '<': get minimal time on any process,
*           = '+': get sum of times across processes.
*
*  TIMETYPE (global input) CHARACTER
*           Controls what time will be returned in TIMES:
*           = 'W': wall clock time,
*           = 'C': CPU time (default).
*
*  N        (global input) INTEGER
*           The number of timers to combine.
*
*  IBEG     (global input) INTEGER
*           The first timer to be combined.
*
*  TIMES    (global output) DOUBLE PRECISION array, dimension (N)
*           The requested timing information is returned in this array.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            NTIMER
      parameter( ntimer = 64 )
      DOUBLE PRECISION   ERRFLAG
      parameter( errflag = -1.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            TMPDIS
      INTEGER            I
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgamx2d, dgamn2d, dgsum2d
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   DCPUTIME00, DWALLTIME00
      EXTERNAL           dcputime00, dwalltime00, lsame
*     ..
*     .. Common Blocks ..
      LOGICAL            DISABLED
      DOUBLE PRECISION   CPUSEC( NTIMER ), CPUSTART( NTIMER ),
     $                   WALLSEC( NTIMER ), WALLSTART( NTIMER )
      COMMON /sltimer00/ cpusec, wallsec, cpustart, wallstart, disabled
*     ..
*     .. Executable Statements ..
*
*     Disable timer for combine operation
*
      tmpdis = disabled
      disabled = .true.
*
*     Copy timer information into user's times array
*
      IF( lsame( timetype, 'W' ) ) THEN
*
*        If walltime not available on this machine, fill in times
*        with -1 flag, and return
*
         IF( dwalltime00().EQ.errflag ) THEN
            DO 10 i = 1, n
               times( i ) = errflag
   10       CONTINUE
            RETURN
         ELSE
            DO 20 i = 1, n
               times( i ) = wallsec( ibeg + i - 1 )
   20       CONTINUE
         END IF
      ELSE
         IF( dcputime00().EQ.errflag ) THEN
            DO 30 i = 1, n
               times( i ) = errflag
   30       CONTINUE
            RETURN
         ELSE
            DO 40 i = 1, n
               times( i ) = cpusec( ibeg + i - 1 )
   40       CONTINUE
         END IF
      ENDIF
*
*     Combine all nodes' information, restore disabled, and return
*
      IF( op.EQ.'>' ) THEN
         CALL dgamx2d( ictxt, scope, ' ', n, 1, times, n, -1, -1,
     $                 -1, -1, 0 )
      ELSE IF( op.EQ.'<' ) THEN
         CALL dgamn2d( ictxt, scope, ' ', n, 1, times, n, -1, -1,
     $                 -1, -1, 0 )
      ELSE IF( op.EQ.'+' ) THEN
         CALL dgsum2d( ictxt, scope, ' ', n, 1, times, n, -1, 0 )
      ELSE
         CALL dgamx2d( ictxt, scope, ' ', n, 1, times, n, -1, -1,
     $                 -1, -1, 0 )
      END IF
*
      disabled = tmpdis
*
      RETURN
*
*     End of SLCOMBINE
*