pb_jump()

subroutine pb_jump	(	integer	k,
		integer, dimension( 4 )	muladd,
		integer, dimension( 2 )	irann,
		integer, dimension( 2 )	iranm,
		integer, dimension( 4 )	ima
	)

Definition at line 4647 of file pblastst.f.

*
*  -- PBLAS test routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      INTEGER            K
*     ..
*     .. Array Arguments ..
      INTEGER            IMA( 4 ), IRANM( 2 ), IRANN( 2 ), MULADD( 4 )
*     ..
*
*  Purpose
*  =======
*
*  PB_JUMP  computes the constants A and C to jump K numbers in the ran-
*  dom sequence:
*
*     X( n+K ) = A * X( n ) + C.
*
*  The constants encoded in MULADD specify how to jump from entry in the
*  sequence to the next.
*
*  Arguments
*  =========
*
*  K       (local input) INTEGER
*          On entry, K specifies the number of entries  of  the sequence
*          to jump over. When K is less or equal than zero, A and C  are
*          not computed, and  IRANM  is set to  IRANN corresponding to a
*          jump of size zero.
*
*  MULADD  (local input) INTEGER array
*          On entry,  MULADD  is an  array of dimension 4 containing the
*          encoded constants a and c to  jump  from  X( n ) to  X( n+1 )
*          ( = a*X( n )+c) in the random sequence.  MULADD(1:2) contains
*          respectively the 16-lower and 16-higher bits of  the constant
*          a,  and  MULADD(3:4) contains the 16-lower and 16-higher bits
*          of the constant c.
*
*  IRANN   (local input) INTEGER array
*          On entry,  IRANN  is an array of dimension 2. This array con-
*          tains respectively the 16-lower and 16-higher bits of the en-
*          coding of X( n ).
*
*  IRANM   (local output) INTEGER array
*          On entry,  IRANM  is an  array of dimension 2.  On exit, this
*          array contains respectively the 16-lower and  16-higher  bits
*          of the encoding of X( n+K ).
*
*  IMA     (local output) INTEGER array
*          On entry, IMA is an array of dimension 4. On exit, when K is
*          greater than zero, this array contains the encoded constants
*          A and C to  jump  from X( n ) to  X( n+K ) in the random se-
*          quence.  IMA(1:2)  contains  respectively  the  16-lower and
*          16-higher bits of the constant A, and IMA(3:4)  contains the
*          16-lower  and  16-higher  bits of the constant  C. When K is
*          less or equal than zero, this array is not referenced.
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            I
*     ..
*     .. Local Arrays ..
      INTEGER            J( 2 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           pb_ladd, pb_lmul
*     ..
*     .. Executable Statements ..
*
      IF( k.GT.0 ) THEN
*
         ima( 1 ) = muladd( 1 )
         ima( 2 ) = muladd( 2 )
         ima( 3 ) = muladd( 3 )
         ima( 4 ) = muladd( 4 )
*
         DO 10 i = 1, k - 1
*
            CALL pb_lmul( ima, muladd, j )
*
            ima( 1 ) = j( 1 )
            ima( 2 ) = j( 2 )
*
            CALL pb_lmul( ima( 3 ), muladd, j )
            CALL pb_ladd( muladd( 3 ), j, ima( 3 ) )
*
   10    CONTINUE
*
         CALL pb_lmul( irann, ima, j )
         CALL pb_ladd( j, ima( 3 ), iranm )
*
      ELSE
*
         iranm( 1 ) = irann( 1 )
         iranm( 2 ) = irann( 2 )
*
      END IF
*
      RETURN
*
*     End of PB_JUMP
*

Here is the caller graph for this function: