pb_ainfog2l()

subroutine pb_ainfog2l	(	integer	m,
		integer	n,
		integer	i,
		integer	j,
		integer, dimension( * )	desc,
		integer	nprow,
		integer	npcol,
		integer	myrow,
		integer	mycol,
		integer	imb1,
		integer	inb1,
		integer	mp,
		integer	nq,
		integer	ii,
		integer	jj,
		integer	prow,
		integer	pcol,
		integer	rprow,
		integer	rpcol
	)

Definition at line 2020 of file pblastst.f.

*
*  -- PBLAS test routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      INTEGER            I, II, IMB1, INB1, J, JJ, M, MP, MYCOL, MYROW,
     $                   N, NPCOL, NPROW, NQ, PCOL, PROW, RPCOL, RPROW
*     ..
*     .. Array Arguments ..
      INTEGER            DESC( * )
*     ..
*
*  Purpose
*  =======
*
*  PB_AINFOG2L  computes the  starting  local row and column indexes II,
*  JJ  corresponding to  the  submatrix  starting  globally at the entry
*  pointed by I,  J. This routine returns the coordinates in the grid of
*  the  process owning  the  matrix entry of global indexes I, J, namely
*  PROW  and  PCOL. In addition, this routine computes the quantities MP
*  and  NQ,  which are respectively the local number of rows and columns
*  owned by the process of coordinate  MYROW, MYCOL corresponding to the
*  global submatrix A(I:I+M-1,J:J+N-1).  Finally, the size  of the first
*  partial block and the relative process coordinates  are also returned
*  respectively in IMB, INB and RPROW, RPCOL.
*
*  Notes
*  =====
*
*  A description  vector  is associated with each 2D block-cyclicly dis-
*  tributed matrix.  This  vector  stores  the  information  required to
*  establish the  mapping  between a  matrix entry and its corresponding
*  process and memory location.
*
*  In  the  following  comments,   the character _  should  be  read  as
*  "of  the  distributed  matrix".  Let  A  be a generic term for any 2D
*  block cyclicly distributed matrix.  Its description vector is DESCA:
*
*  NOTATION         STORED IN       EXPLANATION
*  ---------------- --------------- ------------------------------------
*  DTYPE_A (global) DESCA( DTYPE_ ) The descriptor type.
*  CTXT_A  (global) DESCA( CTXT_  ) The BLACS context handle, indicating
*                                   the NPROW x NPCOL BLACS process grid
*                                   A  is distributed over.  The context
*                                   itself  is  global,  but  the handle
*                                   (the integer value) may vary.
*  M_A     (global) DESCA( M_     ) The  number of rows in the distribu-
*                                   ted matrix A, M_A >= 0.
*  N_A     (global) DESCA( N_     ) The number of columns in the distri-
*                                   buted matrix A, N_A >= 0.
*  IMB_A   (global) DESCA( IMB_   ) The number of rows of the upper left
*                                   block of the matrix A, IMB_A > 0.
*  INB_A   (global) DESCA( INB_   ) The  number  of columns of the upper
*                                   left   block   of   the   matrix  A,
*                                   INB_A > 0.
*  MB_A    (global) DESCA( MB_    ) The blocking factor used to  distri-
*                                   bute the last  M_A-IMB_A rows of  A,
*                                   MB_A > 0.
*  NB_A    (global) DESCA( NB_    ) The blocking factor used to  distri-
*                                   bute the last  N_A-INB_A  columns of
*                                   A, NB_A > 0.
*  RSRC_A  (global) DESCA( RSRC_  ) The process row over which the first
*                                   row of the matrix  A is distributed,
*                                   NPROW > RSRC_A >= 0.
*  CSRC_A  (global) DESCA( CSRC_  ) The  process  column  over which the
*                                   first  column of  A  is distributed.
*                                   NPCOL > CSRC_A >= 0.
*  LLD_A   (local)  DESCA( LLD_   ) The  leading  dimension of the local
*                                   array  storing  the  local blocks of
*                                   the distributed matrix A,
*                                   IF( Lc( 1, N_A ) > 0 )
*                                      LLD_A >= MAX( 1, Lr( 1, M_A ) )
*                                   ELSE
*                                      LLD_A >= 1.
*
*  Let K be the number of  rows of a matrix A starting at the global in-
*  dex IA,i.e, A( IA:IA+K-1, : ). Lr( IA, K ) denotes the number of rows
*  that the process of row coordinate MYROW ( 0 <= MYROW < NPROW ) would
*  receive if these K rows were distributed over NPROW processes.  If  K
*  is the number of columns of a matrix  A  starting at the global index
*  JA, i.e, A( :, JA:JA+K-1, : ), Lc( JA, K ) denotes the number  of co-
*  lumns that the process MYCOL ( 0 <= MYCOL < NPCOL ) would  receive if
*  these K columns were distributed over NPCOL processes.
*
*  The values of Lr() and Lc() may be determined via a call to the func-
*  tion PB_NUMROC:
*  Lr( IA, K ) = PB_NUMROC( K, IA, IMB_A, MB_A, MYROW, RSRC_A, NPROW )
*  Lc( JA, K ) = PB_NUMROC( K, JA, INB_A, NB_A, MYCOL, CSRC_A, NPCOL )
*
*  Arguments
*  =========
*
*  M       (global input) INTEGER
*          On entry, M specifies the global number of rows of the subma-
*          trix. M must be at least zero.
*
*  N       (global input) INTEGER
*          On entry, N specifies  the  global  number  of columns of the
*          submatrix. N must be at least zero.
*
*  I       (global input) INTEGER
*          On entry, I  specifies  the  global starting row index of the
*          submatrix. I must at least one.
*
*  J       (global input) INTEGER
*          On entry, J  specifies  the global starting column  index  of
*          the submatrix. J must at least one.
*
*  DESC    (global and local input) INTEGER array
*          On entry,  DESC is an integer array of dimension DLEN_.  This
*          is the array descriptor of the underlying matrix.
*
*  NPROW   (global input) INTEGER
*          On entry,  NPROW   specifies the total number of process rows
*          over which the matrix is distributed.  NPROW must be at least
*          one.
*
*  NPCOL   (global input) INTEGER
*          On entry, NPCOL specifies the total number of process columns
*          over which the matrix is distributed.  NPCOL must be at least
*          one.
*
*  MYROW   (local input) INTEGER
*          On entry,  MYROW  specifies the row coordinate of the process
*          whose local index  II  is determined.  MYROW must be at least
*          zero and strictly less than NPROW.
*
*  MYCOL   (local input) INTEGER
*          On entry,  MYCOL  specifies the column coordinate of the pro-
*          cess whose local index  JJ  is determined.  MYCOL  must be at
*          least zero and strictly less than NPCOL.
*
*  IMB1    (global output) INTEGER
*          On exit, IMB1 specifies the number of rows of the upper  left
*          block of the submatrix. On exit,  IMB1 is less or equal  than
*          M and greater or equal than MIN( 1, M ).
*
*  INB1    (global output) INTEGER
*          On exit, INB1 specifies  the number  of  columns of the upper
*          left block of the submatrix. On exit,  INB1 is  less or equal
*          than N and greater or equal than MIN( 1, N ).
*
*  MP      (local output) INTEGER
*          On exit, MP specifies the local number of rows of the  subma-
*          trix, that the processes of row coordinate MYROW own.  MP  is
*          at least zero.
*
*  NQ      (local output) INTEGER
*          On exit, NQ specifies  the  local  number  of columns  of the
*          submatrix,  that  the processes  of column  coordinate  MYCOL
*          own. NQ is at least zero.
*
*  II      (local output) INTEGER
*          On exit, II  specifies the  local  starting  row index of the
*          submatrix. On exit, II is at least one.
*
*  JJ      (local output) INTEGER
*          On exit, JJ  specifies the  local  starting  column index  of
*          the submatrix. On exit, II is at least one.
*
*  PROW    (global output) INTEGER
*          On exit,  PROW  specifies the row coordinate of  the  process
*          that possesses the first row of the submatrix. On exit,  PROW
*          is -1 if DESC(RSRC_)  is -1 on input, and, at least zero  and
*          strictly less than NPROW otherwise.
*
*  PCOL    (global output) INTEGER
*          On exit, PCOL  specifies the column coordinate of the process
*          that possesses the first column of the  submatrix.  On  exit,
*          PCOL is -1 if DESC(CSRC_)  is -1 on input, and, at least zero
*          and strictly less than NPCOL otherwise.
*
*  RPROW   (global output) INTEGER
*          On exit, RPROW specifies  the  relative row coordinate of the
*          process that possesses the first row  I  of the submatrix. On
*          exit, RPROW is -1 if DESC(RSRC_) is  -1  on  input,  and,  at
*          least zero and strictly less than NPROW otherwise.
*
*  RPCOL   (global output) INTEGER
*          On exit, RPCOL specifies  the  relative column  coordinate of
*          the process that possesses the first column  J  of the subma-
*          trix. On exit, RPCOL is -1 if  DESC(CSRC_)  is  -1  on input,
*          and, at least zero and strictly less than NPCOL otherwise.
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D_INB, CSRC_, CTXT_, DLEN_,
     $                   DTYPE_, IMB_, INB_, LLD_, MB_, M_, NB_, N_,
     $                   RSRC_
      parameter( block_cyclic_2d_inb = 2, dlen_ = 11,
     $                   dtype_ = 1, ctxt_ = 2, m_ = 3, n_ = 4,
     $                   imb_ = 5, inb_ = 6, mb_ = 7, nb_ = 8,
     $                   rsrc_ = 9, csrc_ = 10, lld_ = 11 )
*     ..
*     .. Local Scalars ..
      INTEGER            CSRC, I1, ILOCBLK, J1, M1, MB, MYDIST, N1, NB,
     $                   NBLOCKS, RSRC
*     ..
*     .. Local Arrays ..
      INTEGER            DESC2( DLEN_ )
*     ..
*     .. External Subroutines ..
      EXTERNAL           pb_desctrans
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          min
*     ..
*     .. Executable Statements ..
*
*     Convert descriptor
*
      CALL pb_desctrans( desc, desc2 )
*
      mb   = desc2( mb_ )
      imb1 = desc2( imb_ )
      rsrc = desc2( rsrc_ )
*
      IF( ( rsrc.EQ.-1 ).OR.( nprow.EQ.1 ) ) THEN
*
         ii    = i
         imb1  = imb1 - i + 1
         IF( imb1.LE.0 )
     $      imb1 = ( ( -imb1 ) / mb + 1 ) * mb + imb1
         imb1  = min( imb1, m )
         mp    = m
         prow  = rsrc
         rprow = 0
*
      ELSE
*
*        Figure out PROW, II and IMB1 first
*
         IF( i.LE.imb1 ) THEN
*
            prow = rsrc
*
            IF( myrow.EQ.prow ) THEN
               ii = i
            ELSE
               ii = 1
            END IF
*
            imb1 = imb1 - i + 1
*
         ELSE
*
            i1 = i - imb1 - 1
            nblocks = i1 / mb + 1
            prow = rsrc + nblocks
            prow = prow - ( prow / nprow ) * nprow
*
            IF( myrow.EQ.rsrc ) THEN
*
               ilocblk = nblocks / nprow
*
               IF( ilocblk.GT.0 ) THEN
                  IF( ( ilocblk*nprow ).GE.nblocks ) THEN
                     IF( myrow.EQ.prow ) THEN
                        ii = i + ( ilocblk - nblocks ) * mb
                     ELSE
                        ii = imb1 + ( ilocblk - 1 ) * mb + 1
                     END IF
                  ELSE
                     ii = imb1 + ilocblk * mb + 1
                  END IF
               ELSE
                  ii = imb1 + 1
               END IF
*
            ELSE
*
               mydist = myrow - rsrc
               IF( mydist.LT.0 )
     $            mydist = mydist + nprow
*
               ilocblk = nblocks / nprow
*
               IF( ilocblk.GT.0 ) THEN
                  mydist = mydist - nblocks + ilocblk * nprow
                  IF( mydist.LT.0 ) THEN
                     ii = ( ilocblk + 1 ) * mb + 1
                  ELSE IF( myrow.EQ.prow ) THEN
                     ii = i1 + ( ilocblk - nblocks + 1 ) * mb + 1
                  ELSE
                     ii = ilocblk * mb + 1
                  END IF
               ELSE
                  mydist = mydist - nblocks
                  IF( mydist.LT.0 ) THEN
                     ii = mb + 1
                  ELSE IF( myrow.EQ.prow ) THEN
                     ii = i1 + ( 1 - nblocks ) * mb + 1
                  ELSE
                     ii = 1
                  END IF
               END IF
            END IF
*
            imb1 = nblocks * mb - i1
*
         END IF
*
*        Figure out MP
*
         IF( m.LE.imb1 ) THEN
*
            IF( myrow.EQ.prow ) THEN
               mp = m
            ELSE
               mp = 0
            END IF
*
         ELSE
*
            m1 = m - imb1
            nblocks = m1 / mb + 1
*
            IF( myrow.EQ.prow ) THEN
               ilocblk = nblocks / nprow
               IF( ilocblk.GT.0 ) THEN
                  IF( ( nblocks - ilocblk * nprow ).GT.0 ) THEN
                     mp = imb1 + ilocblk * mb
                  ELSE
                     mp = m + mb * ( ilocblk - nblocks )
                  END IF
               ELSE
                  mp = imb1
               END IF
            ELSE
               mydist = myrow - prow
               IF( mydist.LT.0 )
     $            mydist = mydist + nprow
               ilocblk = nblocks / nprow
               IF( ilocblk.GT.0 ) THEN
                  mydist = mydist - nblocks + ilocblk * nprow
                  IF( mydist.LT.0 ) THEN
                     mp = ( ilocblk + 1 ) * mb
                  ELSE IF( mydist.GT.0 ) THEN
                     mp = ilocblk * mb
                  ELSE
                     mp = m1 + mb * ( ilocblk - nblocks + 1 )
                  END IF
               ELSE
                  mydist = mydist - nblocks
                  IF( mydist.LT.0 ) THEN
                     mp = mb
                  ELSE IF( mydist.GT.0 ) THEN
                     mp = 0
                  ELSE
                     mp = m1 + mb * ( 1 - nblocks )
                  END IF
               END IF
            END IF
*
         END IF
*
         imb1 = min( imb1, m )
         rprow = myrow - prow
         IF( rprow.LT.0 )
     $      rprow = rprow + nprow
*
      END IF
*
      nb   = desc2( nb_ )
      inb1 = desc2( inb_ )
      csrc = desc2( csrc_ )
*
      IF( ( csrc.EQ.-1 ).OR.( npcol.EQ.1 ) ) THEN
*
         jj    = j
         inb1  = inb1 - i + 1
         IF( inb1.LE.0 )
     $      inb1 = ( ( -inb1 ) / nb + 1 ) * nb + inb1
         inb1  = min( inb1, n )
         nq    = n
         pcol  = csrc
         rpcol = 0
*
      ELSE
*
*        Figure out PCOL, JJ and INB1 first
*
         IF( j.LE.inb1 ) THEN
*
            pcol = csrc
*
            IF( mycol.EQ.pcol ) THEN
               jj = j
            ELSE
               jj = 1
            END IF
*
            inb1 = inb1 - j + 1
*
         ELSE
*
            j1 = j - inb1 - 1
            nblocks = j1 / nb + 1
            pcol = csrc + nblocks
            pcol = pcol - ( pcol / npcol ) * npcol
*
            IF( mycol.EQ.csrc ) THEN
*
               ilocblk = nblocks / npcol
*
               IF( ilocblk.GT.0 ) THEN
                  IF( ( ilocblk*npcol ).GE.nblocks ) THEN
                     IF( mycol.EQ.pcol ) THEN
                        jj = j + ( ilocblk - nblocks ) * nb
                     ELSE
                        jj = inb1 + ( ilocblk - 1 ) * nb + 1
                     END IF
                  ELSE
                     jj = inb1 + ilocblk * nb + 1
                  END IF
               ELSE
                  jj = inb1 + 1
               END IF
*
            ELSE
*
               mydist = mycol - csrc
               IF( mydist.LT.0 )
     $            mydist = mydist + npcol
*
               ilocblk = nblocks / npcol
*
               IF( ilocblk.GT.0 ) THEN
                  mydist = mydist - nblocks + ilocblk * npcol
                  IF( mydist.LT.0 ) THEN
                     jj = ( ilocblk + 1 ) * nb + 1
                  ELSE IF( mycol.EQ.pcol ) THEN
                     jj = j1 + ( ilocblk - nblocks + 1 ) * nb + 1
                  ELSE
                     jj = ilocblk * nb + 1
                  END IF
               ELSE
                  mydist = mydist - nblocks
                  IF( mydist.LT.0 ) THEN
                     jj = nb + 1
                  ELSE IF( mycol.EQ.pcol ) THEN
                     jj = j1 + ( 1 - nblocks ) * nb + 1
                  ELSE
                     jj = 1
                  END IF
               END IF
            END IF
*
            inb1 = nblocks * nb - j1
*
         END IF
*
*        Figure out NQ
*
         IF( n.LE.inb1 ) THEN
*
            IF( mycol.EQ.pcol ) THEN
               nq = n
            ELSE
               nq = 0
            END IF
*
         ELSE
*
            n1 = n - inb1
            nblocks = n1 / nb + 1
*
            IF( mycol.EQ.pcol ) THEN
               ilocblk = nblocks / npcol
               IF( ilocblk.GT.0 ) THEN
                  IF( ( nblocks - ilocblk * npcol ).GT.0 ) THEN
                     nq = inb1 + ilocblk * nb
                  ELSE
                     nq = n + nb * ( ilocblk - nblocks )
                  END IF
               ELSE
                  nq = inb1
               END IF
            ELSE
               mydist = mycol - pcol
               IF( mydist.LT.0 )
     $            mydist = mydist + npcol
               ilocblk = nblocks / npcol
               IF( ilocblk.GT.0 ) THEN
                  mydist = mydist - nblocks + ilocblk * npcol
                  IF( mydist.LT.0 ) THEN
                     nq = ( ilocblk + 1 ) * nb
                  ELSE IF( mydist.GT.0 ) THEN
                     nq = ilocblk * nb
                  ELSE
                     nq = n1 + nb * ( ilocblk - nblocks + 1 )
                  END IF
               ELSE
                  mydist = mydist - nblocks
                  IF( mydist.LT.0 ) THEN
                     nq = nb
                  ELSE IF( mydist.GT.0 ) THEN
                     nq = 0
                  ELSE
                     nq = n1 + nb * ( 1 - nblocks )
                  END IF
               END IF
            END IF
*
         END IF
*
         inb1 = min( inb1, n )
         rpcol = mycol - pcol
         IF( rpcol.LT.0 )
     $      rpcol = rpcol + npcol
*
      END IF
*
      RETURN
*
*     End of PB_AINFOG2L
*

Here is the call graph for this function:

Here is the caller graph for this function: