zsptrs.f

Go to the documentation of this file.

*> \brief \b ZSPTRS
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download ZSPTRS + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zsptrs.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zsptrs.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zsptrs.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZSPTRS( UPLO, N, NRHS, AP, IPIV, B, LDB, INFO )
*
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            INFO, LDB, N, NRHS
*       ..
*       .. Array Arguments ..
*       INTEGER            IPIV( * )
*       COMPLEX*16         AP( * ), B( LDB, * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZSPTRS solves a system of linear equations A*X = B with a complex
*> symmetric matrix A stored in packed format using the factorization
*> A = U*D*U**T or A = L*D*L**T computed by ZSPTRF.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the details of the factorization are stored
*>          as an upper or lower triangular matrix.
*>          = 'U':  Upper triangular, form is A = U*D*U**T;
*>          = 'L':  Lower triangular, form is A = L*D*L**T.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>          The number of right hand sides, i.e., the number of columns
*>          of the matrix B.  NRHS >= 0.
*> \endverbatim
*>
*> \param[in] AP
*> \verbatim
*>          AP is COMPLEX*16 array, dimension (N*(N+1)/2)
*>          The block diagonal matrix D and the multipliers used to
*>          obtain the factor U or L as computed by ZSPTRF, stored as a
*>          packed triangular matrix.
*> \endverbatim
*>
*> \param[in] IPIV
*> \verbatim
*>          IPIV is INTEGER array, dimension (N)
*>          Details of the interchanges and the block structure of D
*>          as determined by ZSPTRF.
*> \endverbatim
*>
*> \param[in,out] B
*> \verbatim
*>          B is COMPLEX*16 array, dimension (LDB,NRHS)
*>          On entry, the right hand side matrix B.
*>          On exit, the solution matrix X.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B.  LDB >= max(1,N).
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit
*>          < 0: if INFO = -i, the i-th argument had an illegal value
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup hptrs
*
*  =====================================================================
      SUBROUTINE zsptrs( UPLO, N, NRHS, AP, IPIV, B, LDB, INFO )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, LDB, N, NRHS
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      COMPLEX*16         AP( * ), B( LDB, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX*16         ONE
      parameter( one = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            J, K, KC, KP
      COMPLEX*16         AK, AKM1, AKM1K, BK, BKM1, DENOM
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zgemv, zgeru, zscal, zswap
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( nrhs.LT.0 ) THEN
         info = -3
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -7
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZSPTRS', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 .OR. nrhs.EQ.0 )
     $   RETURN
*
      IF( upper ) THEN
*
*        Solve A*X = B, where A = U*D*U**T.
*
*        First solve U*D*X = B, overwriting B with X.
*
*        K is the main loop index, decreasing from N to 1 in steps of
*        1 or 2, depending on the size of the diagonal blocks.
*
         k = n
         kc = n*( n+1 ) / 2 + 1
   10    CONTINUE
*
*        If K < 1, exit from loop.
*
         IF( k.LT.1 )
     $      GO TO 30
*
         kc = kc - k
         IF( ipiv( k ).GT.0 ) THEN
*
*           1 x 1 diagonal block
*
*           Interchange rows K and IPIV(K).
*
            kp = ipiv( k )
            IF( kp.NE.k )
     $         CALL zswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
*
*           Multiply by inv(U(K)), where U(K) is the transformation
*           stored in column K of A.
*
            CALL zgeru( k-1, nrhs, -one, ap( kc ), 1, b( k, 1 ), ldb,
     $                  b( 1, 1 ), ldb )
*
*           Multiply by the inverse of the diagonal block.
*
            CALL zscal( nrhs, one / ap( kc+k-1 ), b( k, 1 ), ldb )
            k = k - 1
         ELSE
*
*           2 x 2 diagonal block
*
*           Interchange rows K-1 and -IPIV(K).
*
            kp = -ipiv( k )
            IF( kp.NE.k-1 )
     $         CALL zswap( nrhs, b( k-1, 1 ), ldb, b( kp, 1 ), ldb )
*
*           Multiply by inv(U(K)), where U(K) is the transformation
*           stored in columns K-1 and K of A.
*
            CALL zgeru( k-2, nrhs, -one, ap( kc ), 1, b( k, 1 ), ldb,
     $                  b( 1, 1 ), ldb )
            CALL zgeru( k-2, nrhs, -one, ap( kc-( k-1 ) ), 1,
     $                  b( k-1, 1 ), ldb, b( 1, 1 ), ldb )
*
*           Multiply by the inverse of the diagonal block.
*
            akm1k = ap( kc+k-2 )
            akm1 = ap( kc-1 ) / akm1k
            ak = ap( kc+k-1 ) / akm1k
            denom = akm1*ak - one
            DO 20 j = 1, nrhs
               bkm1 = b( k-1, j ) / akm1k
               bk = b( k, j ) / akm1k
               b( k-1, j ) = ( ak*bkm1-bk ) / denom
               b( k, j ) = ( akm1*bk-bkm1 ) / denom
   20       CONTINUE
            kc = kc - k + 1
            k = k - 2
         END IF
*
         GO TO 10
   30    CONTINUE
*
*        Next solve U**T*X = B, overwriting B with X.
*
*        K is the main loop index, increasing from 1 to N in steps of
*        1 or 2, depending on the size of the diagonal blocks.
*
         k = 1
         kc = 1
   40    CONTINUE
*
*        If K > N, exit from loop.
*
         IF( k.GT.n )
     $      GO TO 50
*
         IF( ipiv( k ).GT.0 ) THEN
*
*           1 x 1 diagonal block
*
*           Multiply by inv(U**T(K)), where U(K) is the transformation
*           stored in column K of A.
*
            CALL zgemv( 'Transpose', k-1, nrhs, -one, b, ldb, ap( kc ),
     $                  1, one, b( k, 1 ), ldb )
*
*           Interchange rows K and IPIV(K).
*
            kp = ipiv( k )
            IF( kp.NE.k )
     $         CALL zswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
            kc = kc + k
            k = k + 1
         ELSE
*
*           2 x 2 diagonal block
*
*           Multiply by inv(U**T(K+1)), where U(K+1) is the transformation
*           stored in columns K and K+1 of A.
*
            CALL zgemv( 'Transpose', k-1, nrhs, -one, b, ldb, ap( kc ),
     $                  1, one, b( k, 1 ), ldb )
            CALL zgemv( 'Transpose', k-1, nrhs, -one, b, ldb,
     $                  ap( kc+k ), 1, one, b( k+1, 1 ), ldb )
*
*           Interchange rows K and -IPIV(K).
*
            kp = -ipiv( k )
            IF( kp.NE.k )
     $         CALL zswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
            kc = kc + 2*k + 1
            k = k + 2
         END IF
*
         GO TO 40
   50    CONTINUE
*
      ELSE
*
*        Solve A*X = B, where A = L*D*L**T.
*
*        First solve L*D*X = B, overwriting B with X.
*
*        K is the main loop index, increasing from 1 to N in steps of
*        1 or 2, depending on the size of the diagonal blocks.
*
         k = 1
         kc = 1
   60    CONTINUE
*
*        If K > N, exit from loop.
*
         IF( k.GT.n )
     $      GO TO 80
*
         IF( ipiv( k ).GT.0 ) THEN
*
*           1 x 1 diagonal block
*
*           Interchange rows K and IPIV(K).
*
            kp = ipiv( k )
            IF( kp.NE.k )
     $         CALL zswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
*
*           Multiply by inv(L(K)), where L(K) is the transformation
*           stored in column K of A.
*
            IF( k.LT.n )
     $         CALL zgeru( n-k, nrhs, -one, ap( kc+1 ), 1, b( k, 1 ),
     $                     ldb, b( k+1, 1 ), ldb )
*
*           Multiply by the inverse of the diagonal block.
*
            CALL zscal( nrhs, one / ap( kc ), b( k, 1 ), ldb )
            kc = kc + n - k + 1
            k = k + 1
         ELSE
*
*           2 x 2 diagonal block
*
*           Interchange rows K+1 and -IPIV(K).
*
            kp = -ipiv( k )
            IF( kp.NE.k+1 )
     $         CALL zswap( nrhs, b( k+1, 1 ), ldb, b( kp, 1 ), ldb )
*
*           Multiply by inv(L(K)), where L(K) is the transformation
*           stored in columns K and K+1 of A.
*
            IF( k.LT.n-1 ) THEN
               CALL zgeru( n-k-1, nrhs, -one, ap( kc+2 ), 1, b( k, 1 ),
     $                     ldb, b( k+2, 1 ), ldb )
               CALL zgeru( n-k-1, nrhs, -one, ap( kc+n-k+2 ), 1,
     $                     b( k+1, 1 ), ldb, b( k+2, 1 ), ldb )
            END IF
*
*           Multiply by the inverse of the diagonal block.
*
            akm1k = ap( kc+1 )
            akm1 = ap( kc ) / akm1k
            ak = ap( kc+n-k+1 ) / akm1k
            denom = akm1*ak - one
            DO 70 j = 1, nrhs
               bkm1 = b( k, j ) / akm1k
               bk = b( k+1, j ) / akm1k
               b( k, j ) = ( ak*bkm1-bk ) / denom
               b( k+1, j ) = ( akm1*bk-bkm1 ) / denom
   70       CONTINUE
            kc = kc + 2*( n-k ) + 1
            k = k + 2
         END IF
*
         GO TO 60
   80    CONTINUE
*
*        Next solve L**T*X = B, overwriting B with X.
*
*        K is the main loop index, decreasing from N to 1 in steps of
*        1 or 2, depending on the size of the diagonal blocks.
*
         k = n
         kc = n*( n+1 ) / 2 + 1
   90    CONTINUE
*
*        If K < 1, exit from loop.
*
         IF( k.LT.1 )
     $      GO TO 100
*
         kc = kc - ( n-k+1 )
         IF( ipiv( k ).GT.0 ) THEN
*
*           1 x 1 diagonal block
*
*           Multiply by inv(L**T(K)), where L(K) is the transformation
*           stored in column K of A.
*
            IF( k.LT.n )
     $         CALL zgemv( 'Transpose', n-k, nrhs, -one, b( k+1, 1 ),
     $                     ldb, ap( kc+1 ), 1, one, b( k, 1 ), ldb )
*
*           Interchange rows K and IPIV(K).
*
            kp = ipiv( k )
            IF( kp.NE.k )
     $         CALL zswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
            k = k - 1
         ELSE
*
*           2 x 2 diagonal block
*
*           Multiply by inv(L**T(K-1)), where L(K-1) is the transformation
*           stored in columns K-1 and K of A.
*
            IF( k.LT.n ) THEN
               CALL zgemv( 'Transpose', n-k, nrhs, -one, b( k+1, 1 ),
     $                     ldb, ap( kc+1 ), 1, one, b( k, 1 ), ldb )
               CALL zgemv( 'Transpose', n-k, nrhs, -one, b( k+1, 1 ),
     $                     ldb, ap( kc-( n-k ) ), 1, one, b( k-1, 1 ),
     $                     ldb )
            END IF
*
*           Interchange rows K and -IPIV(K).
*
            kp = -ipiv( k )
            IF( kp.NE.k )
     $         CALL zswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
            kc = kc - ( n-k+2 )
            k = k - 2
         END IF
*
         GO TO 90
  100    CONTINUE
      END IF
*
      RETURN
*
*     End of ZSPTRS
*
      END