zlar2v()

subroutine zlar2v	(	integer	n,
		complex*16, dimension( * )	x,
		complex*16, dimension( * )	y,
		complex*16, dimension( * )	z,
		integer	incx,
		double precision, dimension( * )	c,
		complex*16, dimension( * )	s,
		integer	incc
	)

ZLAR2V applies a vector of plane rotations with real cosines and complex sines from both sides to a sequence of 2-by-2 symmetric/Hermitian matrices.

Download ZLAR2V + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZLAR2V applies a vector of complex plane rotations with real cosines
 from both sides to a sequence of 2-by-2 complex Hermitian matrices,
 defined by the elements of the vectors x, y and z. For i = 1,2,...,n

    (       x(i)  z(i) ) :=
    ( conjg(z(i)) y(i) )

      (  c(i) conjg(s(i)) ) (       x(i)  z(i) ) ( c(i) -conjg(s(i)) )
      ( -s(i)       c(i)  ) ( conjg(z(i)) y(i) ) ( s(i)        c(i)  )

Parameters

[in]	N	N is INTEGER The number of plane rotations to be applied.
[in,out]	X	X is COMPLEX*16 array, dimension (1+(N-1)*INCX) The vector x; the elements of x are assumed to be real.
[in,out]	Y	Y is COMPLEX*16 array, dimension (1+(N-1)*INCX) The vector y; the elements of y are assumed to be real.
[in,out]	Z	Z is COMPLEX*16 array, dimension (1+(N-1)*INCX) The vector z.
[in]	INCX	INCX is INTEGER The increment between elements of X, Y and Z. INCX > 0.
[in]	C	C is DOUBLE PRECISION array, dimension (1+(N-1)*INCC) The cosines of the plane rotations.
[in]	S	S is COMPLEX*16 array, dimension (1+(N-1)*INCC) The sines of the plane rotations.
[in]	INCC	INCC is INTEGER The increment between elements of C and S. INCC > 0.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 110 of file zlar2v.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INCC, INCX, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   C( * )
      COMPLEX*16         S( * ), X( * ), Y( * ), Z( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            I, IC, IX
      DOUBLE PRECISION   CI, SII, SIR, T1I, T1R, T5, T6, XI, YI, ZII,
     $                   ZIR
      COMPLEX*16         SI, T2, T3, T4, ZI
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dcmplx, dconjg, dimag
*     ..
*     .. Executable Statements ..
*
      ix = 1
      ic = 1
      DO 10 i = 1, n
         xi = dble( x( ix ) )
         yi = dble( y( ix ) )
         zi = z( ix )
         zir = dble( zi )
         zii = dimag( zi )
         ci = c( ic )
         si = s( ic )
         sir = dble( si )
         sii = dimag( si )
         t1r = sir*zir - sii*zii
         t1i = sir*zii + sii*zir
         t2 = ci*zi
         t3 = t2 - dconjg( si )*xi
         t4 = dconjg( t2 ) + si*yi
         t5 = ci*xi + t1r
         t6 = ci*yi - t1r
         x( ix ) = ci*t5 + ( sir*dble( t4 )+sii*dimag( t4 ) )
         y( ix ) = ci*t6 - ( sir*dble( t3 )-sii*dimag( t3 ) )
         z( ix ) = ci*t3 + dconjg( si )*dcmplx( t6, t1i )
         ix = ix + incx
         ic = ic + incc
   10 CONTINUE
      RETURN
*
*     End of ZLAR2V
*

Here is the caller graph for this function: