clar2v()

subroutine clar2v	(	integer	n,
		complex, dimension( * )	x,
		complex, dimension( * )	y,
		complex, dimension( * )	z,
		integer	incx,
		real, dimension( * )	c,
		complex, dimension( * )	s,
		integer	incc )

CLAR2V applies a vector of plane rotations with real cosines and complex sines from both sides to a sequence of 2-by-2 symmetric/Hermitian matrices.

Download CLAR2V + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CLAR2V applies a vector of complex plane rotations with real cosines
!> from both sides to a sequence of 2-by-2 complex Hermitian matrices,
!> defined by the elements of the vectors x, y and z. For i = 1,2,...,n
!>
!>    (       x(i)  z(i) ) :=
!>    ( conjg(z(i)) y(i) )
!>
!>      (  c(i) conjg(s(i)) ) (       x(i)  z(i) ) ( c(i) -conjg(s(i)) )
!>      ( -s(i)       c(i)  ) ( conjg(z(i)) y(i) ) ( s(i)        c(i)  )
!> 

Parameters

[in]	N	!> N is INTEGER !> The number of plane rotations to be applied. !>
[in,out]	X	!> X is COMPLEX array, dimension (1+(N-1)*INCX) !> The vector x; the elements of x are assumed to be real. !>
[in,out]	Y	!> Y is COMPLEX array, dimension (1+(N-1)*INCX) !> The vector y; the elements of y are assumed to be real. !>
[in,out]	Z	!> Z is COMPLEX array, dimension (1+(N-1)*INCX) !> The vector z. !>
[in]	INCX	!> INCX is INTEGER !> The increment between elements of X, Y and Z. INCX > 0. !>
[in]	C	!> C is REAL array, dimension (1+(N-1)*INCC) !> The cosines of the plane rotations. !>
[in]	S	!> S is COMPLEX array, dimension (1+(N-1)*INCC) !> The sines of the plane rotations. !>
[in]	INCC	!> INCC is INTEGER !> The increment between elements of C and S. INCC > 0. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 108 of file clar2v.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INCC, INCX, N
*     ..
*     .. Array Arguments ..
      REAL               C( * )
      COMPLEX            S( * ), X( * ), Y( * ), Z( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            I, IC, IX
      REAL               CI, SII, SIR, T1I, T1R, T5, T6, XI, YI, ZII,
     $                   ZIR
      COMPLEX            SI, T2, T3, T4, ZI
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          aimag, cmplx, conjg, real
*     ..
*     .. Executable Statements ..
*
      ix = 1
      ic = 1
      DO 10 i = 1, n
         xi = real( x( ix ) )
         yi = real( y( ix ) )
         zi = z( ix )
         zir = real( zi )
         zii = aimag( zi )
         ci = c( ic )
         si = s( ic )
         sir = real( si )
         sii = aimag( si )
         t1r = sir*zir - sii*zii
         t1i = sir*zii + sii*zir
         t2 = ci*zi
         t3 = t2 - conjg( si )*xi
         t4 = conjg( t2 ) + si*yi
         t5 = ci*xi + t1r
         t6 = ci*yi - t1r
         x( ix ) = ci*t5 + ( sir*real( t4 )+sii*aimag( t4 ) )
         y( ix ) = ci*t6 - ( sir*real( t3 )-sii*aimag( t3 ) )
         z( ix ) = ci*t3 + conjg( si )*cmplx( t6, t1i )
         ix = ix + incx
         ic = ic + incc
   10 CONTINUE
      RETURN
*
*     End of CLAR2V
*

Here is the caller graph for this function: