LAPACK 3.11.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches

## ◆ dlassq()

 subroutine dlassq ( integer n, real(wp), dimension(*) x, integer incx, real(wp) scl, real(wp) sumsq )

DLASSQ updates a sum of squares represented in scaled form.

Purpose:
``` DLASSQ  returns the values  scl  and  smsq  such that

( scl**2 )*smsq = x( 1 )**2 +...+ x( n )**2 + ( scale**2 )*sumsq,

where  x( i ) = X( 1 + ( i - 1 )*INCX ). The value of  sumsq  is
assumed to be non-negative.

scale and sumsq must be supplied in SCALE and SUMSQ and
scl and smsq are overwritten on SCALE and SUMSQ respectively.

If scale * sqrt( sumsq ) > tbig then
we require:   scale >= sqrt( TINY*EPS ) / sbig   on entry,
and if 0 < scale * sqrt( sumsq ) < tsml then
we require:   scale <= sqrt( HUGE ) / ssml       on entry,
where
tbig -- upper threshold for values whose square is representable;
sbig -- scaling constant for big numbers; \see la_constants.f90
tsml -- lower threshold for values whose square is representable;
ssml -- scaling constant for small numbers; \see la_constants.f90
and
TINY*EPS -- tiniest representable number;
HUGE     -- biggest representable number.```
Parameters
 [in] N ``` N is INTEGER The number of elements to be used from the vector x.``` [in] X ``` X is DOUBLE PRECISION array, dimension (1+(N-1)*abs(INCX)) The vector for which a scaled sum of squares is computed. x( i ) = X( 1 + ( i - 1 )*INCX ), 1 <= i <= n.``` [in] INCX ``` INCX is INTEGER The increment between successive values of the vector x. If INCX > 0, X(1+(i-1)*INCX) = x(i) for 1 <= i <= n If INCX < 0, X(1-(n-i)*INCX) = x(i) for 1 <= i <= n If INCX = 0, x isn't a vector so there is no need to call this subroutine. If you call it anyway, it will count x(1) in the vector norm N times.``` [in,out] SCALE ``` SCALE is DOUBLE PRECISION On entry, the value scale in the equation above. On exit, SCALE is overwritten with scl , the scaling factor for the sum of squares.``` [in,out] SUMSQ ``` SUMSQ is DOUBLE PRECISION On entry, the value sumsq in the equation above. On exit, SUMSQ is overwritten with smsq , the basic sum of squares from which scl has been factored out.```
Contributors:
Weslley Pereira, University of Colorado Denver, USA Nick Papior, Technical University of Denmark, DK
Further Details:
```  Anderson E. (2017)
Algorithm 978: Safe Scaling in the Level 1 BLAS
ACM Trans Math Softw 44:1--28
https://doi.org/10.1145/3061665

Blue, James L. (1978)
A Portable Fortran Program to Find the Euclidean Norm of a Vector
ACM Trans Math Softw 4:15--23
https://doi.org/10.1145/355769.355771```

Definition at line 136 of file dlassq.f90.

137 use la_constants, &
138 only: wp=>dp, zero=>dzero, one=>done, &
139 sbig=>dsbig, ssml=>dssml, tbig=>dtbig, tsml=>dtsml
140 use la_xisnan
141!
142! -- LAPACK auxiliary routine --
143! -- LAPACK is a software package provided by Univ. of Tennessee, --
144! -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
145!
146! .. Scalar Arguments ..
147 integer :: incx, n
148 real(wp) :: scl, sumsq
149! ..
150! .. Array Arguments ..
151 real(wp) :: x(*)
152! ..
153! .. Local Scalars ..
154 integer :: i, ix
155 logical :: notbig
156 real(wp) :: abig, amed, asml, ax, ymax, ymin
157! ..
158!
159! Quick return if possible
160!
161 if( la_isnan(scl) .or. la_isnan(sumsq) ) return
162 if( sumsq == zero ) scl = one
163 if( scl == zero ) then
164 scl = one
165 sumsq = zero
166 end if
167 if (n <= 0) then
168 return
169 end if
170!
171! Compute the sum of squares in 3 accumulators:
172! abig -- sums of squares scaled down to avoid overflow
173! asml -- sums of squares scaled up to avoid underflow
174! amed -- sums of squares that do not require scaling
175! The thresholds and multipliers are
176! tbig -- values bigger than this are scaled down by sbig
177! tsml -- values smaller than this are scaled up by ssml
178!
179 notbig = .true.
180 asml = zero
181 amed = zero
182 abig = zero
183 ix = 1
184 if( incx < 0 ) ix = 1 - (n-1)*incx
185 do i = 1, n
186 ax = abs(x(ix))
187 if (ax > tbig) then
188 abig = abig + (ax*sbig)**2
189 notbig = .false.
190 else if (ax < tsml) then
191 if (notbig) asml = asml + (ax*ssml)**2
192 else
193 amed = amed + ax**2
194 end if
195 ix = ix + incx
196 end do
197!
198! Put the existing sum of squares into one of the accumulators
199!
200 if( sumsq > zero ) then
201 ax = scl*sqrt( sumsq )
202 if (ax > tbig) then
203! We assume scl >= sqrt( TINY*EPS ) / sbig
204 abig = abig + (scl*sbig)**2 * sumsq
205 else if (ax < tsml) then
206! We assume scl <= sqrt( HUGE ) / ssml
207 if (notbig) asml = asml + (scl*ssml)**2 * sumsq
208 else
209 amed = amed + scl**2 * sumsq
210 end if
211 end if
212!
213! Combine abig and amed or amed and asml if more than one
214! accumulator was used.
215!
216 if (abig > zero) then
217!
218! Combine abig and amed if abig > 0.
219!
220 if (amed > zero .or. la_isnan(amed)) then
221 abig = abig + (amed*sbig)*sbig
222 end if
223 scl = one / sbig
224 sumsq = abig
225 else if (asml > zero) then
226!
227! Combine amed and asml if asml > 0.
228!
229 if (amed > zero .or. la_isnan(amed)) then
230 amed = sqrt(amed)
231 asml = sqrt(asml) / ssml
232 if (asml > amed) then
233 ymin = amed
234 ymax = asml
235 else
236 ymin = asml
237 ymax = amed
238 end if
239 scl = one
240 sumsq = ymax**2*( one + (ymin/ymax)**2 )
241 else
242 scl = one / ssml
243 sumsq = asml
244 end if
245 else
246!
247! Otherwise all values are mid-range or zero
248!
249 scl = one
250 sumsq = amed
251 end if
252 return
real(dp), parameter dtsml
real(dp), parameter dzero
real(dp), parameter dsbig
integer, parameter dp
real(dp), parameter done
real(dp), parameter dtbig
real(dp), parameter dssml
LA_CONSTANTS is a module for the scaling constants for the compiled Fortran single and double precisi...
Here is the caller graph for this function: