LAPACK 3.11.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ dlanst()

double precision function dlanst ( character  NORM,
integer  N,
double precision, dimension( * )  D,
double precision, dimension( * )  E 
)

DLANST returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a real symmetric tridiagonal matrix.

Download DLANST + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 DLANST  returns the value of the one norm,  or the Frobenius norm, or
 the  infinity norm,  or the  element of  largest absolute value  of a
 real symmetric tridiagonal matrix A.
Returns
DLANST
    DLANST = ( max(abs(A(i,j))), NORM = 'M' or 'm'
             (
             ( norm1(A),         NORM = '1', 'O' or 'o'
             (
             ( normI(A),         NORM = 'I' or 'i'
             (
             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'

 where  norm1  denotes the  one norm of a matrix (maximum column sum),
 normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
 normF  denotes the  Frobenius norm of a matrix (square root of sum of
 squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
Parameters
[in]NORM
          NORM is CHARACTER*1
          Specifies the value to be returned in DLANST as described
          above.
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.  When N = 0, DLANST is
          set to zero.
[in]D
          D is DOUBLE PRECISION array, dimension (N)
          The diagonal elements of A.
[in]E
          E is DOUBLE PRECISION array, dimension (N-1)
          The (n-1) sub-diagonal or super-diagonal elements of A.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 99 of file dlanst.f.

100*
101* -- LAPACK auxiliary routine --
102* -- LAPACK is a software package provided by Univ. of Tennessee, --
103* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
104*
105* .. Scalar Arguments ..
106 CHARACTER NORM
107 INTEGER N
108* ..
109* .. Array Arguments ..
110 DOUBLE PRECISION D( * ), E( * )
111* ..
112*
113* =====================================================================
114*
115* .. Parameters ..
116 DOUBLE PRECISION ONE, ZERO
117 parameter( one = 1.0d+0, zero = 0.0d+0 )
118* ..
119* .. Local Scalars ..
120 INTEGER I
121 DOUBLE PRECISION ANORM, SCALE, SUM
122* ..
123* .. External Functions ..
124 LOGICAL LSAME, DISNAN
125 EXTERNAL lsame, disnan
126* ..
127* .. External Subroutines ..
128 EXTERNAL dlassq
129* ..
130* .. Intrinsic Functions ..
131 INTRINSIC abs, sqrt
132* ..
133* .. Executable Statements ..
134*
135 IF( n.LE.0 ) THEN
136 anorm = zero
137 ELSE IF( lsame( norm, 'M' ) ) THEN
138*
139* Find max(abs(A(i,j))).
140*
141 anorm = abs( d( n ) )
142 DO 10 i = 1, n - 1
143 sum = abs( d( i ) )
144 IF( anorm .LT. sum .OR. disnan( sum ) ) anorm = sum
145 sum = abs( e( i ) )
146 IF( anorm .LT. sum .OR. disnan( sum ) ) anorm = sum
147 10 CONTINUE
148 ELSE IF( lsame( norm, 'O' ) .OR. norm.EQ.'1' .OR.
149 $ lsame( norm, 'I' ) ) THEN
150*
151* Find norm1(A).
152*
153 IF( n.EQ.1 ) THEN
154 anorm = abs( d( 1 ) )
155 ELSE
156 anorm = abs( d( 1 ) )+abs( e( 1 ) )
157 sum = abs( e( n-1 ) )+abs( d( n ) )
158 IF( anorm .LT. sum .OR. disnan( sum ) ) anorm = sum
159 DO 20 i = 2, n - 1
160 sum = abs( d( i ) )+abs( e( i ) )+abs( e( i-1 ) )
161 IF( anorm .LT. sum .OR. disnan( sum ) ) anorm = sum
162 20 CONTINUE
163 END IF
164 ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
165*
166* Find normF(A).
167*
168 scale = zero
169 sum = one
170 IF( n.GT.1 ) THEN
171 CALL dlassq( n-1, e, 1, scale, sum )
172 sum = 2*sum
173 END IF
174 CALL dlassq( n, d, 1, scale, sum )
175 anorm = scale*sqrt( sum )
176 END IF
177*
178 dlanst = anorm
179 RETURN
180*
181* End of DLANST
182*
logical function disnan(DIN)
DISNAN tests input for NaN.
Definition: disnan.f:59
double precision function dlanst(NORM, N, D, E)
DLANST returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition: dlanst.f:100
subroutine dlassq(n, x, incx, scl, sumsq)
DLASSQ updates a sum of squares represented in scaled form.
Definition: dlassq.f90:137
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
Here is the call graph for this function:
Here is the caller graph for this function: