 LAPACK  3.10.1 LAPACK: Linear Algebra PACKage

## ◆ dlasd6()

 subroutine dlasd6 ( integer ICOMPQ, integer NL, integer NR, integer SQRE, double precision, dimension( * ) D, double precision, dimension( * ) VF, double precision, dimension( * ) VL, double precision ALPHA, double precision BETA, integer, dimension( * ) IDXQ, integer, dimension( * ) PERM, integer GIVPTR, integer, dimension( ldgcol, * ) GIVCOL, integer LDGCOL, double precision, dimension( ldgnum, * ) GIVNUM, integer LDGNUM, double precision, dimension( ldgnum, * ) POLES, double precision, dimension( * ) DIFL, double precision, dimension( * ) DIFR, double precision, dimension( * ) Z, integer K, double precision C, double precision S, double precision, dimension( * ) WORK, integer, dimension( * ) IWORK, integer INFO )

DLASD6 computes the SVD of an updated upper bidiagonal matrix obtained by merging two smaller ones by appending a row. Used by sbdsdc.

Download DLASD6 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
``` DLASD6 computes the SVD of an updated upper bidiagonal matrix B
obtained by merging two smaller ones by appending a row. This
routine is used only for the problem which requires all singular
values and optionally singular vector matrices in factored form.
B is an N-by-M matrix with N = NL + NR + 1 and M = N + SQRE.
A related subroutine, DLASD1, handles the case in which all singular
values and singular vectors of the bidiagonal matrix are desired.

DLASD6 computes the SVD as follows:

( D1(in)    0    0       0 )
B = U(in) * (   Z1**T   a   Z2**T    b ) * VT(in)
(   0       0   D2(in)   0 )

= U(out) * ( D(out) 0) * VT(out)

where Z**T = (Z1**T a Z2**T b) = u**T VT**T, and u is a vector of dimension M
with ALPHA and BETA in the NL+1 and NL+2 th entries and zeros
elsewhere; and the entry b is empty if SQRE = 0.

The singular values of B can be computed using D1, D2, the first
components of all the right singular vectors of the lower block, and
the last components of all the right singular vectors of the upper
block. These components are stored and updated in VF and VL,
respectively, in DLASD6. Hence U and VT are not explicitly
referenced.

The singular values are stored in D. The algorithm consists of two
stages:

The first stage consists of deflating the size of the problem
when there are multiple singular values or if there is a zero
in the Z vector. For each such occurrence the dimension of the
secular equation problem is reduced by one. This stage is
performed by the routine DLASD7.

The second stage consists of calculating the updated
singular values. This is done by finding the roots of the
secular equation via the routine DLASD4 (as called by DLASD8).
This routine also updates VF and VL and computes the distances
between the updated singular values and the old singular
values.

DLASD6 is called from DLASDA.```
Parameters
 [in] ICOMPQ ``` ICOMPQ is INTEGER Specifies whether singular vectors are to be computed in factored form: = 0: Compute singular values only. = 1: Compute singular vectors in factored form as well.``` [in] NL ``` NL is INTEGER The row dimension of the upper block. NL >= 1.``` [in] NR ``` NR is INTEGER The row dimension of the lower block. NR >= 1.``` [in] SQRE ``` SQRE is INTEGER = 0: the lower block is an NR-by-NR square matrix. = 1: the lower block is an NR-by-(NR+1) rectangular matrix. The bidiagonal matrix has row dimension N = NL + NR + 1, and column dimension M = N + SQRE.``` [in,out] D ``` D is DOUBLE PRECISION array, dimension ( NL+NR+1 ). On entry D(1:NL,1:NL) contains the singular values of the upper block, and D(NL+2:N) contains the singular values of the lower block. On exit D(1:N) contains the singular values of the modified matrix.``` [in,out] VF ``` VF is DOUBLE PRECISION array, dimension ( M ) On entry, VF(1:NL+1) contains the first components of all right singular vectors of the upper block; and VF(NL+2:M) contains the first components of all right singular vectors of the lower block. On exit, VF contains the first components of all right singular vectors of the bidiagonal matrix.``` [in,out] VL ``` VL is DOUBLE PRECISION array, dimension ( M ) On entry, VL(1:NL+1) contains the last components of all right singular vectors of the upper block; and VL(NL+2:M) contains the last components of all right singular vectors of the lower block. On exit, VL contains the last components of all right singular vectors of the bidiagonal matrix.``` [in,out] ALPHA ``` ALPHA is DOUBLE PRECISION Contains the diagonal element associated with the added row.``` [in,out] BETA ``` BETA is DOUBLE PRECISION Contains the off-diagonal element associated with the added row.``` [in,out] IDXQ ``` IDXQ is INTEGER array, dimension ( N ) This contains the permutation which will reintegrate the subproblem just solved back into sorted order, i.e. D( IDXQ( I = 1, N ) ) will be in ascending order.``` [out] PERM ``` PERM is INTEGER array, dimension ( N ) The permutations (from deflation and sorting) to be applied to each block. Not referenced if ICOMPQ = 0.``` [out] GIVPTR ``` GIVPTR is INTEGER The number of Givens rotations which took place in this subproblem. Not referenced if ICOMPQ = 0.``` [out] GIVCOL ``` GIVCOL is INTEGER array, dimension ( LDGCOL, 2 ) Each pair of numbers indicates a pair of columns to take place in a Givens rotation. Not referenced if ICOMPQ = 0.``` [in] LDGCOL ``` LDGCOL is INTEGER leading dimension of GIVCOL, must be at least N.``` [out] GIVNUM ``` GIVNUM is DOUBLE PRECISION array, dimension ( LDGNUM, 2 ) Each number indicates the C or S value to be used in the corresponding Givens rotation. Not referenced if ICOMPQ = 0.``` [in] LDGNUM ``` LDGNUM is INTEGER The leading dimension of GIVNUM and POLES, must be at least N.``` [out] POLES ``` POLES is DOUBLE PRECISION array, dimension ( LDGNUM, 2 ) On exit, POLES(1,*) is an array containing the new singular values obtained from solving the secular equation, and POLES(2,*) is an array containing the poles in the secular equation. Not referenced if ICOMPQ = 0.``` [out] DIFL ``` DIFL is DOUBLE PRECISION array, dimension ( N ) On exit, DIFL(I) is the distance between I-th updated (undeflated) singular value and the I-th (undeflated) old singular value.``` [out] DIFR ``` DIFR is DOUBLE PRECISION array, dimension ( LDDIFR, 2 ) if ICOMPQ = 1 and dimension ( K ) if ICOMPQ = 0. On exit, DIFR(I,1) = D(I) - DSIGMA(I+1), DIFR(K,1) is not defined and will not be referenced. If ICOMPQ = 1, DIFR(1:K,2) is an array containing the normalizing factors for the right singular vector matrix. See DLASD8 for details on DIFL and DIFR.``` [out] Z ``` Z is DOUBLE PRECISION array, dimension ( M ) The first elements of this array contain the components of the deflation-adjusted updating row vector.``` [out] K ``` K is INTEGER Contains the dimension of the non-deflated matrix, This is the order of the related secular equation. 1 <= K <=N.``` [out] C ``` C is DOUBLE PRECISION C contains garbage if SQRE =0 and the C-value of a Givens rotation related to the right null space if SQRE = 1.``` [out] S ``` S is DOUBLE PRECISION S contains garbage if SQRE =0 and the S-value of a Givens rotation related to the right null space if SQRE = 1.``` [out] WORK ` WORK is DOUBLE PRECISION array, dimension ( 4 * M )` [out] IWORK ` IWORK is INTEGER array, dimension ( 3 * N )` [out] INFO ``` INFO is INTEGER = 0: successful exit. < 0: if INFO = -i, the i-th argument had an illegal value. > 0: if INFO = 1, a singular value did not converge```
Contributors:
Ming Gu and Huan Ren, Computer Science Division, University of California at Berkeley, USA

Definition at line 309 of file dlasd6.f.

313 *
314 * -- LAPACK auxiliary routine --
315 * -- LAPACK is a software package provided by Univ. of Tennessee, --
316 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
317 *
318 * .. Scalar Arguments ..
319  INTEGER GIVPTR, ICOMPQ, INFO, K, LDGCOL, LDGNUM, NL,
320  \$ NR, SQRE
321  DOUBLE PRECISION ALPHA, BETA, C, S
322 * ..
323 * .. Array Arguments ..
324  INTEGER GIVCOL( LDGCOL, * ), IDXQ( * ), IWORK( * ),
325  \$ PERM( * )
326  DOUBLE PRECISION D( * ), DIFL( * ), DIFR( * ),
327  \$ GIVNUM( LDGNUM, * ), POLES( LDGNUM, * ),
328  \$ VF( * ), VL( * ), WORK( * ), Z( * )
329 * ..
330 *
331 * =====================================================================
332 *
333 * .. Parameters ..
334  DOUBLE PRECISION ONE, ZERO
335  parameter( one = 1.0d+0, zero = 0.0d+0 )
336 * ..
337 * .. Local Scalars ..
338  INTEGER I, IDX, IDXC, IDXP, ISIGMA, IVFW, IVLW, IW, M,
339  \$ N, N1, N2
340  DOUBLE PRECISION ORGNRM
341 * ..
342 * .. External Subroutines ..
343  EXTERNAL dcopy, dlamrg, dlascl, dlasd7, dlasd8, xerbla
344 * ..
345 * .. Intrinsic Functions ..
346  INTRINSIC abs, max
347 * ..
348 * .. Executable Statements ..
349 *
350 * Test the input parameters.
351 *
352  info = 0
353  n = nl + nr + 1
354  m = n + sqre
355 *
356  IF( ( icompq.LT.0 ) .OR. ( icompq.GT.1 ) ) THEN
357  info = -1
358  ELSE IF( nl.LT.1 ) THEN
359  info = -2
360  ELSE IF( nr.LT.1 ) THEN
361  info = -3
362  ELSE IF( ( sqre.LT.0 ) .OR. ( sqre.GT.1 ) ) THEN
363  info = -4
364  ELSE IF( ldgcol.LT.n ) THEN
365  info = -14
366  ELSE IF( ldgnum.LT.n ) THEN
367  info = -16
368  END IF
369  IF( info.NE.0 ) THEN
370  CALL xerbla( 'DLASD6', -info )
371  RETURN
372  END IF
373 *
374 * The following values are for bookkeeping purposes only. They are
375 * integer pointers which indicate the portion of the workspace
376 * used by a particular array in DLASD7 and DLASD8.
377 *
378  isigma = 1
379  iw = isigma + n
380  ivfw = iw + m
381  ivlw = ivfw + m
382 *
383  idx = 1
384  idxc = idx + n
385  idxp = idxc + n
386 *
387 * Scale.
388 *
389  orgnrm = max( abs( alpha ), abs( beta ) )
390  d( nl+1 ) = zero
391  DO 10 i = 1, n
392  IF( abs( d( i ) ).GT.orgnrm ) THEN
393  orgnrm = abs( d( i ) )
394  END IF
395  10 CONTINUE
396  CALL dlascl( 'G', 0, 0, orgnrm, one, n, 1, d, n, info )
397  alpha = alpha / orgnrm
398  beta = beta / orgnrm
399 *
400 * Sort and Deflate singular values.
401 *
402  CALL dlasd7( icompq, nl, nr, sqre, k, d, z, work( iw ), vf,
403  \$ work( ivfw ), vl, work( ivlw ), alpha, beta,
404  \$ work( isigma ), iwork( idx ), iwork( idxp ), idxq,
405  \$ perm, givptr, givcol, ldgcol, givnum, ldgnum, c, s,
406  \$ info )
407 *
408 * Solve Secular Equation, compute DIFL, DIFR, and update VF, VL.
409 *
410  CALL dlasd8( icompq, k, d, z, vf, vl, difl, difr, ldgnum,
411  \$ work( isigma ), work( iw ), info )
412 *
413 * Report the possible convergence failure.
414 *
415  IF( info.NE.0 ) THEN
416  RETURN
417  END IF
418 *
419 * Save the poles if ICOMPQ = 1.
420 *
421  IF( icompq.EQ.1 ) THEN
422  CALL dcopy( k, d, 1, poles( 1, 1 ), 1 )
423  CALL dcopy( k, work( isigma ), 1, poles( 1, 2 ), 1 )
424  END IF
425 *
426 * Unscale.
427 *
428  CALL dlascl( 'G', 0, 0, one, orgnrm, n, 1, d, n, info )
429 *
430 * Prepare the IDXQ sorting permutation.
431 *
432  n1 = k
433  n2 = n - k
434  CALL dlamrg( n1, n2, d, 1, -1, idxq )
435 *
436  RETURN
437 *
438 * End of DLASD6
439 *
subroutine dlasd7(ICOMPQ, NL, NR, SQRE, K, D, Z, ZW, VF, VFW, VL, VLW, ALPHA, BETA, DSIGMA, IDX, IDXP, IDXQ, PERM, GIVPTR, GIVCOL, LDGCOL, GIVNUM, LDGNUM, C, S, INFO)
DLASD7 merges the two sets of singular values together into a single sorted set. Then it tries to def...
Definition: dlasd7.f:280
subroutine dlascl(TYPE, KL, KU, CFROM, CTO, M, N, A, LDA, INFO)
DLASCL multiplies a general rectangular matrix by a real scalar defined as cto/cfrom.
Definition: dlascl.f:143
subroutine dlasd8(ICOMPQ, K, D, Z, VF, VL, DIFL, DIFR, LDDIFR, DSIGMA, WORK, INFO)
DLASD8 finds the square roots of the roots of the secular equation, and stores, for each element in D...
Definition: dlasd8.f:166
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine dlamrg(N1, N2, A, DTRD1, DTRD2, INDEX)
DLAMRG creates a permutation list to merge the entries of two independently sorted sets into a single...
Definition: dlamrg.f:99
subroutine dcopy(N, DX, INCX, DY, INCY)
DCOPY
Definition: dcopy.f:82
Here is the call graph for this function:
Here is the caller graph for this function: