LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ sorhr_col()

subroutine sorhr_col ( integer m,
integer n,
integer nb,
real, dimension( lda, * ) a,
integer lda,
real, dimension( ldt, * ) t,
integer ldt,
real, dimension( * ) d,
integer info )

SORHR_COL

Download SORHR_COL + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!>  SORHR_COL takes an M-by-N real matrix Q_in with orthonormal columns
!>  as input, stored in A, and performs Householder Reconstruction (HR),
!>  i.e. reconstructs Householder vectors V(i) implicitly representing
!>  another M-by-N matrix Q_out, with the property that Q_in = Q_out*S,
!>  where S is an N-by-N diagonal matrix with diagonal entries
!>  equal to +1 or -1. The Householder vectors (columns V(i) of V) are
!>  stored in A on output, and the diagonal entries of S are stored in D.
!>  Block reflectors are also returned in T
!>  (same output format as SGEQRT).
!>
Parameters
[in]M
!>          M is INTEGER
!>          The number of rows of the matrix A. M >= 0.
!>
[in]N
!>          N is INTEGER
!>          The number of columns of the matrix A. M >= N >= 0.
!>
[in]NB
!>          NB is INTEGER
!>          The column block size to be used in the reconstruction
!>          of Householder column vector blocks in the array A and
!>          corresponding block reflectors in the array T. NB >= 1.
!>          (Note that if NB > N, then N is used instead of NB
!>          as the column block size.)
!>
[in,out]A
!>          A is REAL array, dimension (LDA,N)
!>
!>          On entry:
!>
!>             The array A contains an M-by-N orthonormal matrix Q_in,
!>             i.e the columns of A are orthogonal unit vectors.
!>
!>          On exit:
!>
!>             The elements below the diagonal of A represent the unit
!>             lower-trapezoidal matrix V of Householder column vectors
!>             V(i). The unit diagonal entries of V are not stored
!>             (same format as the output below the diagonal in A from
!>             SGEQRT). The matrix T and the matrix V stored on output
!>             in A implicitly define Q_out.
!>
!>             The elements above the diagonal contain the factor U
!>             of the  LU-decomposition:
!>                Q_in - ( S ) = V * U
!>                       ( 0 )
!>             where 0 is a (M-N)-by-(M-N) zero matrix.
!>
[in]LDA
!>          LDA is INTEGER
!>          The leading dimension of the array A.  LDA >= max(1,M).
!>
[out]T
!>          T is REAL array,
!>          dimension (LDT, N)
!>
!>          Let NOCB = Number_of_output_col_blocks
!>                   = CEIL(N/NB)
!>
!>          On exit, T(1:NB, 1:N) contains NOCB upper-triangular
!>          block reflectors used to define Q_out stored in compact
!>          form as a sequence of upper-triangular NB-by-NB column
!>          blocks (same format as the output T in SGEQRT).
!>          The matrix T and the matrix V stored on output in A
!>          implicitly define Q_out. NOTE: The lower triangles
!>          below the upper-triangular blocks will be filled with
!>          zeros. See Further Details.
!>
[in]LDT
!>          LDT is INTEGER
!>          The leading dimension of the array T.
!>          LDT >= max(1,min(NB,N)).
!>
[out]D
!>          D is REAL array, dimension min(M,N).
!>          The elements can be only plus or minus one.
!>
!>          D(i) is constructed as D(i) = -SIGN(Q_in_i(i,i)), where
!>          1 <= i <= min(M,N), and Q_in_i is Q_in after performing
!>          i-1 steps of “modified” Gaussian elimination.
!>          See Further Details.
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0:  successful exit
!>          < 0:  if INFO = -i, the i-th argument had an illegal value
!>
Further Details:
!>
!> The computed M-by-M orthogonal factor Q_out is defined implicitly as
!> a product of orthogonal matrices Q_out(i). Each Q_out(i) is stored in
!> the compact WY-representation format in the corresponding blocks of
!> matrices V (stored in A) and T.
!>
!> The M-by-N unit lower-trapezoidal matrix V stored in the M-by-N
!> matrix A contains the column vectors V(i) in NB-size column
!> blocks VB(j). For example, VB(1) contains the columns
!> V(1), V(2), ... V(NB). NOTE: The unit entries on
!> the diagonal of Y are not stored in A.
!>
!> The number of column blocks is
!>
!>     NOCB = Number_of_output_col_blocks = CEIL(N/NB)
!>
!> where each block is of order NB except for the last block, which
!> is of order LAST_NB = N - (NOCB-1)*NB.
!>
!> For example, if M=6,  N=5 and NB=2, the matrix V is
!>
!>
!>     V = (    VB(1),   VB(2), VB(3) ) =
!>
!>       = (   1                      )
!>         ( v21    1                 )
!>         ( v31  v32    1            )
!>         ( v41  v42  v43   1        )
!>         ( v51  v52  v53  v54    1  )
!>         ( v61  v62  v63  v54   v65 )
!>
!>
!> For each of the column blocks VB(i), an upper-triangular block
!> reflector TB(i) is computed. These blocks are stored as
!> a sequence of upper-triangular column blocks in the NB-by-N
!> matrix T. The size of each TB(i) block is NB-by-NB, except
!> for the last block, whose size is LAST_NB-by-LAST_NB.
!>
!> For example, if M=6,  N=5 and NB=2, the matrix T is
!>
!>     T  = (    TB(1),    TB(2), TB(3) ) =
!>
!>        = ( t11  t12  t13  t14   t15  )
!>          (      t22       t24        )
!>
!>
!> The M-by-M factor Q_out is given as a product of NOCB
!> orthogonal M-by-M matrices Q_out(i).
!>
!>     Q_out = Q_out(1) * Q_out(2) * ... * Q_out(NOCB),
!>
!> where each matrix Q_out(i) is given by the WY-representation
!> using corresponding blocks from the matrices V and T:
!>
!>     Q_out(i) = I - VB(i) * TB(i) * (VB(i))**T,
!>
!> where I is the identity matrix. Here is the formula with matrix
!> dimensions:
!>
!>  Q(i){M-by-M} = I{M-by-M} -
!>    VB(i){M-by-INB} * TB(i){INB-by-INB} * (VB(i))**T {INB-by-M},
!>
!> where INB = NB, except for the last block NOCB
!> for which INB=LAST_NB.
!>
!> =====
!> NOTE:
!> =====
!>
!> If Q_in is the result of doing a QR factorization
!> B = Q_in * R_in, then:
!>
!> B = (Q_out*S) * R_in = Q_out * (S * R_in) = Q_out * R_out.
!>
!> So if one wants to interpret Q_out as the result
!> of the QR factorization of B, then the corresponding R_out
!> should be equal to R_out = S * R_in, i.e. some rows of R_in
!> should be multiplied by -1.
!>
!> For the details of the algorithm, see [1].
!>
!> [1] ,
!>     G. Ballard, J. Demmel, L. Grigori, M. Jacquelin, H.D. Nguyen,
!>     E. Solomonik, J. Parallel Distrib. Comput.,
!>     vol. 85, pp. 3-31, 2015.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Contributors:
!>
!> November   2019, Igor Kozachenko,
!>            Computer Science Division,
!>            University of California, Berkeley
!>
!>

Definition at line 256 of file sorhr_col.f.

257 IMPLICIT NONE
258*
259* -- LAPACK computational routine --
260* -- LAPACK is a software package provided by Univ. of Tennessee, --
261* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
262*
263* .. Scalar Arguments ..
264 INTEGER INFO, LDA, LDT, M, N, NB
265* ..
266* .. Array Arguments ..
267 REAL A( LDA, * ), D( * ), T( LDT, * )
268* ..
269*
270* =====================================================================
271*
272* .. Parameters ..
273 REAL ONE, ZERO
274 parameter( one = 1.0e+0, zero = 0.0e+0 )
275* ..
276* .. Local Scalars ..
277 INTEGER I, IINFO, J, JB, JBTEMP1, JBTEMP2, JNB,
278 $ NPLUSONE
279* ..
280* .. External Subroutines ..
281 EXTERNAL scopy, slaorhr_col_getrfnp, sscal,
282 $ strsm,
283 $ xerbla
284* ..
285* .. Intrinsic Functions ..
286 INTRINSIC max, min
287* ..
288* .. Executable Statements ..
289*
290* Test the input parameters
291*
292 info = 0
293 IF( m.LT.0 ) THEN
294 info = -1
295 ELSE IF( n.LT.0 .OR. n.GT.m ) THEN
296 info = -2
297 ELSE IF( nb.LT.1 ) THEN
298 info = -3
299 ELSE IF( lda.LT.max( 1, m ) ) THEN
300 info = -5
301 ELSE IF( ldt.LT.max( 1, min( nb, n ) ) ) THEN
302 info = -7
303 END IF
304*
305* Handle error in the input parameters.
306*
307 IF( info.NE.0 ) THEN
308 CALL xerbla( 'SORHR_COL', -info )
309 RETURN
310 END IF
311*
312* Quick return if possible
313*
314 IF( min( m, n ).EQ.0 ) THEN
315 RETURN
316 END IF
317*
318* On input, the M-by-N matrix A contains the orthogonal
319* M-by-N matrix Q_in.
320*
321* (1) Compute the unit lower-trapezoidal V (ones on the diagonal
322* are not stored) by performing the "modified" LU-decomposition.
323*
324* Q_in - ( S ) = V * U = ( V1 ) * U,
325* ( 0 ) ( V2 )
326*
327* where 0 is an (M-N)-by-N zero matrix.
328*
329* (1-1) Factor V1 and U.
330
331 CALL slaorhr_col_getrfnp( n, n, a, lda, d, iinfo )
332*
333* (1-2) Solve for V2.
334*
335 IF( m.GT.n ) THEN
336 CALL strsm( 'R', 'U', 'N', 'N', m-n, n, one, a, lda,
337 $ a( n+1, 1 ), lda )
338 END IF
339*
340* (2) Reconstruct the block reflector T stored in T(1:NB, 1:N)
341* as a sequence of upper-triangular blocks with NB-size column
342* blocking.
343*
344* Loop over the column blocks of size NB of the array A(1:M,1:N)
345* and the array T(1:NB,1:N), JB is the column index of a column
346* block, JNB is the column block size at each step JB.
347*
348 nplusone = n + 1
349 DO jb = 1, n, nb
350*
351* (2-0) Determine the column block size JNB.
352*
353 jnb = min( nplusone-jb, nb )
354*
355* (2-1) Copy the upper-triangular part of the current JNB-by-JNB
356* diagonal block U(JB) (of the N-by-N matrix U) stored
357* in A(JB:JB+JNB-1,JB:JB+JNB-1) into the upper-triangular part
358* of the current JNB-by-JNB block T(1:JNB,JB:JB+JNB-1)
359* column-by-column, total JNB*(JNB+1)/2 elements.
360*
361 jbtemp1 = jb - 1
362 DO j = jb, jb+jnb-1
363 CALL scopy( j-jbtemp1, a( jb, j ), 1, t( 1, j ), 1 )
364 END DO
365*
366* (2-2) Perform on the upper-triangular part of the current
367* JNB-by-JNB diagonal block U(JB) (of the N-by-N matrix U) stored
368* in T(1:JNB,JB:JB+JNB-1) the following operation in place:
369* (-1)*U(JB)*S(JB), i.e the result will be stored in the upper-
370* triangular part of T(1:JNB,JB:JB+JNB-1). This multiplication
371* of the JNB-by-JNB diagonal block U(JB) by the JNB-by-JNB
372* diagonal block S(JB) of the N-by-N sign matrix S from the
373* right means changing the sign of each J-th column of the block
374* U(JB) according to the sign of the diagonal element of the block
375* S(JB), i.e. S(J,J) that is stored in the array element D(J).
376*
377 DO j = jb, jb+jnb-1
378 IF( d( j ).EQ.one ) THEN
379 CALL sscal( j-jbtemp1, -one, t( 1, j ), 1 )
380 END IF
381 END DO
382*
383* (2-3) Perform the triangular solve for the current block
384* matrix X(JB):
385*
386* X(JB) * (A(JB)**T) = B(JB), where:
387*
388* A(JB)**T is a JNB-by-JNB unit upper-triangular
389* coefficient block, and A(JB)=V1(JB), which
390* is a JNB-by-JNB unit lower-triangular block
391* stored in A(JB:JB+JNB-1,JB:JB+JNB-1).
392* The N-by-N matrix V1 is the upper part
393* of the M-by-N lower-trapezoidal matrix V
394* stored in A(1:M,1:N);
395*
396* B(JB) is a JNB-by-JNB upper-triangular right-hand
397* side block, B(JB) = (-1)*U(JB)*S(JB), and
398* B(JB) is stored in T(1:JNB,JB:JB+JNB-1);
399*
400* X(JB) is a JNB-by-JNB upper-triangular solution
401* block, X(JB) is the upper-triangular block
402* reflector T(JB), and X(JB) is stored
403* in T(1:JNB,JB:JB+JNB-1).
404*
405* In other words, we perform the triangular solve for the
406* upper-triangular block T(JB):
407*
408* T(JB) * (V1(JB)**T) = (-1)*U(JB)*S(JB).
409*
410* Even though the blocks X(JB) and B(JB) are upper-
411* triangular, the routine STRSM will access all JNB**2
412* elements of the square T(1:JNB,JB:JB+JNB-1). Therefore,
413* we need to set to zero the elements of the block
414* T(1:JNB,JB:JB+JNB-1) below the diagonal before the call
415* to STRSM.
416*
417* (2-3a) Set the elements to zero.
418*
419 jbtemp2 = jb - 2
420 DO j = jb, jb+jnb-2
421 DO i = j-jbtemp2, min( nb, n )
422 t( i, j ) = zero
423 END DO
424 END DO
425*
426* (2-3b) Perform the triangular solve.
427*
428 CALL strsm( 'R', 'L', 'T', 'U', jnb, jnb, one,
429 $ a( jb, jb ), lda, t( 1, jb ), ldt )
430*
431 END DO
432*
433 RETURN
434*
435* End of SORHR_COL
436*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
scopy
subroutine scopy(n, sx, incx, sy, incy)
SCOPY
Definition scopy.f:82
slaorhr_col_getrfnp
subroutine slaorhr_col_getrfnp(m, n, a, lda, d, info)
SLAORHR_COL_GETRFNP
Definition slaorhr_col_getrfnp.f:144
sscal
subroutine sscal(n, sa, sx, incx)
SSCAL
Definition sscal.f:79
strsm
subroutine strsm(side, uplo, transa, diag, m, n, alpha, a, lda, b, ldb)
STRSM
Definition strsm.f:181
Here is the call graph for this function:
Here is the caller graph for this function: